Voir le flux RSS

JackIsJack

Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires

Noter ce billet
par , 22/12/2015 à 18h59 (1022 Affichages)
Bonjour,

Un exemple :

Code vb.net : Sélectionner tout - Visualiser dans une fenêtre à part
1
2
3
4
5
        Dim MonTimer As New TimerAnimation
 
        MonTimer.Transition(Me.PictureBox1, "Left", TimerAnimation.TypeTransition.easeInElastic, 400, 500, 1000)
 
        ' La propriété 'Left' de l'objet 'Picturebox1' va être modifié de la valeur 400 à la valeur 500, en 1000 millisecondes (1 seconde), de façon 'easeInElastic'

La classe à importer :

Code vb.net : Sélectionner tout - Visualiser dans une fenêtre à part
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
Public Class TimerAnimation
    Inherits Timer
 
    Private _Objet As Object
    Private _NomPropriete As String
    Private _Type As String
    Private _Debut As Integer
    Private _Fin As Integer
    Private _Duree As Integer ' Exprimée en millisecondes
    Private _ActionParSeconde As Integer
 
    Private t As Double
    Private NombreIteration As Integer
    Private IterationEnCours As Integer
    Private Change As Integer
 
    Public Property Debut() As Integer
 
        Get
            Return _Debut
        End Get
        Set(ByVal value As Integer)
            _Debut = value
        End Set
 
    End Property
 
    Public Property Fin() As Integer
 
        Get
            Return _Fin
        End Get
 
        Set(ByVal value As Integer)
 
            _Fin = value
 
            Change = _Fin - _Debut
 
        End Set
 
    End Property
 
    Public Property Duree() As Integer
 
        Get
            Return _Duree
        End Get
        Set(ByVal value As Integer)
 
            _Duree = value
 
            NombreIteration = Math.Round(_Duree / _ActionParSeconde, 0)
 
        End Set
    End Property
 
    Public Property ActionParSeconde() As Integer
 
        Get
            Return _ActionParSeconde
        End Get
 
        Set(ByVal value As Integer)
 
            _ActionParSeconde = value
 
            Me.Interval = _ActionParSeconde
 
            NombreIteration = Math.Round(_Duree / _ActionParSeconde, 0)
 
        End Set
    End Property
 
    Public Property Type() As TypeTransition
 
        Get
            Return _Type
        End Get
 
        Set(ByVal value As TypeTransition)
            _Type = value
        End Set
 
    End Property
 
    Public Property Objet() As Object
 
        Get
            Return _Objet
        End Get
 
        Set(ByVal value As Object)
 
            _Objet = value
 
        End Set
 
    End Property
 
    Public Property NomPropriete() As String
 
        Get
            Return _NomPropriete
        End Get
 
        Set(ByVal value As String)
 
            _NomPropriete = value
 
        End Set
 
    End Property
 
    Sub Transition(ByVal m_objet As Object, ByVal m_NomPropriete As String, ByVal m_Type As TypeTransition, ByVal m_Debut As Integer, ByVal m_Fin As Integer, ByVal m_Duree As Integer)
 
        Me.Objet = m_objet
        Me.NomPropriete = m_NomPropriete
        Me.Type = m_Type
        Me.Debut = m_Debut
        Me.Fin = m_Fin
        Me.Duree = m_Duree
 
        AddHandler Me.Tick, AddressOf ActualiserPropriete
 
        Me.Start()
 
    End Sub
 
    Private Sub ActualiserPropriete()
 
        Me.Actualiser()
 
        CallByName(_Objet, _NomPropriete, CallType.Set, Me.Easing())
 
    End Sub
 
    Public Sub New()
 
        ' Par défaut 
        ActionParSeconde = 20
        IterationEnCours = 0
        Me.Enabled = True
 
    End Sub
 
    Public Sub Actualiser()
 
        IterationEnCours = IterationEnCours + 1
 
        t = Me.IterationEnCours / Me.NombreIteration
 
    End Sub
 
    Function Easing() As Double
 
        If IterationEnCours > NombreIteration Then
 
            Me.Stop()
 
        End If
 
        Easing = EasingFunctions(_Type, t, Debut, Change, 1)
 
    End Function
 
    Enum TypeTransition
        easeInBack
        easeInBounce
        easeOutBounce
        easeInOutBounce
        easeInCirc
        easeInCubic
        easeInElastic
        easeInExpo
        easeInOutBack
        easeInOutCirc
        easeInOutCubic
        easeInOutElastic
        easeInOutExpo
        easeInOutQuad
        easeInOutQuart
        easeInOutQuint
        easeInOutSine
        easeInQuad
        easeInQuart
        easeInQuint
        easeInSine
        easeOutBack
        easeOutCirc
        easeOutCubic
        easeOutElastic
        easeOutExpo
        easeOutQuad
        easeOutQuart
        easeOutQuint
        easeOutSine
    End Enum
 
    Shared Function EasingFunctions(ByVal mode As String, ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Select Case (mode)
 
            Case TypeTransition.easeInBack
 
                EasingFunctions = easeInBack(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInBounce
 
                EasingFunctions = easeInBounce(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutBounce
 
                EasingFunctions = easeOutBounce(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutBounce
 
                EasingFunctions = easeInOutBounce(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInCirc
 
                EasingFunctions = easeInCirc(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInCubic
                EasingFunctions = easeInCubic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInElastic
 
                EasingFunctions = easeInElastic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInExpo
 
                EasingFunctions = easeInExpo(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutBack
                EasingFunctions = easeInOutBack(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutCirc
 
                EasingFunctions = easeInOutCirc(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutCubic
 
                EasingFunctions = easeInOutCubic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutElastic
 
                EasingFunctions = easeInOutElastic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutExpo
                EasingFunctions = easeInOutExpo(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutQuad
 
                EasingFunctions = easeInOutQuad(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutQuart
 
                EasingFunctions = easeInOutQuart(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutQuint
 
                EasingFunctions = easeInOutQuint(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInOutSine
 
                EasingFunctions = easeInOutSine(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInQuad
 
                EasingFunctions = easeInQuad(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInQuart
 
                EasingFunctions = easeInQuart(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInQuint
 
                EasingFunctions = easeInQuint(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeInSine
 
                EasingFunctions = easeInSine(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutBack
 
                EasingFunctions = easeOutBack(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutCirc
 
                EasingFunctions = easeOutCirc(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutCubic
 
                EasingFunctions = easeOutCubic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutElastic
 
                EasingFunctions = easeOutElastic(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutExpo
 
                EasingFunctions = easeOutExpo(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutQuad
 
                EasingFunctions = easeOutQuad(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutQuart
 
                EasingFunctions = easeOutQuart(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutQuint
 
                EasingFunctions = easeOutQuint(t, b, c, d)
                Exit Function
 
            Case TypeTransition.easeOutSine
 
                EasingFunctions = easeOutSine(t, b, c, d)
                Exit Function
 
            Case Else
 
                EasingFunctions = -1
 
        End Select
 
    End Function
 
    Shared Function easeInQuad(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeInQuad = c * t * t + b
 
    End Function
 
    Shared Function easeOutQuad(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeOutQuad = -c * t * (t - 2) + b
 
    End Function
 
    Shared Function easeInOutQuad(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = 2 * t / d
 
        If t < 1 Then
            '
            easeInOutQuad = (c / 2) * t * t + b
 
        Else
 
            t = t - 1
 
            easeInOutQuad = -c / 2 * (t * (t - 2) - 1) + b
 
        End If
 
    End Function
 
    Shared Function easeInCubic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeInCubic = c * (t) * t * t + b
 
    End Function
 
    Shared Function easeOutCubic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = (t / d) - 1
 
        easeOutCubic = c * (t * t * t + 1) + b
 
    End Function
 
    Shared Function easeInOutCubic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = 2 * t / d
        If (t < 1) Then
            easeInOutCubic = c / 2 * t * t * t + b
        Else
            t = t - 2
            easeInOutCubic = c / 2 * (t * t * t + 2) + b
        End If
 
    End Function
 
    Shared Function easeInQuart(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeInQuart = c * t * t * t * t + b
 
    End Function
 
    Shared Function easeOutQuart(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d - 1
        easeOutQuart = -c * ((t * t * t * t) - 1) + b
 
    End Function
 
    Shared Function easeInOutQuart(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = 2 * t / d
 
        If (t < 1) Then
            easeInOutQuart = c / 2 * t * t * t * t + b
        Else
            t = t - 2
            easeInOutQuart = -c / 2 * (t * t * t * t - 2) + b
        End If
 
    End Function
 
    Shared Function easeInQuint(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeInQuint = c * t * t * t * t * t + b
 
    End Function
 
    Shared Function easeOutQuint(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d - 1
        easeOutQuint = c * (t * t * t * t * t + 1) + b
 
    End Function
 
    Shared Function easeInOutQuint(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = 2 * t / d
        If (t < 1) Then
            easeInOutQuint = c / 2 * t * t * t * t * t + b
        Else
            t = t - 2
            easeInOutQuint = c / 2 * (t * t * t * t * t + 2) + b
        End If
 
    End Function
 
    Shared Function easeInSine(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        easeInSine = -c * Math.Cos((t / d) * (Math.PI / 2)) + c + b
 
    End Function
 
    Shared Function easeOutSine(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        easeOutSine = c * Math.Sin(t / d * (Math.PI / 2)) + b
 
    End Function
 
    Shared Function easeInOutSine(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        easeInOutSine = -c / 2 * (Math.Cos(Math.PI * t / d) - 1) + b
 
    End Function
 
    Shared Function easeInExpo(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        If t = 0 Then
            easeInExpo = b
        Else
            easeInExpo = c * Math.Pow(2, 10 * (t / d - 1)) + b
        End If
 
    End Function
 
    Shared Function easeOutExpo(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        If t = d Then
            easeOutExpo = b + c
        Else
            easeOutExpo = c * (-Math.Pow(2, -10 * t / d) + 1) + b
        End If
 
    End Function
 
    Shared Function easeInOutExpo(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        If t = 0 Then
            easeInOutExpo = b
            Exit Function
        End If
 
        If t = d Then
            easeInOutExpo = b + c
            Exit Function
        End If
 
        t = 2 * t / d
        If t < 1 Then
            easeInOutExpo = c / 2 * Math.Pow(2, 10 * (t - 1)) + b
        Else
            t = t - 1
            easeInOutExpo = c / 2 * (-Math.Pow(2, -10 * t) + 2) + b
        End If
 
    End Function
 
    Shared Function easeInCirc(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d
        easeInCirc = -c * (Math.Sqrt(1 - (t * t)) - 1) + b
 
    End Function
 
    Shared Function easeOutCirc(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = t / d - 1
        easeOutCirc = c * Math.Sqrt(1 - (t * t)) + b
 
    End Function
 
    Shared Function easeInOutCirc(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        t = 2 * t / d
        If t < 1 Then
            easeInOutCirc = -c / 2 * (Math.Sqrt(1 - t * t) - 1) + b
        Else
            t = t - 2
            easeInOutCirc = c / 2 * (Math.Sqrt(1 - t * t) + 1) + b
        End If
 
    End Function
 
    Shared Function easeInElastic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double = 1.70158
        Dim p As Double = 0
        Dim a As Double = c
 
        If t = 0 Then
            easeInElastic = b
            Exit Function
        End If
 
        t = t / d
        If t = 1 Then
            easeInElastic = b + c
            Exit Function
        End If
 
        p = d * 0.3
 
        If (a < Math.Abs(c)) Then
            a = c
            s = p / 4
        Else
            s = p / (2 * Math.PI) * Math.Asin(c / a)
        End If
 
        t = t - 1
        easeInElastic = -(a * Math.Pow(2, 10 * t) * Math.Sin((t * d - s) * (2 * Math.PI) / p)) + b
 
    End Function
 
    Shared Function easeOutElastic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double = 1.70158
        Dim p As Double = 0
        Dim a As Double = c
 
        If t = 0 Then
            easeOutElastic = b
            Exit Function
        End If
 
        t = t / d
        If t = 1 Then
            easeOutElastic = b + c
            Exit Function
        End If
 
        p = d * 0.3
 
        If (a < Math.Abs(c)) Then
            a = c
            s = p / 4
        Else
            s = p / (2 * Math.PI) * Math.Asin(c / a)
        End If
 
        easeOutElastic = a * Math.Pow(2, -10 * t) * Math.Sin((t * d - s) * (2 * Math.PI) / p) + c + b
 
    End Function
 
    Shared Function easeInOutElastic(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double = 1.70158
        Dim p As Double = 0
        Dim a As Double = c
 
        If t = 0 Then
            easeInOutElastic = b
            Exit Function
        End If
 
        t = 2 * t / d
        If t = 2 Then
            easeInOutElastic = b + c
            Exit Function
        End If
 
        p = d * 0.3 * 1.5
 
        If (a < Math.Abs(c)) Then
            a = c
            s = p / 4
        Else
            s = p / (2 * Math.PI) * Math.Asin(c / a)
        End If
 
        If t < 1 Then
            t = t - 1
            easeInOutElastic = -0.5 * (a * Math.Pow(2, 10 * t) * Math.Sin((t * d - s) * (2 * Math.PI) / p)) + b
        Else
            t = t - 1
            easeInOutElastic = a * Math.Pow(2, -10 * t) * Math.Sin((t * d - s) * (2 * Math.PI) / p) * 0.5 + c + b
        End If
 
    End Function
 
    Shared Function easeInBack(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double
        s = 1.70158
        t = t / d
        easeInBack = c * t * t * ((s + 1) * t - s) + b
 
    End Function
 
    Shared Function easeOutBack(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double
        s = 1.70158
        t = t / d - 1
        easeOutBack = c * (t * t * ((s + 1) * t + s) + 1) + b
 
    End Function
 
    Shared Function easeInOutBack(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        Dim s As Double
        s = 1.70158
 
        t = 2 * t / d
 
        If t < 1 Then
            s = s * 1.525
            easeInOutBack = c / 2 * (t * t * (((s) + 1) * t - s)) + b
        Else
            t = t - 2
            easeInOutBack = c / 2 * ((t) * t * (((s) + 1) * t + s) + 2) + b
        End If
 
    End Function
 
    Shared Function easeInBounce(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        easeInBounce = c - easeOutBounce(d - t, 0, c, d) + b
 
    End Function
 
    Shared Function easeOutBounce(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        If (t / d) < (1 / 2.75) Then
 
            t = t / d
 
            easeOutBounce = c * (7.5625 * t * t) + b
 
        ElseIf t < (2 / 2.75) Then
 
            t = t - (1.5 / 2.75)
 
            easeOutBounce = c * (7.5625 * t * t + 0.75) + b
 
        ElseIf t < (2.5 / 2.75) Then
 
            t = t - (2.25 / 2.75)
            easeOutBounce = c * (7.5625 * t * t + 0.9375) + b
 
        Else
 
            t = t - (2.625 / 2.75)
 
            easeOutBounce = c * (7.5625 * t * t + 0.984375) + b
 
        End If
 
    End Function
 
    Shared Function easeInOutBounce(ByVal t As Double, ByVal b As Double, ByVal c As Double, ByVal d As Double) As Double
 
        If t < d / 2 Then
            easeInOutBounce = easeInBounce(t * 2, 0, c, d) * 0.5 + b
        Else
            easeInOutBounce = easeOutBounce(t * 2 - d, 0, c, d) * 0.5 + c * 0.5 + b
        End If
 
    End Function
 
End Class

PS : Toutes les fonctions ont été traduites du javascript. Merci à l'auteur des fonctions javascript, Robert Penners.

Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Viadeo Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Twitter Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Google Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Facebook Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Digg Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Delicious Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog MySpace Envoyer le billet « Tween de contrôles VB.NET, animations, courbes de Bézier, transitions non-linéaires » dans le blog Yahoo

Mis à jour 29/07/2018 à 18h21 par LittleWhite (Coloration du code)

Catégories
DotNET , VB.NET

Commentaires