Discussion :

[Oyabi]

Je reviens vers vous puisque je voudrais désormais charger et décharger l'AddIn à l'ouverture/fermeture de mon classeur.
J'ai trouvé ces codes mais rien ne fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub Check(ByVal cmAdDesc As String)
Dim Trouve As Boolean, Connecte As Boolean
Dim CmAd As COMAddIn
Dim Msg As String
 
If Not ThisWorkbook.ReadOnly Then
    For Each CmAd In Application.COMAddIns
        If UCase(CmAd.Description) = UCase(cmAdDesc) Then
            progId = CmAd.progId 'progId est un string
            Trouve = True
            Connecte = CmAd.Connect
            Exit For
        End If
    Next CmAd
 
    If Trouve And Connecte Then
        'Msg = "COM Add-In " & cmAdDesc & " connecté"
    ElseIf Trouve = True And Connecte = False Then
        Application.COMAddIns(progId).Connect = True 'J'ai essayé avec progId et description mais rien à faire
    Else 'J'ai pas pris le temps de modifier le else encore
        Msg = "COM AddIn " & cmAdDesc & " n'est pas " & IIf(Not Trouve, "installé", "connecté") & "." & vbNewLine & "Seule la consultation est possible."
        ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
        MsgBox Msg
    End If
End If
End Sub

Merci à vous.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub Check(ByVal cmAdDesc As String)
Dim Trouve As Boolean, Connecte As Boolean
Dim CmAd As COMAddIn
Dim Msg As String
 
If Not ThisWorkbook.ReadOnly Then
    For Each CmAd In Application.COMAddIns
        If UCase(CmAd.Description) = UCase(cmAdDesc) Then
            Trouve = True
            Connecte = CmAd.Connect
            Exit For
        End If
    Next CmAd
 
    If Trouve And Connecte Then
        'Msg = "COM Add-In " & cmAdDesc & " connecté"
    ElseIf Trouve = True And Not Connecte Then
        CmAd.Connect = True                        'J'ai essayé avec progId et description mais rien à faire
    Else                                           'J'ai pas pris le temps de modifier le else encore
        Msg = "COM AddIn " & cmAdDesc & " n'est pas " & IIf(Not Trouve, "installé", "connecté") & "." & vbNewLine & "Seule la consultation est possible."
        'ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
        MsgBox Msg
    End If
End If
End Sub

Quand tu trouvais ton COM Addin, tu sors de la boucle avec Exit For et tu as ce COM Addin dans la variable CmAd.
Il suffit de l'utiliser

[Oyabi]

Haha c'était tout bête, merci encore à toi.
Bonne soirée.

[mercatog]

Pour pallier au problème qui pourrait être rencontré lors du chargement de l'addin, une petite modification

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Check(ByVal cmAdDesc As String)
Dim Trouve As Boolean, Connecte As Boolean
Dim CmAd As COMAddIn
Dim Msg As String
 
If Not ThisWorkbook.ReadOnly Then
    For Each CmAd In Application.COMAddIns
        If UCase(CmAd.Description) = UCase(cmAdDesc) Then
            Trouve = True
            Connecte = CmAd.Connect
            Exit For
        End If
    Next CmAd
 
    If Trouve And Connecte Then
        Msg = "COM Add-In " & cmAdDesc & " connecté"
    ElseIf Trouve And Not Connecte Then
        On Error Resume Next
        CmAd.Connect = True
        On Error GoTo 0
        Msg = "COM AddIn " & cmAdDesc & IIf(CmAd.Connect, " vient d'", " n' a pu ") & "être connecté"
    Else
        Msg = "COM AddIn " & cmAdDesc & " n'est pas " & IIf(Not Trouve, "installé", "connecté") & "." & vbNewLine & "Seule la consultation est possible."
        ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
    End If
    MsgBox Msg
End If
End Sub

[Oyabi]

Encore mieux merci
Et si je veux mettre cmAdd dans une variable globale pour pouvoir décharger l'AddIn facilement c'est une bonne idée ou il vaut mieux refaire une boucle etc ?
J'ai tenté un Public myAddIn As COMAddIn en haut de mon fichier et en faisant myAddIn = CmAd mais ça ne fonctionne pas.
Désolé de ma nullité. :p
Bonne soirée.

[mercatog]

Mieux une boucle sur le même principe (car tu n'as pas des millions de COM Addins à scruter)
Une variable publique pour peu de choses c'est surdimensionné à mon avis. (Subjectivement)

Sinon, pour affecter des objets on met Set

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MyAddin=cmAd

[Oyabi]

Cool j'ai réussi grâce à toi.
Merci et passe une bonne journée.