Discussion :

[yzf-r]

Bonjour,

Je souhaiterai savoir s'il est possible d'utiliser une liste en VBA et comment récupérer les valeurs du "row label" (voir pièce jointe) d'une pivot table dans une liste donc.

Le but est de pouvoir utiliser chaque entrée dans une autre fonction.
J'ai pensé à un while comme ci-dessous par exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
        While "entré de ma liste" <> "Grand Total"
 
            CaptureCallLogHistory "entré de ma liste"
 
        Wend

une idée?

[pgz]

Bonsoir.

Ton champ de ligne a un nom. Tu peux instancier ce champ et lire la collection de ses éléments

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
dim pvtIt as Excel.PivotItem
For each pvtIt in ThisWorkbook.Worksheets("NomFeuille").PivotTables("NomTCD").RowFields("NomChamp").PivotItems
    call Maprocedure(pvtIt.Name)
Next pvtIt

En espérant que cela t'aide,

PGZ

[yzf-r]

Merci PGZ,

ca marche nickel, je pensais pas que cela pouvait se faire aussi rapidement (avec aussi peu de ligne de code)
Ça fonctionne mais à un détail prés dans mon cas.

Le each passe en revue toutes les valeurs du "row label", même celles qui ne sont pas affiché (comme tu peux le voir en pièce jointe), car pas valeur.
Du coup, ma procédure plante ensuite, tu sais pourquoi

Hier tu m'as donné l'astuce pour afficher les colonnes même quand celle-ci n'ont pas de valeur, ce qui est parfait pour mon cas.

Par contre, je n'ai pas trouvé comment afficher les "row label" dans ce cas. Est-ce possible?
Ou devrais-je faire un test ensuite dans mon procédure genre:

"Si" pvtIt.Name "est dans le row label de mon de ma 2éme pivotabel" alors

Mais la pareil, il faut que le check se fasse sur ceux affichés.
Mais je pense que tout serait réglé s'il est possible d'afficher la liste complète.

merci par avance

[pgz]

Bonjour.

Le champ de ligne fonctionne comme le champ de colonne. Tu peux regler ses paramètres (Field settings) avec l'option "Show items with no data", et tous les éléments du champ seront affichés.

Sinon, tu peux savoir si un élément a des données en testant la valeur de sa propriété recordcount. Cela donnerait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
dim pvtIt as Excel.PivotItem
For each pvtIt in ThisWorkbook.Worksheets("NomFeuille").PivotTables("NomTCD").RowFields("NomChamp").PivotItems
    If pvtIt.recordcount > 0 then call Maprocedure(pvtIt.Name)
Next pvtIt

COrdialement,

PGZ

[yzf-r]

RRRRRah! presque.

J'avoue que je préfèrerai ne pas avoir à afficher les row sans valeur car ensuite mes graphes qui en dépendent sont moins "propre".
Néanmoins, avec toutes les rows affichées, cela fonctionne nickel.

J'ai tenté le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If pvtIt.recordcount > 0

, cela ignore bien la row "blank" mais pas la row "jer" dans mon exemple.

Désolé, j'ai oublié de joindre l'image dans mon précédent message.

[yzf-r]

je voulais dire "Jes", c'est "Jes" qui n'a pas de valeur et qui et quand même traité malgré le fait qu'elle n'apparaisse pas dans la pivottable.

[pgz]

Bonjour.

J'ai tenté le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If pvtIt.recordcount > 0

, cela ignore bien la row "blank" mais pas la row "jer" dans mon exemple.

Si l'élément "jes" n'a pas de valeurs, alors sa propriété RecordCount doit être à 0.

SI ce n'est pas le cas, ce n'est pas normal et j'aimerais bien savoir la valeur renvoyée. Pour le savoir, tu peux modifier le programme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
dim pvtIt as Excel.PivotItem
For each pvtIt in ThisWorkbook.Worksheets("NomFeuille").PivotTables("NomTCD").RowFields("NomChamp").PivotItems
    Debug.print pvtit.name & " : " & pvtit.RecordCount
    'If pvtIt.recordcount > 0 then call Maprocedure(pvtIt.Name)
Next pvtIt

Peux-tu faire cet essai et dire ce que tu lis pour "jes"?

PGZ

[yzf-r]

la valeur est 18.
Après vérification, c'est donc à cause de mon "report filter", voir pièce jointe.

Je filtre les entrées, c'est pour cela que "jes" n'apparait.
Si j'affiche tout alors, la valeur est alors de 18

[pgz]

Bonsoir.

Si je comprends bien, c'est un filtrage sur le champ de colonne qui empêche l'affichage de "jes" alors que cet item a la propriété Visible = True et la propriété RecordCount > 1.

SI c'est cela, tu peux essayer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim oRng As Excel.Range
Dim pvtIt As Excel.PivotItem
 
For Each oRng In ThisWorkbook.Worksheets("NomFeuille").PivotTables("NomTCD").RowRange.Cells
    On Error Resume Next
        Set pvtIt = ThisWorkbook.Worksheets("NomFeuille").PivotTables("NomTCD").RowFields("NomChampDeLigne").PivotItems(oRng.Value)
        If Err.Number = 0 Then call Maprocédure(pvtIt.Name)
    On Error GoTo 0
Next oRng

Cordialement,

PGZ

[yzf-r]

C'est exactement ça

merci PGZ

si je peux abuser de ta bonté, j'aurai une dernière requête.
Existe-t-il une commande simple en VBA pour faire un refresh de toutes les pivottable d'un workbook.

Pour l'instant, je le fais sheet aprés sheet:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub RefreshAllWorksheetPivots()
 
Dim pt As PivotTable
 
    Sheets("ARM Incoming APOs").Select
    For Each pt In ActiveSheet.PivotTables
        pt.RefreshTable
    Next pt
.......

[pgz]

Bonsoir.

Tu commences par scruter les feuilles.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub RefreshAllWorksheetPivots()
 
Dim pt As Excel.PivotTable
Dim oSh as Excel.Worksheet
 
application.ScreenUpdating = False 
 
For each oSh in thisworkbook.WorkSheets
    For Each pt In osh.PivotTables
        pt.RefreshTable
    Next pt
next oSh
 
Application.ScreenUpdating = True

Mais attention : au cas où tous les TCD utilisent les mêmes données, il est préférable de leur affecter un unique cache commun à tous les TCD. Dans ce cas, tu peux te contenter de rafraîchir ce cache. Par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ThisWorkbook.PivotCaches("NomCache").Refresh

Cordialement,

PGZ