Discussion :

[curt]

Bonjour à tous,

je ne suis pas très habitué à Word, mais voilà ma question :

J'ai une feuille Excel qui me sert de source pour faire du publipostage.
Dans Word, j'ai dans mon document : Une page de garde, une page dans laquelle j'ai mis une table de révision et (enfin !) ma feuille avec LE CHAMP (il n'y en a qu'un) et alimenté par la source Excel.

Quand je lance le publipostage, j'obtiens, pour chaque enregistrements excel, une page de garde, la page de révision et la page avec le champ renseigné. (par exemple, pour 10 enregistrements Excel, j'ai 30 pages Word )

Donc, comment avoir uniquement :
Une page de garde
La page de sommaire (table de révision)
Et la suite des feuilles renseignées.

Désolé si j'ai été un peu long.
Bonne fin d'après midi.
Curt

[Heureux-oli]

Salut,


Sans VBA, point de solution.

[curt]

Bonsoir Heureux-Oli,

merci pour l'info. Je pensais avoir loupé un truc sur le publipostage.
Bon ben, j'ai plus qu'à mis mettre.

Bonne soirée.
Curt

Ps : je laisse le post ouvert au cas où quelqu'un aurait déjà réalisé la même chose ou similaire.

[Heureux-oli]

Salut,

Il y a peut-être une solution, mais elle passe par deux documents.
L'un qui contient tes deux premières pages et le second le document publiposté.
Un maître et un esclave.

http://heureuxoli.developpez.com/office/word/longdoc/

[curt]

Bonjour Heureux-oli,

j'ai "tenté" de comprendre le fonctionnement doc maître et esclave (c'est pas simple !! ).

Peux-tu me dire si c'est bon. Le doc esclave est représenté par un hyperlien et ça me paraît bizarre. Le fichier Excel est la source du doc esclave Krol2. Le doc Krol est le maître.

D'avance merci.
Curt

[Heureux-oli]

Salut,

Le Hyperlien est normal.
Parcontre, il faut un document terminé pour faire la relation Maître Esclave.

je me suis amusé à faire une macro.


Il fonctionne sur le fichier Xl que tu as posté.

[curt]

Bonsoir Heureux-Oli,

mille mercis pour le fichier... tu as fais tout le travail et tout fonctionne parfaitement.

Il n'y a plus qu'à personaliser le document.
Encore une fois

Curt

[curt]

Bonjour Heureux-Oli,

je reviens vers toi pour la question suivante :

Le code fonctionne NICKEL sur 2007 et 2003, mais patatra, ma collègue à Office 2000 sur son poste et comme d'habittude, je me heurte à l'erreur [Type non défini] sur l'instruction FileDialog...

J'ai parcouru la FAQ et le forum, mais comment adapter ton code à Word 2000 ?

Encore merci et désolé du dérangement.
Curt

[Heureux-oli]

Salut,

C'est un objet qui se trouve dans la librairie Office à partir de la version 2003.
Il faut faire une boîte de dialogue qui devrait permettre de trouver le fichier.

Et dans ce cas, il faudrait passer par du FSO.

Peut-être passer par une boîte de dialogue qui ne serait pas du FialeDialog mais Dialog

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.Dialogs(wdDialogFileOpen)

Cette boîte de dialogue ne s'utilise pas de la même manière.

[curt]

Bonjour Heureux-Oli,

j'avais déjà eu ce soucis avec Access et j'utilisais l'Api (dans la Faq).
Malheureusement, ça ne fonctionne pas dans ce cas.

Là, je vais avoir besoin d'un GROS coup de main... Je ne parviens pas à faire fonctionner le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Sub Document_New()
Dim xlApp As Excel.Application
Dim xlWB As Excel.Workbook
Dim xlWS As Excel.Worksheet
 
Dim oDlg As Dialog
 
Dim intLi As Integer
Dim intI As Integer
 
Set oDlg = Application.Dialogs(wdDialogFileOpen)
 
With oDlg
    .InitialFileName = "Dossier d'Appel d'Offre.xls"
    .AllowMultiSelect = False
    .Show
End With
 
Set xlApp = New Excel.Application
Set xlWB = xlApp.Workbooks.Open(oDlg.SelectedItems(1))
Set xlWS = xlWB.Sheets(1)
intLi = xlWS.UsedRange.Rows.Count
 
ActiveDocument.Bookmarks("S1").Select
 
For intI = 1 To intLi
        Selection.TypeText xlWS.Cells(intI, 1).Value
        Selection.Style = "Titre 1"
        Selection.TypeParagraph
        Selection.InsertBreak
        Selection.EndKey Unit:=wdStory
Next intI
 
Set xlWS = Nothing
Set xlWB = Nothing
xlApp.Quit
Set xlApp = Nothing
ActiveDocument.Fields.Update
 
End Sub

j'ai une erreur 438 sur la ligne [.InitialFileName = "Dossier d'Appel d'Offre.xls"]

Merci d'avance pour l'aide.
Curt

Curt

[Heureux-oli]

Salut,
J'ai modifié le code de la FAQ pour que ça fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
 
Option Explicit
 
  'Déclaration de l'API
Private Declare Sub PathStripPath Lib "shlwapi.dll" Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
                   "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
 
 'Structure du fichier
Private Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
 
 'Constantes
Private Const OFN_READONLY = &H1
Private Const OFN_OVERWRITEPROMPT = &H2
Private Const OFN_HIDEREADONLY = &H4
Private Const OFN_NOCHANGEDIR = &H8
Private Const OFN_SHOWHELP = &H10
Private Const OFN_ENABLEHOOK = &H20
Private Const OFN_ENABLETEMPLATE = &H40
Private Const OFN_ENABLETEMPLATEHANDLE = &H80
Private Const OFN_NOVALIDATE = &H100
Private Const OFN_ALLOWMULTISELECT = &H200
Private Const OFN_EXTENSIONDIFFERENT = &H400
Private Const OFN_PATHMUSTEXIST = &H800
Private Const OFN_FILEMUSTEXIST = &H1000
Private Const OFN_CREATEPROMPT = &H2000
Private Const OFN_SHAREAWARE = &H4000
Private Const OFN_NOREADONLYRETURN = &H8000
Private Const OFN_NOTESTFILECREATE = &H10000
 
Private Const OFN_SHAREFALLTHROUGH = 2
Private Const OFN_SHARENOWARN = 1
Private Const OFN_SHAREWARN = 0
 
 
Public Function OuvrirUnFichier(Handle As Long, _
                                Titre As String, _
                                TypeRetour As Byte, _
                                Optional TitreFiltre As String, _
                                Optional TypeFichier As String, _
                                Optional RepParDefaut As String) As String
 'OuvrirUnFichier est la fonction a utiliser dans votre formulaire pour ouvrir _
 'la boîte de dialogue de sélection d'un fichier.
 'Explication des paramètres
    'Handle = le handle de la fenêtre (Me.Hwnd)
    'Titre = Titre de la boîte de dialogue
    'TypeRetour (Définit la valeur, de type String, renvoyée par la fonction)
        '1 = Chemin complet + Nom du fichier
        '2 = Nom fichier seulement
    'TitreFiltre = Titre du filtre
        'Exemple: Fichier Access
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'TypeFichier = Extention du fichier (Sans le .)
        'Exemple: MDB
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'RepParDefaut = Répertoire d'ouverture par defaut
        'Exemple: C:\windows\system32
        'Si vous laissé l'argument vide, par defaut il se place dans le répertoire de votre application
 
Dim StructFile As OPENFILENAME
Dim sFiltre As String
 
 'Construction du filtre en fonction des arguments spécifiés
If Len(TitreFiltre) > 0 And Len(TypeFichier) > 0 Then
  sFiltre = TitreFiltre & " (" & TypeFichier & ")" & Chr$(0) & "*." & TypeFichier & Chr$(0)
End If
sFiltre = sFiltre & "Tous (*.*)" & Chr$(0) & "*.*" & Chr$(0)
 
 
 'Configuration de la boîte de dialogue
  With StructFile
    .lStructSize = Len(StructFile) 'Initialisation de la grosseur de la structure
    .hwndOwner = Handle 'Identification du handle de la fenêtre
    .lpstrFilter = sFiltre 'Application du filtre
    .lpstrFile = String$(254, vbNullChar) 'Initialisation du fichier '0' x 254
    .nMaxFile = 254 'Taille maximale du fichier
    .lpstrFileTitle = String$(254, vbNullChar) 'Initialisation du nom du fichier '0' x 254
    .nMaxFileTitle = 254  'Taille maximale du nom du fichier
    .lpstrTitle = Titre 'Titre de la boîte de dialogue
    .flags = OFN_HIDEREADONLY  'Option de la boite de dialogue
    If ((IsNull(RepParDefaut)) Or (RepParDefaut = "")) Then
        RepParDefaut = Application.Options.DefaultFilePath(wdDocumentsPath)
        PathStripPath (RepParDefaut)
        Else: .lpstrInitialDir = RepParDefaut
    End If
  End With
 
If (GetOpenFileName(StructFile)) Then 'Si un fichier est sélectionné
    Select Case TypeRetour
      Case 1: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFile, InStr(1, StructFile.lpstrFile, vbNullChar) - 1))
      Case 2: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFileTitle, InStr(1, StructFile.lpstrFileTitle, vbNullChar) - 1))
    End Select
  End If
 
End Function

Et son appel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

OuvrirUnFichier(0, "Parcourir", 1, "Fichier Excel", "xls")

[curt]

Ok, j'ai la boîte de dialogue qui s'ouvre
Bon mais du coup, le traitement de la feuille Excel de ta macro ne tourne plus

Désolé d'être un peu
Merci pour ta patience.

Curt

[Heureux-oli]

Salut,

C'est cette ligne qu'il faut changer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set xlWB = xlApp.Workbooks.Open(oDlg.SelectedItems(1))

Par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set xlWB = xlApp.Workbooks.Open(OuvrirUnFichier(0, "Parcourir", 1, "Fichier Excel", "xls"))

Et enlever ces lignes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Dim oDlg As Dialog
 
 
Set oDlg = Application.Dialogs(wdDialogFileOpen)
 
With oDlg
    .InitialFileName = "Dossier d'Appel d'Offre.xls"
    .AllowMultiSelect = False
    .Show
End With

[curt]

Encore merci,

j'en étais là (presque !).

Et ben voilà, ça tourne tout bien.
Mille merci de ma part et tu gagnes une bise de ma collègue !!!

Curt