par , 22/01/2020 à 15h58 (1439 Affichages)
Introduction
Entrez VRAI en cellule A2 et multipliez le contenu de cette cellule par 100.
Vous obtiendrez 100 alors que si vous entrez FAUX, le résultat renvoyé sera 0
Que pouvons-nous en conclure ? Que VRAI vaut 1 et FAUX vaut 0
Sachant cela, voyons des exemples concrets avec la liste de données illustrée ci-dessous
L’équivalent d’un SI
Imagions une ville qui accorderait une prime de 50 € à toutes personnes ayant des enfants.
Sans savoir qu’une valeur logique se multiplie, nous utiliserions bien entendu instinctivement la fonction SI en tapant en cellule E2 et suivantes la formule =SI(C2>0 ;50 ;0) ou si les données sont converties en tableau structuré =SI([@Enfant]>0 ; 50 ; 0)
Au lieu de cela, nous écrirons =(C2>0) * 50 ou ([@Enfant]>0) * 50
L’équivalent d’un SI avec un ET imbriqué
Pour effectuer l’équivalent d’un ET, il y a lieu de multiplier tous les tests logiques
Une prime de 50 € est accordée à toutes personnes de sexe féminin, ayant des enfants et habitant la commune de Moulinsart
La formule avec une plage classique
=(B2="F") * (C2>0) * (D2="Moulinsart") * 50
La formule avec un tableau structuré
=([@Sexe]="F") * ([@Enfant]>0) * ([@Habitant]="Moulinsart") * 50
L’équivalent d’un SI avec un OU imbriqué par addition
Pour effectuer l’équivalent d’un OU, il y a lieu d’additionner tous les tests logiques et de tester le résultat de cette addition par l’opérateur de comparaison > soit >0
La prime est accordée à toutes personnes habitant Moulinsart OU ayant des enfants
La formule avec une plage classique
=( ( (C2>0) + (D2="Moulinsart") ) >0 ) * 50
La formule avec un tableau structuré
=((([@Enfant]>0) + ([@Habitant]="Moulinsart"))>0) * 50
Consulter le profil
Marquer ce blog comme lu
