[VBA] Sélectionner un répertoire [Trucs & Astuces]

**skual** · 28/02/2006, 09h04

Bonjour tout le monde,

J'ai un controle TextBox et un bouton Parcourir. J'aimerai que, quand je clique sur Parcourir s'ouvre une boite permettant de sélectionner un répertoire.
J'essayé GetOpenFileName mais cela ne marche que pour des fichiers.
J'ai aussi vu quelques sujet la dessus mais pour du Visual Basic.
Y a-t-il un moyen de faire cela simplement en VBA?

Merci d'avance.

**ouskel'n'or** · 28/02/2006, 09h18

Regarde Dialogs, dans l'aide. Mais peut-être

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Application.Dialogs.Item(xlDialogOpen).Show

A+

PS - Il y a une autre méthode mais là, tout de suite, elle m'échappe. Il y aura bien quelqu'un pour te la donner...

Edit
Je vois que tu n'est pas un nouveau venu sur le forum, donc, tu devrais savoir que les majuscules sont prohibées dans le sujet hormis pour signaler VB / VBA ...
Donc, change ton titre. Débutant est inutile, à ta question, on le verra tout de suite

**skual** · 28/02/2006, 09h47

Cette collection Dialogs est très complète mais je n'y trouve rien pour sélectionner un répertoire.

Quant à:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Application.Dialogs.Item(xlDialogOpen).Show

Elle ne permet de sélectionner qu'un fichier et non un répertoire et ne renvoie pas le chemin du fichier.

Désolé pour les majuscules (je me disais que si on en utilise pour VB/VBA on pouvait aussi en utiliser pour le reste) mais c'était pas pour crier.

**ouskel'n'or** · 28/02/2006, 10h21

Elle ne permet de sélectionner qu'un fichier et non un répertoire

Si, une fois le fichier ouvert

et ne renvoie pas le chemin du fichier.

Si, une fois le fichier ouvert.
Mais j'ai vu passer la réponse précise à ta question sur le forum. Réponse donnée par DarkVader. Un peu de recherche dans ses réponses d'il y a 15 jours / 3 semaines...

Bonne chance

**skual** · 28/02/2006, 10h49

Bon, j'ai trouvé un sujet qui se rapproche ici http://www.developpez.net/forums/vie...731&highlight=
mais je n'ai pas trop compris en fait.

Tant pis, mon chemin de répertoire sera entré manuellement sans passer par une boite de dialogue Parcourir.

Merci quand même ouskel'n'or. Bonne journée. 8)

**repié** · 28/02/2006, 10h57

Et la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.GetFolder

elle ne fait pas ce que tu cherche?

**skual** · 28/02/2006, 11h11

Apparemment, cette méthode ne renvoie pas un chemin mais un objet Folder et il faut lui spécifier un chemin en argument (chemin que l'on n'est pas censé connaître).

Mais je sais pas trop en fait, je ne vois pas trop comment l'utiliser.

:

**repié** · 28/02/2006, 11h15

effectivement tu as raison, cette fonction ne semble pas pouvoir te servir

**SilkyRoad** · 28/02/2006, 11h17

bonjour

si tu disposes d'Office XP tu peux tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub selectionRepertoire_afficherChemin()
Dim Repertoire As FileDialog
 
Set Repertoire = Application.FileDialog(msoFileDialogFolderPicker)
Repertoire.Show
 
MsgBox Repertoire.SelectedItems(1)
End Sub

bonne journée
michel

**repié** · 28/02/2006, 11h19

ton code tourne aussi sur Office 2002!
Mais j'avoue qu'il est quand même bizarre à utiliser!

**SilkyRoad** · 28/02/2006, 11h31

Rebonjour Repié

Office XP et Office 2002 : c'est la meme chose

que veux tu dire par "bizarre à utiliser" ? ...;o)

bonne journée
michel

**repié** · 28/02/2006, 11h40

ah ok excuse j'ai pas réfléchis!

je trouve ca un peu bizarre parce que je n'avais jamais utilisé une interface telle que celle ci pour trouver un dossier

En fait, dans ma tête, la fenetre qui va demander un dossier c'est celle que certeins logiciels (tels que Winamp ou média player par exemple) propose.
Mais comme ce code fonctionne, c'est nickel!

je le retient!

**skual** · 28/02/2006, 11h51

OK merci SilkyRoad mais je suis sous Office 2000 (en entreprise donc difficile pour moi de réclamer XP rien que pour cela).

C'est dommage, la fonction est bien mais effectivement Office 2000 ne reconnaît pas le:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
FileDialog

Existe-t-il un équivalent pour Office 2000?

Merci.

**ThierryAIM** · 28/02/2006, 11h58

essaie avec ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2
Private Type BrowseInfo
    hwndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
 
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, _
        ByVal lpBuffer As String) As Long
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, _
        ByVal lpString2 As String) As Long
 
Public Function SelectFolder(Titre As String, Handle As Long) As String
Dim lpIDList As Long
Dim strBuffer As String
Dim strTitre As String
Dim tBrowseInfo As BrowseInfo
 
    strTitre = Titre
    With tBrowseInfo
        .hwndOwner = Handle
        .lpszTitle = lstrcat(strTitre, "")
        .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN
    End With
 
    lpIDList = SHBrowseForFolder(tBrowseInfo)
 
    If (lpIDList) Then
        strBuffer = String(255, vbNullChar)
        SHGetPathFromIDList lpIDList, strBuffer
        SelectFolder = Left(strBuffer, InStr(strBuffer, vbNullChar) - 1)
    End If
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub cmdModifDir_Click()
   Textbox1.Text = SelectFolder("Choisir le répertoire par défaut", 0)
End Sub

**skual** · 28/02/2006, 12h14

Génial Thierry AIM, j'ai eu un peu peur en voyant le code

(je débute) mais je dois dire que ça marche à merveille, je vais maintenant essayer de le comprendre.

Merci beaucoup.

**skual** · 02/03/2006, 14h52

Encore moi, je viens d'avoir un problème.

Le code de Thierry AIM marchait parfaitement bien jusqu'à aujourd'hui mais là après avoir desinstallé Microsoft Visual C++ et Basic 6 de mon PC (je n'utilise que l'éditeur VB d'Excel) j'ai une erreur ici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
strBuffer = String(255, vbNullChar)

Sur le String(....)

Erreur de type:

Erreur de compilation
Projet ou bibliothèque introuvable

Je crois que quand j'ai supprimé MVC++ et B 6, j'ai du supprimer des bibliothèques indispensable.

Je n'ai pourtant rien touché à Microsoft Excel et son éditeur VB.

Est ce je me trompe?
Faut-il rajouter une bibliothèque? Comment?

Merci..

**ouskel'n'or** · 02/03/2006, 17h30

Re-install Excel après l'avoir complètement désinstallé

A+

**skual** · 02/03/2006, 19h08

OK merci ouskel'n'or, je vais essayer ça.

Bonne soirée.

**ThierryAIM** · 02/03/2006, 22h37

tu as surement une référence marquée MANQUANTE dans ta liste de références de ton projet VBA
ca ne vient pas de la fonction String

**skual** · 03/03/2006, 12h26

En fait, je ne peux pas trop réinstaller Excel (je suis en entreprise).

Et bizarrement,après l'erreur de compilation, quand il m'affiche la liste des références, il n'y en a aucune précédée de MANQUANTE.

Je suppose qu'il est diificile de savoir à quelle référence fait précisement appel cette fonction de sélection du répertoire non?

Je crois que je n'ai plus trop de solutions si je ne peux pas réinstaller Excel...

Merci quand même.

[VBA] Sélectionner un répertoire [Trucs & Astuces]

VBA

Discussions similaires

Partager

Partager