Forum du club des d�veloppeurs et IT Pro - Blogs - jimbolion

R�solution des probl�mes fr�quemment rencontr�s dans l'�criture des requ�tes �crites en vba

jimbolion — Sun, 07 Feb 2016 05:55:13 GMT

J'ai souvent vu passer de nombreux fils de discussion suite aux probl�mes rencontr�s lors de l��criture de requ�tes SQL en VBA. Je ne vais pas dans ce blog d�crire l'exhaustivit� de ces cas souvent li�s � la conception m�me de la requ�te mais repr�ciser les bonnes pratiques et les erreurs � ne pas commettre.

Avant tout un petit rappel sur la syntaxe du VBA et les bonnes pratiques :

Le langage Visual basic s'�crit sous la forme d'un texte � raison d'une d�claration ou une instruction par ligne. Un renvoi � la ligne est toutefois r�alisable � l'aide de la notation _ ; il est possible de placer plusieurs instructions sur une seule ligne � l'aide de la notation :, ainsi que d'intercaler des lignes vides ou de placer un commentaire en fin de ligne ou entre les lignes. Il est sage d'encadrer les symboles (&, :, etc.) par au-moins un espace. Les noms, d�finis par Visual basic (mot-clefs, constantes, etc.) ou cr��s par le programmeur, peuvent s'�crire indiff�remment en lettres minuscules ou majuscules (pas de diff�renciation). Toutefois il est recommand� d'utiliser des normes dans l'utilisation des noms ou des champs.

Un type d�finit la nature d'une variable ou d'un param�tre, qui peut �tre un type �l�mentaire : Boolean, Integer, Long, Byte, Single, Double, String, Currency, date, Object, Variant, Enum ou un type compos� � l'aide du mot-clef Type, ou une classe.

liste de d�clarations : Les types de variables et constantes utilis�es doivent �tre d�clar�es dans l'en t�te de la fonction ou de la proc�dure gr�ce aux mots cl�s Dim, Private, Public et const.
Code : S�lectionner tout - Visualiser dans une fen�tre � part
1
2
3
Exemples :
Dim Rsql As string, Madate As Date, manote as Single
Sub maFonction(MonNom As String, Madate As Date)
Me : Objet d�fini dans une proc�dure priv�e, associ�e g�n�ralement � un �v�nement ou un �l�ment d'une bo�te de dialogue (contr�le), d�signant l'objet � laquelle s'applique la proc�dure.

Nous allons donc � l'aide d'un exemple pr�cis, soulever quelques difficult�s et tenter de les r�soudre par des techniques qui jusque l� ne m'ont pos�es aucun souci.

Cr�ation de notre entit� de base nomm�e T_Eleves et des champs d�crivant son contenu :

id Num�roAuto
nomEleve Texte court
prenom Texte court
dateNais Date/Heure
moyenne Num�rique (R�el Simple)
Redoublant Oui/Non (Booleen)

La construction d'une requ�te repose sur quelques r�gles de base et principalement pour commencer celles-ci :

Toutes les valeurs de type texte doivent �tre encadr�s par des quotes (simples ou doubles),
Toutes les valeurs de type date doivent �tre encadr�s par des #.

Nous allons donc commencer par cr�er notre formulaire dont la source est bas�e sur notre entiv� T_Eleves afin de renseigner les diff�rentes valeurs. De nombreux tutoriels existent pour vous aider � r�aliser ces formulaires. Le notre plut�t simpliste n'est l� que pour parler de notre sujet principal.

Une image de ce formulaire nous donnerait l'effet visuel suivant :

Et le code g�n�r� sur l��v�nement sur clic du bouton :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub B_Save_Click() On Error GoTo Err_Commande Dim R_Sql As String ' If Not IsDate(Me.T_DateN) Then MsgBox "La date de Naissance est obligatoire", vbCritical, "Erreur Saisie" Me.T_DateN.SetFocus Exit Sub End If ' R_Sql = "INSERT INTO [T_Eleves] " & _ "(nomEleve, prenom, dateNais, moyenne, Redoublant) " & _ " VALUES (" & _ Nz(Me.T_nom, "") & "', " & _ Nz(Me.T_prenom, "") & "', " & _ "#" & Nz(Me.T_DateN, Null) & "#," & _ Nz(Me.T_Moyenne, 0) & ", " & _ Nz(Me.T_Redoublant, "") & _ ")" ' CurrentDb.Execute R_Sql, dbFailOnError ' Exit Sub Err_Commande: MsgBox Err.Description End Sub

En appliquant les r�gles cit�es pr�c�demment, nous devrions donc pouvoir injecter ces donn�es dans notre table T_Eleves. En cliquant sur le bouton nous op�rons donc sur l�ex�cution du code. Malheureusement, nous levons une erreur de ce type :

Le nombre de valeurs de la requ�te doit co�ncider avec le nombre de champs destination appara�t � l'�cran

La technique de d�bogage largement expliqu�e par Caf�ine dans son fameux tutoriel que voici :
Les techniques de d�bogage
nous permet donc d'afficher le r�sultat de notre cha�ne dans la fen�tre d'ex�cution de l'�diteur VBA

Code sql : S�lectionner tout - Visualiser dans une fen�tre � part

INSERT INTO [T_Eleves] (nomEleve, prenom, dateNais, moyenne, Redoublant) VALUES ('DUPONT', 'Martin',#04/02/1986#,10,5, -1)

En regardant de plus pr�s cette requ�te, nous constatons que 5 champs sont d�clar�s mais que 6 valeurs sont identifi�es. Notre 10,5 n'a pas �t� traduit par le code en 10.5 (SQL n'acceptant que des points pour les valeurs num�riques). Cette erreur ne sera soulev�e que pour les utilisateurs ayant conserv�s la virgule dans les s�parateurs num�riques du panneau de configuration. Si votre projet devait �tre d�ploy� sur d'autres ordinateurs, il vaut mieux int�grer directement ce contr�le dans votre code.

Afin de r�soudre ce probl�me nous allons donc cr�er une fonction standard dans un module sp�cifique. Cette fonction de type publique pourra donc �tre appel�e dans toutes les requ�tes construites par VBA dans l'ensemble du projet.

Code : S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
Function VirgToPoint(sValeur As String) As String ' Conversion implicite de format R�el en Cha�ne VirgToPoint = Replace(sValeur, ",", ".") End Function

et la modification de la ligne dans la proc�dure de notre formulaire :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

"" & VirgToPoint(Nz(Me.T_Moyenne, 0)) & ", " & _

Apr�s r� ex�cution du code une fois le correctif apport� notre requ�te devient :

Code sql : S�lectionner tout - Visualiser dans une fen�tre � part

INSERT INTO [T_Eleves] (nomEleve, prenom, dateNais, moyenne, Redoublant) VALUES ('DUPONT', 'Martin',#04/02/1986#,10.5, -1)

Aucun message d'erreur soulev� par l'�diteur, je vais de nature m�fiante v�rifier l'entr�e dans la table. A mon grand d�sarroi, je constate que la date du 4 f�vrier 1986 est devenue le 2 Avril 1986. Une autre r�gle est donc de formater notre date en format am�ricain ainsi cette portion de code � ins�rer dans le module d�di� :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
Public Function Convert_DateUS_Short(laDate As Date) As String ' Formate la date pass�e en argument en date US. Convert_DateUS_Short = Chr(35) & Format(laDate, "mm-dd-yyyy") & Chr(35) ' Date au format us End Function

et la modification de la ligne dans la proc�dure de notre formulaire :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

& Convert_DateUS_Short(Nz(Me.T_DateN, Date)) & "," & _

Une derni�re v�rification dans notre table pour v�rifier que l'entr�e est conforme et nous continuons notre saisie jusqu'� rencontrer un nouveau probl�me :

Lors de l'enregistrement, un message de ce type appara�t � l'�cran :

Erreur de syntaxe (op�rateur absent) dans l'expression "'D'ARCHAMBAULT', 'Martin',#09-09-1987#,14, -1)"

la quote �tant reconnue par SQL comme d�limiteur de cha�ne de caract�res, le nom d'archambault devra donc �tre prot�g� par un double simple quote. Nous �crirons donc une fonction de ce type :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
Function Protected_Quote(ChaineProtect As String) As String ' Fonction de protection visant � prot�ger les simple quotes et doublequotes dans les requetes SQL Protected_Quote = Replace(ChaineProtect, "'", "''") Protected_Quote = Replace(Protected_Quote, Chr(34), Chr(34) & Chr(34)) End Function

et modifierons notre appel dans la construction de notre fameuse requ�te :

Code : S�lectionner tout - Visualiser dans une fen�tre � part

"'" & Protected_Quote(Nz(Me.T_nom, "")) & "', " & _

En mode d�bogage voil� ce que nous donnerait la syntaxe de notre requ�te :

Code sql : S�lectionner tout - Visualiser dans une fen�tre � part

INSERT INTO [T_Eleves] (nomEleve, prenom, dateNais, moyenne, Redoublant) VALUES ('D''ARCHAMBAULT', 'Martin',#09-09-1987#,14, 0)

Une derni�re v�rification dans notre table afin de v�rifier la saisie de nos deux �l�ves :

Apr�s lecture de ce billet, vous pourrez sereinement construire vos requ�tes en VBA en toute qui�tude. Les techniques d�crites ci-dessus s'appliquent �galement aux requ�tes de type Update (mise � jour).

le code complet du bouton clic apr�s transformations et appels aux fonctions

Code : S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub B_Save_Click() On Error GoTo Err_Commande Dim R_Sql As String ' If Not IsDate(Me.T_DateN) Then MsgBox "La date de Naissance est obligatoire", vbCritical, "Erreur Saisie" Me.T_DateN.SetFocus Exit Sub End If ' R_Sql = "INSERT INTO [T_Eleves] " & _ "(nomEleve, prenom, dateNais, moyenne, Redoublant) " & _ " VALUES (" & _ Protected_Quote(Nz(Me.T_nom, "")) & "', " & _ Protected_Quote(Nz(Me.T_prenom, "")) & "', " & _ & Convert_DateUS_Short(Nz(Me.T_DateN, Date)) & ", " & _ VirgToPoint(Nz(Me.T_Moyenne, 0)) & ", " & _ Nz(Me.T_Redoublant, "") & _ ")" ' CurrentDb.Execute R_Sql, dbFailOnError ' Exit Sub Err_Commande: MsgBox Err.Description End Sub

Bonne lecture � tous

JimboLion

G�rer autrement les variables publiques

jimbolion — Sat, 09 Jan 2016 16:11:07 GMT

Je vais traiter dans cette partie ma fa�on de g�rer une table Param�tres afin de conserver les valeurs au gr� du d�roulement d'un applicatif.
Vous aurez compris, l'int�r�t d'une table Param�tres permet de conserver les valeurs acquises m�me lorsqu'une erreur est lev�e par l'applicatif (en effet le contenu des variables globales est alors effac�). Un autre int�r�t est de pouvoir visualiser rapidement le contenu de ces dites variables, rien de plus frustrant que de chercher dans le code la valeur d'une variable et l'endroit ou son contenu a �t� modifi�.

Nous allons dans ce post en mode pas � pas apprendre � construire nos premiers outils d'aide au d�veloppement.

1. Construction de la table :

Cette entit� est compos� de deux champs nomm�s description et valeur. Description d�fini donc le type de variable alors que valeur d�crit son contenu.

2. La partie VBA :

Afin d'utiliser cette table et la nourrir de nos pr�cieuses informations il va nous falloir cr�er quelques fonctions :

L'insertion des valeurs
La r�cup�ration des valeurs
La suppression des valeurs

a) L'insertion des valeurs :

Cette fonction nous permet d'ins�rer des valeurs dans notre table, ainsi l'insertion d'un ID, d'une cl� ou toute autre information n�cessitant un archivage pour une utilisation ult�rieure. Cette fonction doit �galement contr�ler l'existence d'une cl� d�j� pr�sente, dans ce cas le type de requ�te ex�cut�e sera Update et non Insert. Afin de contr�ler l'existence d'une cl� nous utiliserons la fonction Dcount ici d�taill�e : https://support.office.com/fr-fr/art...a-11a64acbf3d3

Le code permet d'utiliser cette fonction :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Function InsertUpdate_Parametre(p_Description As String, p_Valeur As String) As Boolean
'
' Fonction permettant de Mettre à jour un Parametre dans la table T_Parametres
' la fonction détecte la présence de la clé dans ce cas update sinon Insert
' Retourne True si la fonction s'est correctement déroulée
 
On Error GoTo err_InsertUpdate_Parametre
'
' Inserer une nouvelle valeur dans les parametres
'
Dim R_Sql As String
If DCount("Valeur", "T_Parametres", "Description='" & p_Description & "'") = 0 Then
    R_Sql = "INSERT INTO [T_Parametres] " & _
        "(Description, Valeur) " & _
        " VALUES (" & _
        "'" & Nz(p_Description, "") & "', " & _
        "'" & Protected_Quote(Nz(p_Valeur, "")) & "'" & _
        ")"
Else
    '
    ' Modifier le contenu de la variable
    '
    R_Sql = "UPDATE T_Parametres SET T_Parametres.Valeur = '" & Protected_Quote(Nz(p_Valeur, "")) & "' WHERE (((T_Parametres.Description)='" & Nz(p_Description, "") & "'));"
End If
'
CurrentDb.Execute R_Sql, dbFailOnError
InsertUpdate_Parametre = True
Exit Function
err_InsertUpdate_Parametre:
    MsgBox Err.Description & Err.Number
    Exit Function
End Function

Cette fonction exige deux arguments � savoir la cl� de description et sa valeur ainsi l'utilisation de cette fonction pourrait s'op�rer de la mani�re suivante :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

InsertUpdate_Parametre "TVA_Normale",20.6

et l'alimentation dans la table T_Parametres nous fournirait ceci :

Il est � noter que la fonction retourne True si l'op�ration s'est correctement d�roul�e, l'utilisation du retour permettant d'anticiper certaines actions ou avertir l'utilisateur. La fonction Protected_Quote utilis�e g�re la pr�sence de quotes dans la cha�ne de caract�re entra�nant les erreurs d'interpr�tation de la requ�te.

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
Function Protected_Quote(ChaineProtect As String) As String
'
' Fonction de protection visant à protéger les simple quotes et doublequotes dans les requetes SQL
'
Protected_Quote = Replace(ChaineProtect, "'", "''")
Protected_Quote = Replace(Protected_Quote, Chr(34), Chr(34) & Chr(34))
End Function

b) R�cup�rer une valeur :

Lorsque les cl�s ont �t� enregistr�es dans la base, une fonction permet de r�cup�rer sa valeur ainsi le code suivant r�pond � cette probl�matique :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
Function Get_Parametre(p_Description As String) As String
    '
    ' Fonction permettant de retourner un Parametre depuis la table T_Parametres
    ' Retourne une chaine vide si aucune occurence détectée
    '
    Get_Parametre = Nz(DLookup("Valeur", "T_Parametres", "Description='" & p_Description & "'"), "")
End Function

Nous avons ici utilis� une fonction de domaine et principalement Dlookup. Je vous conseille la lecture de ce tutoriel afin de vous familiariser avec ces fonctions :

Les fonctions de domaines dans Access

A noter que si aucun valeur n'est trouv�e dans la table, la fonction renvoie une cha�ne vide.

un exemple d'utilisation :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

msgbox "Le taux de TVA est : " & Get_Parametre("TVA_Normale")

c) La suppression d'une valeur :

Il peut �tre utile de supprimer une cl� dans la table, voire �ventuellement la totalit� des entr�es. L'impl�mentation de ce code r�pond donc � cette situation :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Function Del_Parametre(Optional p_Description As String) As Boolean
    '
    ' Fonction permettant de supprimer un Parametre dans la table T_Parametres
    ' Retourne True si la fonction s'est correctement déroulée
    '
    Dim R_Sql As String
    On Error GoTo err_Del_Parametre
    Select Case Nz(p_Description, "")
    Case ""
 
        R_Sql = "DELETE T_Parametres.Description FROM T_Parametres;"
    Case Else
        R_Sql = "DELETE T_Parametres.Description FROM T_Parametres WHERE (((T_Parametres.Description)='" & p_Description & "'));"
    End Select
    CurrentDb.Execute R_Sql, dbFailOnError
    Del_Parametre = True
    Exit Function
err_Del_Parametre:
    MsgBox Err.Description & Err.Number
    Exit Function
End Function

Il est � noter que le retour de la fonction renvoie True si elle s'est correctement d�roul�e. Nous remarquerons que l'argument Optional n'implique pas n�cessairement la pr�sence d'une valeur dans l'appel de la fonction. Si aucun argument n'est renseign�, cela nous permettra de vider le contenu complet de la table. Quelques exemples d'appel ci-dessous :

Code vba :

S�lectionner tout - Visualiser dans une fen�tre � part

1
2
Del_Parametre "TVA_Normale" ' efface l'entrée Taux de tva
Del_Parametre               ' Efface toutes les entrées de la table

JimBolion