Erreur de compilation, attendu : =

**locosr** · 20/04/2011, 15h14

Bonjour à tous.

J'ai dernièrement codé une function permettant de télécharger des données sur internet et de les reporter sur un classeur excel. Mais en réutilisant cette function dans ma sub je me heurte à un problème de compilation, attendu : =

Voici le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub download()

Dim name As String
Dim nbtitres As Integer
Dim a, b, c As Integer
Dim fund As Worksheet


nbtitres = Workbooks("Classeur1").Worksheets("Echantillon").Cells(Rows.Count, 2).End(xlUp).Row - 1

Workbooks("classeur1").Worksheets.Add Count:=(nbtitres), after:=Worksheets("echantillon")


For a = 2 To nbtitres


name = "http://ichart.finance.yahoo.com/table.csv?s=%5EIRX&d=3&e=20&f=2011&g=d&a=0&b=4&c=1960&ignore=.csv"
fund = sheets(a)
fnyahoohistquery (name,fund)
Workbooks("classeur1").Worksheets(a).name = Workbooks("classeur1").Worksheets("Echantillon").Cells(a, 1)
Next a



End Sub

Le problème apparait sur la ligne "fnyahoohistquery(name,fund)".
Il est possible que le soucis vienne de la function elle même, je vous cache pas que je suis novice en VBA. A noter que pour coder ma function je n'ai pas utilisé de variant.

Merci d'avance.

**mercatog** · 20/04/2011, 15h23

Soit
1. Remplace ta fonction par une Sub et fais l'appel comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Call fnyahoohistquery(name, fund)
'Ou fnyahoohistquery name, fund

Soit
2. Affecte ta fonction à une variable de même type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
X = fnyahoohistquery(name, fund)

**locosr** · 20/04/2011, 15h37

Merci pour cette réponse rapide, je vais essayer de remanier mon code en suivant tes conseils et voir ce que ça donne.

Une autre question, jusqu'à présent je codais des function qui renvoyaient à des valeurs. Du genre calculer des indicateurs statistiques que je mettais dans un variant. Mais cette function ne renvoie pas vraiment à une valeur, c'est en fait un processus de téléchargement d'un classeur excel présent sur le net, et ensuite un report des données du classeur vers un autre classeur. Est-ce que cela peut entraver ma sub ?

**mercatog** · 20/04/2011, 15h47

La réponse de ta question est déjà donnée.
Tu peux faire une fonction (sans pour autant attendre un résultat précis contenu dans la fonction en sortie). Pour ce cas, utilise plutôt une Sub

Dans un code, on appelle de 2 manières différentes une procédure (Sub) ou une fonction (Function)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Call NomProcedure(Parametre) 'Appel d'une sub
X=NomFonction(Parametre) 'Affectation de la fonction vers X

Exemple simple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function Simple(ByVal x As String) As Byte
 
MsgBox x
End Function
 
Sub Test()
Dim t As Byte
 
t = Simple("CouCou")
MsgBox t
End Sub

La fonction Simple n'engendre aucune valeur. Dans ce cas, il es préférable de faire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Simple(ByVal x As String)
 
MsgBox x
End Sub
 
Sub Test()
 
Call Simple("CouCou")
'ou
'Simple "Coucou" 'sans la call et sans les parenthèses
End Sub

**locosr** · 20/04/2011, 15h54

Merci beaucoup, je vais essayer de développer tout ça dans mon coin

**pgz** · 20/04/2011, 18h19

Bonjour.

Tu peux aussi appeler une fonction par Call si tu n'as pas besoin de la valeur renvoyée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function fCoucou() As Boolean
MsgBox "coucou"
fCoucou = True
End Function
 
Sub testCoucou()
Call fCoucou
End Sub

Cordialement,

PGZ

**locosr** · 20/04/2011, 19h33

Merci pour ces précisions

J'ai également besoin d'un pti coup de pouce sur ma function :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks("table").Worksheets("table").Cells(1, 1).Resize(L, c).Copy Destination:=Workbooks("classeur1").worksheets(1).Cells(1, 1)

J'ai cette ligne de code dans ma function. En gros une fois que le classeur internet à été téléchargé, les données sont reportées sur une feuille de mon classeur initiale. Le seul problème c'est que je vais sélectionner plusieurs classeurs internet qui doivent être reportés sur plusieurs feuilles de mon classeur initiale.

Initialement j'avais créé ma function pour un seul téléchargement qui devait être reporté sur la feuil1. Mais comme vous l'avez vu ma sub est prévue pour télécharger plusieurs données, comment puis je adapter ma function pour que le report se fasse sur le nombre de feuilles adaptées ?

En fait j'ai ma fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Function fnyahooHistQuery(name As String, fund As Worksheet) As Variant

Dim L, c, i, j As Integer

Dim x As Boolean
Dim rg1, rg2 As Range

Workbooks.Open Filename:=name
        
        
        L = Workbooks("table").worksheets("table").Cells(Rows.Count, 1).End(xlUp).Row
        
        c = Workbooks("table").worksheets("table").Cells(1, Columns.Count).End(xlToLeft).Column
        


Workbooks("table").worksheets("table").Cells(1, 1).Resize(L, c).Copy Destination:=Workbooks("classeur1").fund.cells(1,1)



Set rg1 = Workbooks("table").worksheets("table").Cells(1, 1).Resize(L, c)
Set rg2 = Workbooks("classeur1").worksheets(2).Cells(1, 1).Resize(L, c)



For i = 1 To L
For j = 1 To c

If rg1(i, j).Value = rg2(i, j).Value Then

x = True
       Else
         x = False
            End If
            
Next j, i

If x = True Then
MsgBox "True"
Else
MsgBox "False"
End If



Workbooks("table").Close



End Function

Et c'est cette ligne qui ne tourne pas, j'obtiens "erreur d'execution '438', propiété ou méthode non gérée par l'objet". Pour le coup je vois pas ce qui cloche.

**pgz** · 20/04/2011, 21h20

Bonsoir.

Dans les paramètres de ta fonction, si fund est un objet feuille, alors au lieu de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks("classeur1").fund.cells(1,1)

Tu devrias écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

fund.cells(1,1)

Cordialement,

PGZ

**locosr** · 20/04/2011, 21h27

Excellent. Encore une fois merci beaucoup pour ton aide

**mercatog** · 20/04/2011, 21h51

Essaies comme ceci en instanciant convenablement les variables objets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
Private Sub fnyahooHistQuery(Nom As String, Fund As Worksheet)
Dim Wbk As Workbook
Dim Sh As Worksheet
Dim Rg1 As Range, Rg2 As Range
Dim L As Long, i As Long
Dim C As Integer, j As Long
Dim x As Boolean
 
Set Wbk = Workbooks.Open(Nom)
Set Sh = Wbk.Worksheets("table")
With Sh
    L = .Cells(.Rows.Count, 1).End(xlUp).Row
    C = .Cells(1, .Columns.Count).End(xlToLeft).Column
    Set Rg1 = .Cells(1, 1).Resize(L, C)
End With
Set Sh = Nothing
 
Rg1.Copy Fund.Cells(1, 1)
 
' partir d'ici, c'est quoi l'intérêt?
Set Rg2 = ThisWorkbook.Worksheets(2).Cells(1, 1).Resize(L, C)
For i = 1 To L
    For j = 1 To C
        If Rg1(i, j).Value = Rg2(i, j).Value Then
            x = True
        Else
            x = False
            Exit For
        End If
    Next j
    If Not x Then Exit For
Next i
Set Rg1 = Nothing
Set Rg2 = Nothing
Wbk.Close False
Set Wbk = Nothing
If x = True Then
    MsgBox "True"
Else
    MsgBox "False"
End If
End Sub
 
 
Sub Download()
Dim Sh As Worksheet
Dim NbTitres As Integer, i As Integer
Dim Nom As String
 
Application.ScreenUpdating = False
Nom = "http://ichart.finance.yahoo.com/table.csv?s=%5EIRX&d=3&e=20&f=2011&g=d&a=0&b=4&c=1960&ignore=.csv"
With ThisWorkbook
    NbTitres = .Worksheets("Echantillon").Cells(Rows.Count, 2).End(xlUp).Row - 1
    .Worksheets.Add Count:=(NbTitres), After:=.Worksheets("echantillon")
    For i = 2 To NbTitres
        Set Sh = .Worksheets(i)
        Call fnyahooHistQuery(Nom, Sh)
        Sh.name = .Worksheets("Echantillon").Cells(i, 1).Value
        Set Sh = Nothing
    Next i
End With
MsgBox "Traitement terminé..."
End Sub

Je me demande de l'intérêt de faire les boucles de test (cf. commentaire)

**locosr** · 20/04/2011, 21h58

Merci pour ce complément

Pour la boucle de test, c'est simple le prof voulait un message de confirmation une fois le téléchargement terminé. Ne voyant pas l'intérêt d'afficher un signal une fois le classeur internet ouvert, j'ai préféré afficher mon signal une fois le transfert globale achevé, et pour ce faire je vérifie bien la présence du tableau sur mon classeur initial

Erreur de compilation, attendu : = [XL-2007]

Macros et VBA Excel

Discussions similaires

Partager

Partager