Discussion :

[tibofo]

Bonjour à tous,

J'ai trouvé des tas de post sur l'envoi d'email mais tous parlaient d'outlook, thunderbird....

Je voudrais savoir s'il est possible (et comment) envoyer un email avec un fichier txt en pièce jointe via un compte de messagerie internet (en l'occurence ici GMAIL) ?

En fait, je voudrais que cela envoie un email sans utiliser OUTLOOK ou autre, et sans ouvrir la fenêtre internet de Google Mail. Et que ce soit le plus transparent possible pour l'utilisateur (qu'il ne soit pas obligé de valider son compte, d'accepter l'envoi...)


Merci
Bonne année à tousse (bonne grippe, ... quoi !!!)

Thibault

[tibofo]

J'ai trouvé la solution. La voici :

Par contre, je n'arrive pas à envoyer plusieurs fichiers txt donc je ne connais pas le nom. Je sais qu'ils sont dans mon c:\test\*.txt. Si qq'un sait comment faire ??

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory.
Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network).

Const cdoAnonymous = 0 'Do not authenticate
Const cdoBasic = 1 'basic (clear-text) authentication
Const cdoNTLM = 2 'NTLM

Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Example CDO Message avec pj"
objMessage.From = """Thibault"" <monadresse@gmail.com>"
objMessage.To = "destinataire@fournisseur.com"
objMessage.TextBody = "This is some sample message text.." & vbCrLf & "It was sent using SMTP authentication."
objMessage.AddAttachment "c:\testenvoimail.txt"

'==This section provides the configuration information for the remote SMTP server.

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"

'Type of authentication, NONE, Basic (Base64 encoded), NTLM
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

'Your UserID on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = "monadresseexpéditeur@gmail.com"

'Your password on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "monMotDePasse"

'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465

'Use SSL for the connection (False or True)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True

'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

objMessage.Configuration.Fields.Update

'==End remote SMTP server configuration section==

objMessage.Send

En rouge, il s'agit de 2 zones que j'ai dû modifier pour correspondre à une messagerie GMAIL.

Merci