Discussion :

[Vadorblanc]

Bonjour
Je cherche à supprimer toutes les lignes si en colonne B le terme est identique à une autre ligne.
Le code ci-dessous supprime les lignes si un doublon est trouvé en colonne B, mais je voudrais aussi qu'il supprime la première ligne du doublon. Si B3, B4, B5 = identique alors suppression de ligne B3, B4, B5
Merci à vous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Module19SupprimeDoublons()
 
Application.ScreenUpdating = False
Dim LastLig As Long, i As Long
 
With Sheets("Base2")
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    For i = LastLig To 2 Step -1
 
        If Application.CountIf(.Range("B1:B" & LastLig), .Range("B" & i)) > 1 Then
            .Rows(i).Delete
            LastLig = LastLig - 1
        End If
    Next i
End With
End Sub

[mercatog]

Bonsoir
ça fait longtemps. Comment les vacances?
Une proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Module19SupprimeDoublons()
Dim i As Long, n As Long
Dim c As String
 
Application.ScreenUpdating = False
With Sheets("Base2")
    .AutoFilterMode = False
    i = .Cells(.Rows.Count, "B").End(xlUp).Row
    Do
        c = .Range("B" & i)
        If c <> "" Then
            .Range("B1:B" & i).AutoFilter field:=1, Criteria1:=c
            n = .Range("B1:B" & i).SpecialCells(xlCellTypeVisible).Count
            If n > 2 Then .Range("B2:B" & i).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        Else
            n = 2
        End If
        .AutoFilterMode = False
        i = i - n + 1
    Loop While i > 1
End With
End Sub

Le code est général au cas où tu as des cellules vides à l'intérieur de ta colonne B, sinon, le code peut être simplifie (sans la condition si c<>"")

[Vadorblanc]

Bonjour Mercatog
Le code est parfait, MERCI
Je n'ai pas pris encore mes vacances, je regarde tes codes presque tous les jours dont je me fais le plaisir de voter, j'admire ce que tu fais.
Bien cordialement
Un fan