[XL-2003] Additionner la valeur des cellules dont la date est pendant janvier 2010 ? [Résolu]

[[ZiP]]

Bonjour,

Quelle(s) formule(s) puis-je utiliser pour additionner la valeur des cellules de la ligne 2 où la date des cellules (au format date) de la ligne 1 est comprises au mois de janvier 2010 ?

J'ai essayé ça :

Code :

=SOMME.SI(1:1;ET(MOIS(1:1)=1;ANNEE(1:1))=2010;2:2)

Mais ça ne semble pas fonctionner et me retourne 0 au lieu de la bonne valeur !

Merci,
ZiP

[EmmanuelleC]

Comme critere, le somme.si attend un truc du genre "<01/02/2010" (qu'il va comparer avec la plage qu'on lui a indique en premier paramettre)

Donc on ne peut pas en mettre deux comme ca

Comme tu n'as pas excel 2007, passe par un somme prod

Code :

=SOMMEPROD(2:2*(MOIS(1:1)=1)*(ANNEE(1:1)=2010))

[[ZiP]]

Bonjour,

Effectivement, ça marche mieux avec SOMMEPROD !

Merci,
ZiP

[[ZiP]]

Je veux adapter l'exemple simple à mon tableau :



J'ai la formule suivante :

Code :

=SOMMEPROD( C3:C65536 * (MOIS(2:2)=2) * (ANNEE(2:2)=2010) )

Mais je n'y arrive pas, j'ai toujours #VALEUR! qui s'affiche...

Je voudrais additionner les cellules de C3 à C65536 pour chaque colonne où la date répond aux critères suivants : MOIS(2:2)=2 et ANNEE(2:2)=2010

Merci,
ZiP

[EmmanuelleC]

sommeprod nécessite que
1) les plages soient équivalentes (logique vu que le principe, c'est de faire la somme de deux case d'une plages qui se correspondent, si un des deux plages est plus grande que l'autre, il y aura des cellules dont il ne pourra rien faire)
2) que tout les paramettre soient des chiffres (donc il faut commencer apres les colonne d'entete pour le champ que tu veux additionner)

La, il me semble que tu mélanges des colonnes (C3:C65536 c'est vertical ca) avec des lignes (1:1 qui est horizontal)

Dans l'exemple de départ, tu essayais de sommer le contenu de la ligne 2 sur base de condition sur la ligne 1 non?
En voyant l'exemple, ce que tu veux, c'est pas le total de formation pour un nom, sur base d'un critiere de date? si oui, la formule serait sans doute (si la cellule avec DATES dedans est bien la cellule A1)

Code :

=SOMMEPROD(C3:IV3*(MOIS(C1:IV1)=1)*(ANNEE(C1:IV1)=2010))

(IV si tu veux aller jusqu'a la 256 colonne, mais tu peux probablement t'arreter avant)
Et comme tu as des plages qui vont chaque fois de la colonne C a la colonne IV, il peut faire des caculs en utilisant J3 et J1, AC3 et AC1,...

[[ZiP]]

Bonjour,

Effectivement, je mélange les colonnes et les lignes dans le calcul.

L'exemple de départ était simple pour comprendre le principe mais ne correspond pas exactement à ce que l'on me demande. C'était bien la somme du contenu de la ligne 2 sur base de condition sur la ligne 1.

Voici le fichier Excel avec les entêtes de colonne :



Je veux calculer le nombre d'heures total de formation pour un mois donné pour toutes les équipes et toutes les formations dont le critère de date correspond.

Merci,
ZiP

[[ZiP]]

Bonjour,

Votre formule était bonne, voici ce que j'ai pour le mois de janvier 2010 :

Code :

=SOMMEPROD($C$4:$BA$150*(MOIS($C$2:$BA$2)=1)*(ANNEE($C$2:$BA$2)=2010))

J'ai volontairement réduis la plage de recherche.

Merci !
ZiP