[XL-2000] Suppression de lignes [Résolu]

[Brunodm13]

Bonjour,

Il faut que j'exécute 3 fois ce code sur ma feuille Histo contenant 388 lignes pour supprimer celles dont je ne trouve pas la référence dans la feuille OF.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
i = Sheets("Histo").Range("B65536").End(xlUp).Row
 
For Each c In Sheets("Histo").Range("A" & i & ":A2")
    Set v = Sheets("OF").Range("G:G").Find(What:= c.Value, LookIn:=xlValues, LookAt:=xlPart)
        If v Is Nothing Then
            k = c.Row
            Rows(k).Delete
            j = j + 1
        End If
Next c
 
MsgBox j & " lignes supprimées"
j = 0

Alors qu'il me suffit d'exécuter une seule fois celui là pour colorer la cellule de la colonne A de la ligne que je voudrais supprimer.

Code :

1
2
3
4
5
6
7
8
9
i = Sheets("Histo").Range("B65536").End(xlUp).Row
 
For Each c In Sheets("Histo").Range("A" & i & ":A2")
    Set v = Sheets("OF").Range("G:G").Find(What:= c.Value, LookIn:=xlValues, LookAt:=xlPart)
        If v Is Nothing Then
            c.Interior.ColorIndex = 4
            j = j + 1
        End If
Next c

Quelqu'un pourrait-il m'expliquer car là je séche

Bruno

[mapeh]

Bonjour,

si tu pars du bas vers le haut, n'oublie pas le Step -1

Code :

For Each c In Sheets("Histo").Range("A" & i & ":A2") Step -1

[Brunodm13]

Bonjour mapeh,

merci de ta réponse rapide.

Envoyé par mapeh

Bonjour,

si tu pars du bas vers le haut, n'oublie pas le Step -1

L'ajout de Step -1 me génère une erreur de compilation : Erreur de syntaxe.

De toute façon, si je fait :

Code :

For Each c In Sheets("HistoriqueGSI").Range("A2:A" & i)

le problème est le même.

As-tu une autre idée ?

Bruno

[mapeh]

Re-,

essaie avec ce code :

pour une suppression de lignes, il faut toujours aller du bas vers le haut....

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub suppr()
Dim Derlig As Long, I As Long
With Sheets("Histo")
    Derlig = .Range("B65536").End(xlUp).Row
 
    For I = Derlig To 2 Step -1
        Set v = Sheets("OF").Range("G:G").Find(What:=.Cells(I, 1).Value, LookIn:=xlValues, LookAt:=xlPart)
        If v Is Nothing Then
            Rows(I).Delete
            j = j + 1
        End If
    Next I
End With
MsgBox j & " lignes supprimées"
j = 0
End Sub

[Brunodm13]

Ton code supprime bien les lignes en une seule fois

Je ne comprends toujours pas pourquoi il faut que j'exécute le mien 3 fois pour arriver au même résultat...

Encore une fois

A plus.

Bruno

[Krovax]

Le problème du for each est qu'il a de haut en bas

Tu test la ligne 1 c'est bon
tu tests la ligne 2 tu la supprime, la ligne 3 monte a la place de la ligne 2
Tu test la ligne 3 (qui est l'ancienne ligne 4)
....

Il y a des ligne que tu ne testera jamais, du coup tu doit lancer le code plusieurs fois Regarde a l'envers ce que cela donne, tu comprendra l'intérêt

[Brunodm13]

Bonjour Krovax,

Envoyé par Krovax

Le problème du for each est qu'il a de haut en bas

Le For Each qui pose problème teste bien les lignes de bas en haut.

Code :

For Each c In Sheets("Histo").Range("A" & i & ":A2")

Effectivement, au départ, je testais les lignes de haut en bas. Je me suis fait la réflexion qu'effectivement je ratais des lignes tel que tu le décris. Je suis donc passé à un test de bas en haut.

Ce qui est curieux c'est que quelque soit la méthode de test des lignes, le code me supprime 61 lignes, puis 26 et enfin 1.

As-tu une autre idée, car je ne vois pas où se trouve l'erreur.

Cordialement.

Bruno