Discussion :

[rafar]

Bonjour à tous,
Après une longue recherche infructueuse sur ce forum et sur celui de pc-soft,
je me pose une question qui en contient plusieurs:
(d'avance pardon si cette question a déjà été posée, je crois que non)

Je suis développeur débutant et j'utilise WIN14;
je souhaite exporter les données d'une base hyperfile classique vers une base MySQL;
j'ai donc installé le module d'accès natif à MySQL (j'ai dû trouver la libmysql.dll sur google car elle était manquante...),
puis créé une base MySQL avec phpMyAdmin,
j'ai ensuite créé la structure de cette base selon la description de mon analyse grâce à HCréationSiInexistant("*").
J'ai donc 2 bases de structures identiques, l'une en HF contenant mes données (assez peu, les .fic sont légers), l'autre en MySQL, vide.

J'aimerais parcourir tous les .fic de ma base HF (sans doute grâce à HListeFichier?), les lire, et copier chaque enregistrement dans la table MySQL correspondante mais je ne sais pas comment m'y prendre.

Devrais-je passer chaque enregistrement ou même chaque .fic dans un tableau, (si oui, comment? Je n'arrive pas à gérer les tableaux en WLangage)
puis copier ce tableau dans une table MySQL avec un "ChangeConnexion" suivi d'un "HExecuteRequete (INSERT...)"?
Y'a-t-il une instruction WLangage spécifique qui me ferait gagner du temps, un peu comme HCréationSiInexistant mais pour les données?

Merci d'avance, désolé pour ces questions en vrac, j'essaie de faire un tir groupé..

[J0r_x]

Hlistefichier renvoie les fichiers présent dans l'analyse.
Pour chaque fichier présent dans la chaine renvoyé par Hlistefichier (utilise Extraitchaine() pour les récupérer) tu effectue une boucle et tu insères dans la base Mysql

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
w_liste_fichier = HListeFichier()
w_sousfichier = ExtraitChaîne(w_liste_fichier,rangPremier,RC)
TANTQUE w_sousfichier <> EOT
     //Lecture du fichier + insertion dans la base Mysql
     POUR TOUT {w_sousfichier,indfichier}
           //.....
     FIN
     w_sousfichier = ExtraitChaîne(w_liste_fichier,rangSuivant,RC)
FIN

[hpascal]

Bonjour
Tu peux facilement faire ça avec HCopieEnreg (voir l'aide)

Je suppose que chaque fichier est décrit une fois dans l'analyse

Admettons que ton fichier soit décrit en HF dans l'analyse tu créés un alias de ce fichier et tu fais pointer cet alias sur une autre connexion (mysql dans ton cas)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
HAlias(TONFICHIER, TONFICHIER_MySql)
HChangeNom(TONFICHIER_MySql, "TONFICHIER_MySql")
TONFICHIER_MySql..connexion = Cnx_MySql

et la description de Cnx_MySql :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Cnx_Mysql est une Connexion
 
Cnx_Mysql..Serveur = "localhost"
Cnx_Mysql..Provider = hAccèsNatifMySQL
Cnx_Mysql..Utilisateur = "user"
Cnx_Mysql..MotDePasse = "pwd"
Cnx_Mysql..BaseDeDonnées = "tabase"
Cnx_Mysql..Accès = hOLectureEcriture

et la copie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
POUR TOUT TONFICHIER
	HCopieEnreg(TONFICHIER_MySql, TONFICHIER)
	HAjoute(TONFICHIER_MySql)
FIN

Code vite fait, donc à corriger si j'ai fais des betises, mais le principe est là

et ceci pour tous tes fichiers dans la boucle donnée par J0r_x

[rafar]

Merci beaucoup à tous les deux!

Je vais tester tout ça et j'espère, bientôt mettre cette conversation en "résolu".

Cordialement.

[rafar]

eh bien j'ai finalement réussi grâce à vos conseils, mon programme marche parfaitement, vous m'avez fait gagner 2 semaines sur mon planning (je fais un stage de 3 mois pour valider une formation AFPA) et je vais pouvoir m'attaquer à webdev pour un projet qui utilisera MySQL;

en espérant que ça servira à d'autres, voilà mon code:

première procédure qui parcourt et copie un .fic vers une table MySQL

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
PROCEDURE pg_Export_donnees_vers_MySQL(TableHF)
alias est une Sources de Données	
HAnnuleAlias(alias)
HAlias(TableHF,"alias")
HChangeNom(alias,TableHF)
HChangeConnexion(alias,Cnx_prosygma)
HLitPremier(TableHF)
TANTQUE PAS HEnDehors(TableHF)		
	HCopieEnreg(alias,TableHF)
	SI	 HAjoute(alias) ALORS
		Info(alias)
	SINON 
		Erreur(HErreurInfo(hErrComplet))
		FinProgramme()	
	FIN	
	HLitSuivant(TableHF)
	HAnnuleAlias("*")
FIN

puis seconde procédure qui parcourt la base HyperFile et appelle la première:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
PROCEDURE pg_Export_TOTAL_vers_MySQL()
HOuvreConnexion(Cnx_HF)
HChangeConnexion("*",Cnx_HF)
w_liste_fichier,w_sousfichier est une chaîne
w_liste_fichier = HListeFichier()
w_sousfichier = ExtraitChaîne(w_liste_fichier,rangPremier,RC)
TANTQUE w_sousfichier <> EOT
	pg_Export_donnees_vers_MySQL(w_sousfichier)
	w_sousfichier = ExtraitChaîne(w_liste_fichier,rangSuivant,RC)
FIN

merci encore!

rafar

[hpascal]

Bonjour

Juste une chose, ton HAnnuleAlias("*") est mal placé, il devrait être en dehors de ta boucle
D'ailleurs visiblement il ne fait rien sinon tu aurais un plantage

Il me semble que le paramètre "*" ne permet pas d'annuler tous les alias, il faut spécifier le nom de l'alias (ou utiliser HAlias("*"))
Mais dans ton cas il suffit de mettre HAnnuleAlias(alias) en dehors de ta boucle

[rafar]

Yes! J'ai été un peu vite à poster, j'étais bien content d'avoir réussi...

En fait j'avais fait AUSSI ce dont tu parles:
j'ai un HAnnuleAlias(alias) en tout début de procédure, avant la boucle...
j'aurais dû effacer l'autre avant de mettre celui-là,
manque de rigueur...
en tout cas, bien observé!

thanks!

Par contre, j'ai une autre question, qui mérite sans doute une autre discussion..