Discussion :

[Dbiche]

Bonjour à tous,

Je suis un peu novice en matière de macro c'est pourquoi j'ai besoin de votre aide.

Voila ce que je veux que ma macro fasse :
Il y a, dans un premier onglet, un tableau qui récapitule pour le nom de chacun des onglets de mon classeur (59 onglets pour le moment mais il pourra y en avoir plus)
Je veux que ma macro se réfère à se tableau pour copier chacun des onglets suivants (de façon indépendante) pour qu'ils deviennent chacun un fichier différent. En gros, je veux que mes 59 onglets deviennent 59 classeurs et qu'ils s'enregistrent grace à un chemin pré-définit dans mon tableau.
J'ai utilisé la boucle Do While avec un compteur mais la macro ne me copie et enregistre que la premier onglet sur les 59 et je ne comprends pas pourquoi... :/

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Macro_ventil_onglet_ETPDAC2()
 
Dim Var_Nom_Classeur As String
Dim Var_Destination_Fichiers As String
Dim Var_Période As String
Dim Var_Onglet As String
Dim Var_CB As Integer
 
Var_CB = 15
Var_Destination_Fichiers = Cells(7, 1).Value
Var_Onglet = Cells(Var_CB, 1).Value
Libellé_Fichier = Cells(Var_CB, 4).Value
Var_Nom_Classeur = Cells(4, 1).Value
 
Worksheets("Macro").Activate
 
 
Do While Cells(Var_CB, 1).Value <> ""
Sheets(Var_Onglet).Select
Sheets(Var_Onglet).Copy
ActiveWorkbook.SaveAs Filename:= _
Libellé_Fichier, FileFormat:=xlNormal, Password:="", WriteResPassword:="", _
ReadOnlyRecommended:=False, CreateBackup:=False
Var_CB = Var_CB + 1
Loop
 
 
End Sub

Merci par avance de votre aide.

[MarcelG]

Bonjour,

Plutôt que d'utiliser la méthode Do While, pourquoi ne pas balayer les cellules de chaque ligne de ton tableau par la méthode For...Next ?

Je ne sais pas comment est structuré ton tableau.

Tu peux adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Sub Essai()
Dim cel As Range
With ThisWorkbook
    For Each cel In .Sheets("Tableau").Range("A3:A4")
            nomfich = cel.Value
            .Sheets(nomfich).Copy
            monrépertoire = .Sheets("Tableau").Range("D3").Value
            ActiveWorkbook.SaveAs Filename:=monrépertoire & Application.PathSeparator & nomfich
    Next
End With
End Sub

[Philippe Tulliez]

Bonjour,
Il est normal que cela ne fonctionnait pas, tu lis les informations de nom de feuille avant ta boucle donc tu avais beau incrémenter avec VAR_CB cela ne servait à rien.
Je ne sais pas non plus à quoi sert ta variable Var_Nom_Classeur que tu n'utilises nulle part dans le code.
Le code ci-dessous fonctionne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Option Explicit
Sub Macro_ventil_onglet_ETPDAC2()
  Dim Var_Nom_Classeur As String
  Dim Var_Destination_Fichiers As String
  Dim Var_Période As String
  Dim Var_Onglet As String
  Dim Var_CB As Integer
  Dim Libellé_Fichier As String
  Dim sht As Worksheet, wkb As Workbook
  Set wkb = ThisWorkbook
  Set sht = wkb.Worksheets("Macro")
  Var_CB = 15
  Var_Destination_Fichiers = Cells(7, 1): Var_Nom_Classeur = Cells(4, 1)
  While sht.Cells(Var_CB, 1) <> ""
    With sht
     Var_Onglet = .Cells(Var_CB, 1)
     Libellé_Fichier = .Cells(Var_CB, 4)
    End With
    Debug.Print Var_Onglet
    wkb.Sheets(Var_Onglet).Copy
    ActiveWorkbook.SaveAs Filename:=Var_Destination_Fichiers & Libellé_Fichier
    ActiveWorkbook.Close
    Var_CB = Var_CB + 1 
  Wend
End Sub

[Dbiche]

Corona tu es mon sauveur !!
J'ai pas encore tout compris sur ta macro mais elle fonctionne !! Tu es génial ! Merciiiii !!

Merci aussi à toi MarcelG pour ton aide !

Bonne journée.