Discussion :

[kedmard]

Bonjour à tous,

J'ai un fichier qui comporte deux onglets "Onglet1" et "Onglet2" et je souhaite copier les cellules B5 à D13 de l' "Onglet1" pour les coller sur la plage H7 à J15 de l' "Onglet2" lorsque la ligne 4 (ligne de Date) de onglet1 coïncide avec la ligne 6 (Date) de onglet2 .
Enfin je veux que les modifications apportées à la feuille 2 (onglet2) soit enregistrées.

Ci-joint mon fichier pour plus de clarté.


Merci d'avance pour votre aide.

Kalmard

[casefayere]

Bonjour,
Une idée avec un bouton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub CommandButton1_Click()
Dim D As Range
With Sheets("Onglet2")
  Set D = .Range("C6:I6").Find(Sheets("Onglet1").Range("C4"), .Range("I6"))
  If Not D Is Nothing Then
   .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
  End If
End With
End Sub

Enfin je veux que les modifications apportées à la feuille 2 (onglet2) soit enregistrées.

expliques-toi mieux sur cette demande

[kedmard]

Salut, casefayere

merci pour ta réponse,
J'opterai plutôt pour une macro sans bouton car je souhaite ensuite automatiser l' exécution de cette macro depuis une ligne de commande (fichier .bat).
Pour le dernier point je veux juste que le tout soit enregistrer après le collage instruction du genre "save sheet" mais je suis pas sûr du code.

Bonne soirée.

[casefayere]

re,
Je ne comprends pas ta demande mais si tu ne veux pas un bouton, tu peux mettre ce code dans l'évènement "Change" de ta feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Worksheet_Change(ByVal Target As Range)
Dim D As Range
With Sheets("Onglet2")
  If Target.Address = "$C$4" Then
    Set D = .Range("C6:I6").Find(Target, .Range("I6"))
    If Not D Is Nothing Then
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
  End If
End With
End Sub

...après le collage instruction du genre "save sheet" mais je suis pas sûr du code.

Je ne vois pas comment enregistrer une feuille sans enregistrer le fichier mais comme je viens de le dire, je ne comprends pas ta demande

Bonne soirée

[kedmard]

Salut,
L'enregistrement du fichier me conviendrait,
Les deux codes marchent parfaitement, pourrais tu me donner une explication sur les lignes suivantes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Set D = .Range("C6:I6").Find(Sheets("Onglet1").Range("C4"), .Range("I6"))
  If Not D Is Nothing Then
   .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
  End If

Merci encore.

[casefayere]

Je t'explique l'exemple avec la dernière proposition, le principe est le même pour l'autre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Worksheet_Change(ByVal Target As Range)
Dim D As Range
With Sheets("Onglet2")
  If Target.Address = "$C$4" Then 'si la selection est en C4
  'Find est une fonction de recherche
'D est une variable Range, donc on cherche dans la plage Sheets("Onglet2").Range("C6:I6"), la valeur de Sheets("Onglet1").Range("C4")
    Set D = .Range("C6:I6").Find(Target, .Range("I6"))
 'si la recherche est positive, la valeur est trouvée donc D n'est pas "Nothing"
 
    If Not D Is Nothing Then
    'D étant, dans ton exemple I6 de l'onglet2,la plage qui reçoit les données va de d(2,0)  d(10,2) soit de H7 à J15
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
  End If
End With
End Sub

[kedmard]

Mes sincères reciemments,

Bonne journée.


Kedmard.

[casefayere]

Bonjour,
il faut penser à cliquer sur quand ça l'est,

Bonne journée

[kedmard]

Sur la même lancée , as tu une idée sur la façon dont on procédera si le copier/coller doit se faire par comparaison direct? je m'explique:

Supposons que l'onglet 2 des contienne des dates jusqu'au 01/12/2012 comment faire en sorte que si la date de onglet 1 est la meme que celle l'onglet 2 , alors que la copie de B513 de l'onglet 1 soit faite sur la plage correspondant à la date en question dans l'onglet 2.


Je te joint le fichier pour plus de compréhension.

[casefayere]

re,
je ne suis pas en forme ce matin, voici 3 fois que je change le code
si j'ai compris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Worksheet_Change(ByVal Target As Range)
Dim D As Range, dercol As Long
With Sheets("Onglet2")
  dercol = .Cells(6, .Columns.Count).End(xlToLeft).Column
  If Target.Address = "$C$4" Then
    Set D = .Range("C6", .Cells(6, dercol)).Find(Target, .Cells(6, dercol), LookIn:=xlValues)
    If Not D Is Nothing Then
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
  End If
End With
End Sub

[kedmard]

ça ne marche pas ,

J'ai mis le code dans "Thisworkbook", changé la date de l'onglet 1
au 01/08/2012
Et lorsque j'exécute on me demande le nom de la macro et si je mets le nom de ma procédure , j'ai un nouveau module qui se crée ... et mais au finish je n'ai rien dans la colonne de date 01/08/2012 de l'onglet 2


Ai-je sauter une étape ? merci

[casefayere]

As-tu fait attention, j'ai rechangé le code, je n'étais pas en forme, essayes et dis-moi

[Invité]

Je n'ai pas eu le même problème que toi mais je pense que ça pourrait t’intéresser de lire ce que j'ai fait :

http://www.developpez.net/forums/d12...orrespondante/

Il s'agissait de copier une colonne dans une autre feuille selon la date, en l'adaptant tu dois pouvoir copier la colonne source, dans une colonne de destination selon la date. Le problème n'est pas le même dans le lien que je t'ai envoyé, mais ça peut te donner des idées.

[kedmard]

Toujours rien,

Je te mets le fichier en Pj le code est dans "Thisxorbook".

[casefayere]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim D As Range, dercol As Long
With Sheets("Onglet2")
  dercol = .Cells(6, .Columns.Count).End(xlToLeft).Column
  If Target.Address = "$C$4" Then
    Set D = .Range("C6", .Cells(6, dercol)).Find(Target, .Cells(6, dercol), LookIn:=xlValues)
    If Not D Is Nothing Then
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
  End If
End With
 
End Sub

[kedmard]

ça ne marche toujours pas , on me demande toujours de remplir le nom de la macro.

C'est comme si l'éxécution n'avait aucun effet...

Tu as éssayer toi de l'éxécute?

[casefayere]

C'est un évènement "Change donc on ne passe pas par "execute", il faut savoir ce que tu veux. Je t'avais proposé un bouton, en changeant légèrement le code, tu m'as dit non. Ensuite, je t'ai proposé de passer par l'évènement "Change" de ta feuille. Maintenant tu préfères passer par thisworkbook avec l'évènement "Workbook_SheetChange", la macro marchera quand tu sera sur la cellule "C4" de la feuille Onglet1, encore faut-il, par sécurité ajouter la condition "If Sh.name = "Onglet1" soit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim D As Range, dercol As Long
With Sheets("Onglet2")
  dercol = .Cells(6, .Columns.Count).End(xlToLeft).Column
  If Sh.Name = "Onglet1" And Target.Address = "$C$4" Then
    Set D = .Range("C6", .Cells(6, dercol)).Find(Target, .Cells(6, dercol), LookIn:=xlValues)
    If Not D Is Nothing Then
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
  End If
End With
 
End Sub

[kedmard]

Salut casefayere,

Désolé si je n'ai pas été assez claire dans mes post, tes réponses m'ont permi en enfin d'avoir ce que je chechais.
J'ai donc dans "thisworkbook" le code ci-dessous final:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Macopie()
Dim D As Range, dercol As Long
With Sheets("Onglet2")
  dercol = .Cells(6, .Columns.Count).End(xlToLeft).Column
     Set D = .Range("C6", .Cells(6, dercol)).Find(Sheets("Onglet1").Range("C4"), .Cells(6, dercol), LookIn:=xlValues)
    If Not D Is Nothing Then
      .Range(D(2, 0), D(10, 2)).Value = Sheets("Onglet1").Range("B5:D13").Value
    End If
End With
End Sub

Qui résoud mon problème.

Juste un dernier détail, pourquoi tu dis que
D(2, 0) =H7 et D(10,2)=J15

Merci encore pour tout.

[casefayere]

Juste un dernier détail, pourquoi tu dis que
D(2, 0) =H7 et D(10,2)=J15

D représente la cellule cherchée et c'est une variable Range, tu as 2 choix :
- l'écrire comme ci-dessus, le premier chiffre représente le décalage des lignes, le deuxième le décalage des colonnes, sachant que D.Address et D(1,1).address (fais l'essai) te donneront le même résultat, la plage commence 1 ligne en dessous et une colonne avant donc D(2,0), même principe pour D(10,2)

- Tu utilises "Offset", le comptage commence à 0 : D(1,1) = D.offset(0,0), D(2,0) = D.offset(1,-1)

intègres cette ligne dans ton code et regardes le résultat qui sera identique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox D.Address & " " & D(1, 1).Address & " " & D.Offset(0, 0).Address

Je répéte penses à

[kedmard]

Merci .

J'ai déjà cliquez su résolu.

Bonne journée.