Incorporer un code dans un module pour toutes les pages

**jlb59** · 19/02/2012, 14h01

Bonjour à tous,

Je fais un prog qui contient plusieurs pages, et pour chacune d'elles je mets plusieurs sub pour "désactiver la case System" et "empêcher le déplacement" de la fenêtre.
Ci-après les procédures en question :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
'==== Désactive les options de la case system =========================
  Dim nStyle  As Long
  Dim nMenu   As Long
  Dim nCount  As Long
  Dim hMenu As Long
 Dim menuItemCount As Long
 
'--- Désactive la case system "fermer" ----
   hMenu = GetSystemMenu(Me.hwnd, 0)
   If hMenu Then
      menuItemCount = GetMenuItemCount(hMenu)
      Call RemoveMenu(hMenu, menuItemCount - 1, MF_REMOVE Or MF_BYPOSITION)
      Call RemoveMenu(hMenu, menuItemCount - 2, MF_REMOVE Or MF_BYPOSITION)
      Call DrawMenuBar(Me.hwnd)
   End If
 
  '--- Empêche le déplacement ---
  With Me
    nStyle = GetWindowLong(.hwnd, GWL_STYLE)
    nStyle = nStyle And Not (WS_THICKFRAME)
    SetWindowLong .hwnd, GWL_STYLE, nStyle
    nMenu = GetSystemMenu(.hwnd, 0)
    RemoveMenu nMenu, SC_MOVE, MF_REMOVE Or MF_BYCOMMAND
    nCount = GetMenuItemCount(nMenu)
    RemoveMenu nMenu, nCount - 2, MF_REMOVE Or MF_BYPOSITION
    DrawMenuBar .hwnd
  End With
Me.BackColor = &HC0C0C0

Ces lignes de codes m'ont été fournies par différents forums je crois, dont celui-ci si je ne me trompe pas, et je voudrais savoir comment le mettre dans un module (si c'est possible) pour m'éviter de les spécifier dans toutes les pages !

J'ai vu dans l'aide l'index avec "Parent" ! Y a bien des exemples mais pour un "Sub Form_Load" et ça ne m'aide pas.

J'ai fait la même chose pour paramétrer des contrôles (OptionButton" et 'CommandButton") mais ut=niquement pour le positionnement et la couleur.

Donc, pour faire le code plus haut, c'est un peu plus compliqué pour moi.

C'est pour ça que j'ai absolument besoin de vos lumières pour parvenir à un bon résultat.

Merci de votre réponse.

**ProgElecT** · 19/02/2012, 15h33

Salut

Dans un module.bas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Private Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Private Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Const MF_REMOVE = &H1000&
Private Const MF_BYPOSITION = &H400&
Private Const GWL_STYLE = (-16)
Private Const WS_THICKFRAME = &H40000
Private Const SC_MOVE = &HF010&
Private Const MF_BYCOMMAND = &H0&
 
Public Sub GestMenuSys(Frm As Form)
 
'==== Désactive les options de la case system =========================
Dim nStyle  As Long
Dim nMenu   As Long
Dim nCount  As Long
Dim hMenu As Long
Dim menuItemCount As Long
 
'--- Désactive la case system "fermer" ----
   hMenu = GetSystemMenu(Frm.hwnd, 0)
   If hMenu Then
      menuItemCount = GetMenuItemCount(hMenu)
      Call RemoveMenu(hMenu, menuItemCount - 1, MF_REMOVE Or MF_BYPOSITION)
      Call RemoveMenu(hMenu, menuItemCount - 2, MF_REMOVE Or MF_BYPOSITION)
      Call DrawMenuBar(Frm.hwnd)
   End If
 
  '--- Empêche le déplacement ---
  With Frm
    nStyle = GetWindowLong(.hwnd, GWL_STYLE)
    nStyle = nStyle And Not (WS_THICKFRAME)
    SetWindowLong .hwnd, GWL_STYLE, nStyle
    nMenu = GetSystemMenu(.hwnd, 0)
    RemoveMenu nMenu, SC_MOVE, MF_REMOVE Or MF_BYCOMMAND
    nCount = GetMenuItemCount(nMenu)
    RemoveMenu nMenu, nCount - 2, MF_REMOVE Or MF_BYPOSITION
    DrawMenuBar .hwnd
  End With
Frm.BackColor = &HC0C0C0
End Sub

En fait je n'ai fait que remplacé Me par Frm, l'unique paramétre de la sub GestMenuSys.
L'appel dans x Form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Form_Load()
GestMenuSys Me
End Sub

Pour les contrôles sur un Form, une nouvelle Sub dans le module avec paramètre LeCtrl as Control, elle pourrait ressembler a

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Public Sub GestControles(LeCtrl As Control)
Select Case TypeName(LeCtrl)
    Case "TextBox": LeCtrl.BackColor = 255
    Case "OptionButton": LeCtrl.Caption = "Coucou"
    Case "CommandButton": LeCtrl.Caption = "un bouton"
End Select
End Sub

L'appel dans x Form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
GestControles Text1
GestControles Option1
GestControles Command1

**jlb59** · 19/02/2012, 17h33

C'est très sympa d'avoir mis le 1ere exemple d'un module.bas.

Tu me dis avoir remplacé le "Me" par des "Frm", peut-être que mon erreur à l'exécution venait de là !

En tout cas, merci beaucoup des ces exemples.

Je vais essayé ça et si c'est OIK, je mettrai mon post comme "Resolu" !

**jlb59** · 19/02/2012, 18h38

Envoyé par ProgElecT

Salut

Dans un module.bas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Option Explicit
Private Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
...

J'ai fait cela dans un module.bas comme tu me le conseilles, mais à partir de la 1ère ligne "Private" j'ai une erreur, donc pas d'exécution. Impossible d'aller plus loin.

Par contre, si je mets le code dans une "Form_Load" de page, il n'y a pas d'erreur.

Même en mettant "Public", c'est pareil !

Ai-je fait une bêtise ?

**SfJ5Rpw8** · 19/02/2012, 19h07

Envoyé par jlb59

J'ai fait cela dans un module.bas comme tu me le conseilles, mais à partir de la 1ère ligne "Private" j'ai une erreur, ...

qu'est ce qui te fait dire que tu as une erreur ?

**jlb59** · 19/02/2012, 20h28

Simplement que j'ai

Erreur de compilation:
Seuls des commentaires peuvent apparaître après End Sub, End Function ou End Property

C'est ce que j'appelle une erreur puisque c'est marqué comme ça !

**ProgElecT** · 19/02/2012, 22h27

Envoyé par ProgElecT

Salut
L'appel dans x Form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
GestControles Text1
GestControles Option1
GestControles Command1

Ces appels a la Sub GestControles se trouvant dans le même module .bas que la Sub GestMenuSys doivent être fait dans une Sub d'un Form quelconque, pas à la suite.
Code qui a peut créer l'erreur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Form_Load()
GestMenuSys Me
End Sub
GestControles Text1
GestControles Option1
GestControles Command1

l'essai proposé devant être

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Form_Load()
GestMenuSys Me
GestControles Text1
GestControles Option1
GestControles Command1
End Sub

A la condition qu'il y est bien 1 TextBox, 1 OptionButton et un CommandButton sur le Form qui appel cette Sub Public du module.bas.

**jlb59** · 20/02/2012, 05h13

Envoyé par ProgElecT

Ces appels a la Sub GestControles se trouvant dans le même module .bas que la Sub GestMenuSys doivent être fait dans une Sub d'un Form quelconque, pas à la suite.
Code qui a peut créer l'erreur[code]Private Sub Form_Load()

Non, je n'avais pas besoin de tout ça, car toutes mes pages sont différentes (OptionButton, CommandButton, Picture, Label, TextBox...).
Donc, si je mets ton code complet dans un module.bas, toutes les pages devront avoir les mêmes objets.

Tout bien réfléchi, c'est peut-être la source de l'erreur :http://qi98.free.fr/temp/Image3.jpg

Je vais regarder ça de plus près parce que y a pas de raison.
Tu m'as donné un code OK, donc, c'est à moi à faire en sorte que tout aille bien !

**jlb59** · 20/02/2012, 05h17

Envoyé par ProgElecT

Ces appels a la Sub GestControles se trouvant dans le même module .bas que la Sub GestMenuSys doivent être fait dans une Sub d'un Form quelconque, pas à la suite.
...
A la condition qu'il y est bien 1 TextBox, 1 OptionButton et un CommandButton sur le Form qui appel cette Sub Public du module.bas.

Tout a été fait comme tu me l'as mis et pour ce qui est de l'autre condition, toutes les pages n'ont pas tout ça !

Incorporer un code dans un module pour toutes les pages

VB 6 et antérieur

Discussions similaires

Partager

Partager