Discussion :

[ouskel'n'or]

Question récurrente : Comment saisir un mot de passe
Réponse récurrente : En passant par un userform
USF Mot de passe.zip
Pour insérer l'userform dans un projet :
Placer les deux fichiers joints "quelque part" sur votre disque dur
Dans l'éditeur VB, sélectionner votre projet -> clic droit -> Importer -> Chercher l'emplacement des deux fichier -> MotDePasse.frm -> Ok !
Épicétou
La Boîte :
Pour l'appeler depuis une macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Load MotDePasse
MotDePasse.show

Dans la macro, le code qui suit éventuellement ces lignes ne s'éxécutera qu'une fois la boîte de dialogue fermée (fermeture prévue dans la boîte...)

NB - Pour plus de sécurité, changer le mot de passe donné en exemple

[ouskel'n'or]

Dadavyvy me signale également un code ici, qui permet d'utiliser un Inputbox à la place d'un userform pour la saisie des mots de passe, le code saisi apparaissant ici aussi sous forme de "*"

[AlainTech]

On dirait bien qu'on a ça chez nous:
http://www.developpez.net/forums/sho...70&postcount=6

[dadavyvy]

Coool! ce forum est décidément bien complet...
Par contre quand j'ai fait ma recherche Google, ça n'est pas ressorti...

Mots-clés : InputBox & PasswordChar, InputBoxEx, InputBoxDK

[AlainTech]

J'ai ajouté tes mots clés dans la discussion en question.

[Celimen]

le code écrit par Daniel Klann (proposition de dadavyvy) fonctionne sans aucun problème avec l'inputbox

En revanche celui écrit par mossy69vb6 (propostion d'AlainTech) pose un problème d'activeX non reconnu par VBE (je n'ai pas trouvé la solution).

[skk201]

Bonjour je me permet de venir vous aider avec un code que j'utilisai dans un ancien fichier excel. Il semblerait qu'il ai été écrit par un certain Daniel Klann, vivant en allemagne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
'Module pour inputbox pour les mots de pass
Option Explicit
'Code geschrieben von Daniel Klann
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal nCode As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
(ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
ByVal dwThreadId As Long) As Long
Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
(ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0
Private hHook As Long
 
Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim RetVal
Dim strClassName As String, lngBuffer As Long
If lngCode < HC_ACTION Then
    NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
    Exit Function
End If
strClassName = String$(256, " ")
lngBuffer = 255
 If lngCode = HCBT_ACTIVATE Then
    RetVal = GetClassName(wParam, strClassName, lngBuffer)
        If Left$(strClassName, RetVal) = "#32770" Then
        SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
        End If
 End If
CallNextHookEx hHook, lngCode, wParam, lParam
End Function
 
Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _
Optional YPos, Optional HelpFile, Optional Context) As String
Dim lngModHwnd As Long, lngThreadID As Long
lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)
hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
UnhookWindowsHookEx hHook
End Function

Pour l'utilisé il suffis de l'ajouté comme module, et ensuite d'utilisé "InputBoxDK" dans la macro avec les même choix que une inputbox normale. (Prompt, Title, Default, XPos, YPos, HelpFile, Context) As String