Discussion :

[Vadorblanc]

Bonjour
Une première boucle supprime toutes les lignes différentes de "Essai" , je souhaite qu'elle tourne sur toutes les sheets du fichier sauf une sheet "Feuil1" boucle 2, mais l'imbrication des 2 boucles ne fonctionne pas, il faut que je sélectionne chaque sheet et que je lance le code pour supprimer les lignes inutiles, peut-être faut il déclarer une variable manquante?
Merci pour l'aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Boucles()
 
 Dim sht As Worksheet
 For Each sht In Worksheets
  Debug.Print sht.Name
  If sht.Name <> "Feuil1" Then
 
 
   For n = Range("A65536").End(xlUp).Row To 1 Step -1
      If InStr(Range("A" & n), "Essai") = 0 Then Rows(n).Delete
    Next n
 
 
  End If
 Next
End Sub

[Philippe Tulliez]

Bonjour,
En ajoutant l'objet sht devant les range et rows cela fonctionnera. Sans cela, le test se fait sur la feuille active.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
For n = sht.Range("A65536").End(xlUp).Row To 1 Step -1
  If InStr(sht.Range("A" & n), "Essai") = 0 Then sht.Rows(n).Delete
Next n

[mercatog]

Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Boucles()
Dim Sht As Worksheet
Dim i As Long
 
Application.ScreenUpdating = False
For Each Sht In Worksheets
    With Sht
        If .Name <> "Feuil1" Then
            For i = .Cells(.Rows.Count, 1).End(xlUp).Row To 1 Step -1
                If InStr(.Range("A" & i), "Essai") = 0 Then .Rows(i).Delete
            Next i
        End If
    End With
Next Sht
End Sub

[Mytå_Qc]

Salut le forum

En ajoutant un With

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub Boucles()
 Dim n As Long
 Dim sht As Worksheet
 
For Each sht In Worksheets
  With sht
    Debug.Print .Name
    If .Name <> "Feuil1" Then
      For n = .Range("A65536").End(xlUp).Row To 1 Step -1
        If InStr(.Range("A" & n), "Essai") = 0 Then .Rows(n).Delete
      Next n
    End If
  End With
Next sht
End Sub

Mytå_Qc

[Vadorblanc]

Bonjour Corona, Mercatog, Mytå_Qc
Un grand merci à tous les trois, chacune de vos proposition fonctionne.
Très cordialement à vous.

Mytå_Qc comment écris tu ton å dans ton nom ?