Discussion :

[Pimpampoum]

Bonjour à tous,

Je dois pouvoir envoyer des mails et des Meeting Request depuis un fichier excel partagé qui va être utilisé par des utilisateurs d'Office 2003, 2007 et 2010.

Pour éviter le problème de "changement de référence -Microsoft Outlook 1x.0-) j'ai codé un utilisant des objets mais j'ai un problème avec les Meeting Request. Le code ci-dessous fonctionne correctement si j'active la Référence Microsoft Outlook mais je veux que le code fonctionne aussi sans cette référence activé. Ca fait quelques jours que je tourne au tour du pot et je n'arrive pas à trouver la solution.
L'erreur survient à l'auteur de la ligne "RequiredAttendees".
Merci de votre aide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Test()
    Dim olApplication As Object
    Dim olAppointment As Object
 
    Set olApplication = CreateObject("Outlook.Application")
    Set olAppointment = olApplication.CreateItem(olAppointmentItem)
 
    With olAppointment
        .RequiredAttendees = "toto@mail.fr"
        .Subject = "Test Meeting Request"
        .Importance = 2
        .Start = "18/06/2012" & " 8:30"
        .Location = "Dans mon bureau"
        .Body = "Test"
        .MeetingStatus = 1
        .ResponseRequested = True
        .Send
    End With
 
    Set olApplication = Nothing
    Set olAppointment = Nothing
End Sub

[Daniel.C]

Bonjour,

J'ai déjà rencontré ce problème que j'avais contourné en cochant la référence Outlook. Si tu ne le fais pas, "olAppointment" est un mailitem alors que, si la référence est cochée, "olAppointment" est bien un appointmentitem comme tu peux le voir dans la fenêtre des variables locales. A ta place, je listerais les références (cochées) des différentes versions d'Excel et dans ton appli, ja testerai la version pour ajouter la bonne référence :

1. liste des références sur la première feuille du classeur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub ListReferencePaths()
     'Macro purpose:  To determine full path and Globally Unique Identifier (GUID)
     'to each referenced library.  Select the reference in the Tools\References
     'window, then run this code to get the information on the reference's library
 
    On Error Resume Next
    Dim i As Long
    With ThisWorkbook.Sheets(1)
        .Cells.Clear
        .Range("A1") = "Reference name"
        .Range("B1") = "Full path to reference"
        .Range("C1") = "Reference GUID"
        .[D1] = "Majeur"
        .[E1] = "Mineur"
    End With
    For i = 1 To ThisWorkbook.VBProject.References.Count
        With ThisWorkbook.VBProject.References(i)
            ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Offset(1, 0) = .Name
            ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Offset(0, 1) = .FullPath
            ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Offset(0, 2) = .GUID
            ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Offset(0, 3) = .Major
            ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Offset(0, 4) = .Minor
        End With
    Next i
    On Error GoTo 0
End Sub

2. Ajout d'une référence :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub AjoutReference()
ActiveWorkbook.VBProject.References.AddFromGuid "{831FDD16-0C5C-11D2-A9FC-0000F8754DA1}", 2, 0
End Sub

[Invité]

Bonjour

Pas besoin de cocher une référence.

olAppointmentItem est une constante liée à OutLook, celle-ci a une valeur que l'on peut retrouver dans l'explorateur d'objet (F2) de l'éditeur VB.

Il y a donc deux solutions :

• Remplacer la constante pas sa valeur.
• Recrée dans un module la constante avec la valeur.

Personnellement, la deuxième solution est celle que j'utilise.

Le fait de cocher une référence te lis à la version, donc des soucis de portabilité.

Philippe

[Daniel.C]

Super !
J'ai essayé avec la méthode 1; par contre, je n'ai pas compris le 2. Est-ce que tu peux expliquer davantage ?

[Invité]

Re

Un exemple sera plus parlant :

J'utilise un complément Access (c'est le même problème sous Excel) qui permet entre autre d'envoyer un tableau par OutLook qui est le résultat d'une analyse d'un fichier.

Donc dans mon code j'utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set ObjMail = AppOutLook.CreateItem(olMailItem)

Hors, le complément tourne sur des postes avec Access 2000 et 2002, donc impossible de référencer OutLook.

Tu te doutes bien que sans référencer OutLook la ligne bug, car il ne connait pas la constante olMailItem

Donc dans un module je déclare :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Const olMailItem As Long = 0

Ainsi ma constante est reconnue et le code est plus parlant.

En résumant :

Je développe en cochant la référence et je déclare les objets comme des objets OutLook.
Avant de distribuer, je décoche la référence, et les objets OutLook sont déclarés comme des objets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Public AppOutLook As Object
Public ObjMail As Object

Ensuite je déclare les constante en Public avec leur valeur que je récupère dans l'explorateur d'objet et tout est reconnu.

De plus le nom de la constante est plus parlant que sa valeur.

Philippe

[Daniel.C]

De plus le nom de la constante est plus parlant que sa valeur.

C'est le seul intérêt par rapport à la solution 1 ?

[Invité]

C'est le seul intérêt par rapport à la solution 1 ?

Pour moi, c'est un intérêt énorme lorsque l'on veut débugger un programme et lors de la conception de celui-ci.

Philippe

[Daniel.C]

Merci.

[Pimpampoum]

Merci de votre aide. Ça marche !