Cours Commandbar, problème

**Paro.** · 04/01/2012, 11h51

Bonjour,

Je voulez me tenter au cours sur les commandbar mais voila j'ai un petit souci,
soit j'ai une erreur d'execution '5' soit sa ne marche carrement pas.
Pareil avec les fichier demo a telecharger a la fin du cours.

Lien du cours:
http://fring.developpez.com/vba/excel/barremenu/

**CODYCO** · 04/01/2012, 11h58

je te conseil de jeter un oeil sur le topic de SilkyRoad.developpez.com

**Paro.** · 04/01/2012, 13h11

Merci, je viens de faire un petit tour et c'est plutôt intéressant. Malgré tout je n'ai pas réussi a résoudre l'erreur occasionné. J'ai lu "gestions des erreur" mais je n'ai pas trouvé mon bonheur.
D'après mes recherche sa viendrai du fait que VB et un langage anglais et que Excel est en français mais cela n'a rien a voir avec le code.
Je suis perdu!

**CODYCO** · 04/01/2012, 13h34

Peux tu nous donner un morceau de ton code histoire que cela soit plus claire

**Paro.** · 04/01/2012, 13h41

Copier coller du cours directement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
 
Sub barre_menus_perso()
'déclaration des variables
Dim Cbar As CommandBar, Cbut As CommandBarButton
Dim Ctxt As CommandBarComboBox, Cpop1 As CommandBarPopup, Cpop2 As CommandBarPopup
Dim x As Byte
 
'création de la barre de menus
Set Cbar = CommandBars.Add(Name:="MaBarre", Position:=msoBarTop, Temporary:=True)
Cbar.Protection = msoBarNoMove + msoBarNoCustomize '<-- protection de la barre de menus
 
'insertion sur la barre de menus d'un bouton de commande
Set Cbut = Cbar.Controls.Add(msoControlButton)
With Cbut
    .FaceId = 358 '<-- icône
    .OnAction = "Macro1" '<-- procédure à exécuter
    .TooltipText = "Suppression barre de menus" '<-- info-bulle
    .Tag = "cbut1" '<-- étiquette
End With
 
'insertion sur la barre de menus d'une zone de texte
Set Ctxt = Cbar.Controls.Add(msoControlEdit)
With Ctxt
    .Style = msoComboLabel '<-- zone de texte avec label
    .Caption = "Date :" '<-- texte du label
    .TooltipText = "Veuillez introduire une date" '<-- info-bulle
    .OnAction = "Macro2" '<-- procédure à exécuter
    .BeginGroup = True '<-- barre de séparation
    .Tag = "ctxt1" '<-- étiquette
End With
 
'insertion sur la barre de menus d'une zone de liste
Set Ctxt = Cbar.Controls.Add(msoControlDropdown)
With Ctxt
    .Style = msoComboLabel '<-- zone de liste avec label
    .Caption = "Liste :" '<-- texte du label
    .TooltipText = "Faites votre choix" '<-- info-bulle
    .OnAction = "Macro3" '<-- procédure à exécuter
    .BeginGroup = True '<-- barre de séparation
    .Tag = "clist1" '<-- étiquette
    For x = 1 To 5
        .AddItem ("Choix " & x) '<-- ajout de 5 Item
    Next
End With
 
'insertion sur la barre de menus d'un sous-menu 1
Set Cpop1 = Cbar.Controls.Add(msoControlPopup)
With Cpop1
    .Caption = "Sous-menu 1" '<-- label du sous-menu
    .Tag = "sm1" '<-- étiquette
End With
 
'insertion dans le sous-menu 1 d'un premier bouton de commande
Set Cbut = Cpop1.Controls.Add(msoControlButton)
With Cbut
    .Style = msoButtonCaption '<-- bouton avec texte uniquement
    .Caption = "Bouton 1" '<-- label du bouton
    .OnAction = "Macro4" '<-- procédure à exécuter
    .Tag = "sm1cbut1" '<-- étiquette
End With
 
'insertion dans le sous-menu 1 d'un second bouton de commande
Set Cbut = Cpop1.Controls.Add(msoControlButton)
With Cbut
    .Style = msoButtonCaption '<-- bouton avec texte uniquement
    .Caption = "Bouton 2" '<-- label du bouton
    .OnAction = "Macro4" '<-- procédure à exécuter
    .Tag = "sm1cbut2" '<-- étiquette
End With
 
'insertion dans le sous-menu 1 d'un sous-menu 2
Set Cpop2 = Cpop1.Controls.Add(msoControlPopup)
With Cpop2
    .Caption = "Sous-menu 2" '<-- label du sous-menu
    .Tag = "sm2" '<-- étiquette
End With
 
'insertion dans le sous-menu 2 d'un bouton prédéfini ouvrant l'application Word
Set Cbut = Cpop2.Controls.Add(Type:=msoControlButton, ID:=42)
With Cbut
    .Style = msoButtonIconAndCaption '<-- bouton avec icône + texte
    .Caption = "Word" '<-- label du bouton
End With
 
'insertion dans le sous-menu 2 d'un bouton prédéfini ouvrant l'application Access
Set Cbut = Cpop2.Controls.Add(Type:=msoControlButton, ID:=264)
With Cbut
    .Style = msoButtonIconAndCaption '<-- bouton avec icône + texte
    .Caption = "Access" '<-- label du bouton
End With
 
'insertion dans le sous-menu 2 d'un bouton prédéfini ouvrant l'application PowerPoint
Set Cbut = Cpop2.Controls.Add(Type:=msoControlButton, ID:=267)
With Cbut
    .Style = msoButtonIconAndCaption '<-- bouton avec icône + texte
    .Caption = "PowerPoint" '<-- label du bouton
End With
 
Cbar.Visible = True '<-- affichage de la barre de menus
 
End Sub

Quelque que soit le code, il plante toujours a la création de la commandbar au niveau de cette ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Cbar = CommandBars.Add(Name:="MaBarre", Position:=msoBarTop, Temporary:=True)

Se que je ne comprend pas c'est que vu la qualité du cours il n'y a aucune raison que ca plante et pourtant si. Ça vient peut être de ma version Excel ou autre.

**CODYCO** · 04/01/2012, 13h57

Tu es en 2010? si oui cela ne se gère plus du tout comme ca, tu dois repasser par du xml.

**Paro.** · 04/01/2012, 14h02

Merci pour tes réponse,

C'est a dire que ca ne fonctionne plus comme ca?
Je pourrai télécharger une version antérieur, sa marcherai?
N'y a-t-il vraiment aucun moyen pour faire comme cela sous 2010?

**CODYCO** · 04/01/2012, 14h39

Non pas moyen j'ai moi meme rencontrer le probleme il n'y a pas longtemps.
Jusque 2003 cela marche a partir de la version 2007 tu repasses par une gestion en xml, mais une que l'on est rodé c'est pas trop mal mais cela oblige à deux versions si tes utilisateur sont en version antérieur.

Si tu veux te lancer dedans va voir la:
http://silkyroad.developpez.com/excel/callbacks

**Paro.** · 04/01/2012, 14h51

Yahou je vais attendre un peu avant de me lancer la dedans.
Mais si par hasard un jour je retente sur plus que 2007 ou ce situe le fichier xml de personnalisation?

**CODYCO** · 05/01/2012, 10h22

Il est zippé a l'intérieur du fichier xl il faut renommer le fichier excel en zip et le dézipper pour le voir mais le mieux reste d'utiliser un utilitaire commme Office 2007 Custom UI Editor qui te créer le xml et l'associe directement a excel...