Insertion fichier tabulé

[hlander]

Bonjour, pour continuer dans mes problèmes, j'ai besoin grace à une macro de demander de choisir un fichier, et de l'intégrer dans la feuille, ce fichier étant un fichier texte tabulé.

Donc pour demander de choisir un fichier :

 
ficvar = Application.GetOpenFilename(".txt,*.txt", , "Choisissez la variante")
 

Et j'ai fais une macro auto, pour insere ce même fichier et j'ai obtenu ça :

 
  Workbooks.OpenText Filename:= _
        "C:\temp\fic.txt", Origin:=xlWindows, _
        StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
        ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, Comma:=False _
        , Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), Array(2, 1), _
        Array(3, 1), Array(4, 1), Array(5, 1), Array(6, 1), Array(7, 1), Array(8, 1), Array(9, 1), _
        Array(10, 1), Array(11, 1), Array(12, 1), Array(13, 1), Array(14, 1))
 

Mais comment combiner les deux.

Merci

[fring]

Bonjour,

Sub test()
Dim ficvar As Variant
 
ficvar = Application.GetOpenFilename(".txt,*.txt", , "Choisissez la variante")
 
'si l'utilisateur clique sur annuler
If ficvar = False Then Exit Sub
 
Workbooks.OpenText Filename:=ficvar, Origin:=xlWindows, _
        StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
        ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, Comma:=False _
        , Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), Array(2, 1), _
        Array(3, 1), Array(4, 1), Array(5, 1), Array(6, 1), Array(7, 1), Array(8, 1), Array(9, 1), _
        Array(10, 1), Array(11, 1), Array(12, 1), Array(13, 1), Array(14, 1))
 
End Sub

Cdlt

[hlander]

En utilisant le code ci-dessus :

Le fichier choisi test.txt s'ouvre dans un nouveau fichier excel, et non dans la feuille a partir de laquelle je lance la macro.

[fring]

Envoyé par hlander

En utilisant le code ci-dessus :

Le fichier choisi test.txt s'ouvre dans un nouveau fichier excel, et non dans la feuille a partir de laquelle je lance la macro.

C'est exactement ton code...!

[hlander]

oui c'est le code que j'ai réussi a générer avec une macro automatique, mais ce que je recherche c'est comment inserer a une feuille existante le contenu d'un fichier tabulé.

[fring]

Ok mais ta question était

Mais comment combiner les deux.

Soit...
Essaie ceci

Sub test()
Dim ficvar As Variant, Wsh As Worksheet
 
Set Wsh = Sheets("Feuil1") '<-- feuille de destination
ficvar = Application.GetOpenFilename(".txt,*.txt", , "Choisissez la variante")
 
'si l'utilisateur clique sur annuler
If ficvar = False Then Exit Sub
 
With Wsh.QueryTables.Add(Connection:="TEXT;" & ficvar, Destination:=Wsh.Range("A1"))
        .AdjustColumnWidth = True
        .TextFileParseType = xlDelimited
        .Refresh BackgroundQuery:=False
End With
End Sub

[hlander]

Merci beaucoup c'est exactement ça.....