Discussion :

[znmile]

Bonjour à tous! et merci de prendre le temps de me donner un coup de main !

J'ai eu beau chercher, sur le forum et sur google, mais rien n'a fonctionné pour l'instant...

dans un UserForm je crée dynamiquement des combobox.

Puisqu'elles sont en dynamique, l'événement "Nomdemacombobox_change()" n'est pas reconnu (normal)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
'initialisation du USF
 
Private Sub UserForm_Initialize()
 
 For I = 1 To nbJoueurs
 
             'ajout de la combobox
Set bouton = UserForm2.Controls.Add("Forms.combobox.1", "photojoueur" & I, True)
       bouton.Name = "photojoueur" & I
 
Next
End Sub

et l'événement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
'event en pseudo code
 
Private Sub photojoueur1_Change()
 
msgbox " la combo 1 a changé "
 
End Sub

à noter que j'ai donc un certain nombre de combobox ajoutés dynamiquement. si je pouvais regrouper avec
" Sub photoNimportequelJoueur_Change()" ca serait tip top!

Un grand merci par avance!
toute piste est bienvenue!

[mercatog]

Peut être en utilisant un module de classe.

1. Crée un module de Classe (Insertion> Module de Classe) nommé Classe1 (par défaut)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public WithEvents CB As msforms.ComboBox
 
'Ici le code générique pour tous les combo créés
Private Sub CB_Change()
 
If CB.ListIndex > -1 Then MsgBox "L'item " & CB.Value & " de la Combobox " & CB.Name & " a été séléctionné"
 
End Sub

2. Dans le module de ton userform
PS: Dans le code suivant j'ai mis un exemple, chaque Combo créés reporte les données d'une colonne particulière de Feuil1. A toi d'adapter pour tes besoins

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Const NbJoueurs As Byte = 7 'ici pour l'exmple
 
Dim Coll As Collection
 
Private Sub UserForm_Initialize()
Dim Bouton As msforms.ComboBox
Dim Plage As String
Dim i As Byte
Dim Klas As Classe1
 
Set Coll = New Collection
For i = 1 To NbJoueurs
    'Définition par exemple de RowSource de chaque combo
    With Worksheets("Feuil1")
        Plage = "'" & .Name & "'!" & .Range(.Cells(1, i), .Cells(20, i)).Address
    End With
    Set Bouton = Me.Controls.Add("Forms.combobox.1", "photojoueur" & i, True)
    'Paramètres de placement de chaque combo
    With Bouton
        .Name = "photojoueur" & i
        .Left = 10
        .Top = 20 * (i - 1) + 50
        .Width = 200
        .Height = 20
        .RowSource = Plage
    End With
    'ici instantiation de la combo créée
    Set Klas = New Classe1
    Set Klas.CB = Bouton
    Coll.Add Klas
    Set Klas = Nothing
    Set Bouton = Nothing
Next i
End Sub

[znmile]

Merci beaucoup mercatog!

J'avais déjà essayé avec un module de classe, mais j'avais dû me planter dans les déclarations, ou les liens entre l'userform et la classe...

en tout cas, merci énormément pour ton aide!

à Bientôt!