[A-00] Ecriture de données dans un fichier texte

[damkre]

Bonjour à tous !

Je me permets à nouveau de faire appel à vous pour m'aider à résoudre un problème à l'aide de vos lumières

Je suis dans un formulaire, qui contient des données. Dans ce formulaire, j'ai insérée un sous-formulaire ( les deux tables sont liées ).

Sur ce formulaire principal, j'ai un bouton, qui écrit des données dans un fichier texte ( tout cela fonctionne ), sur base de ce code :

Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.CreateTextFile(CurrentProject.Path & "\Résultats.txt", True)
 
'Lignes à écrire
a.WriteLine
a.WriteLine ("Test de texte" & me.MONCHAMP.Value )
 
a.Close
 
MsgBox "Le fichier généré a été créé.", vbInformation, "MON APPLICATION"

Je souhaite maintenant écrire plusieurs lignes, qui seraient toutes celles contenues dans mon sous-formulaire.

Comment y arriver ?

Merci de vos réponses.

[argyronet]

Bonjour,

Il faut que tu établisses ce que tu veux écrire à travers une requête.
De là, avec un objet Recordset, tu lis ta requête ligne à ligne et tu écris dans ton fichier avant chaque MoveNext.
Par contre, la méthode que tu as choisi avec ton fso n'est pas suffisante, il te faut un Textstream avec un paramètre ForAppending.
Sinon, tel que tu l'as écris, tu écraseras toujours ton fichier avec la dernière valeur.

Argy

[damkre]

Bonjour !

Je me permets de demande quelques précisions :

Envoyé par argyronet

Il faut que tu établisses ce que tu veux écrire à travers une requête.

=> Cela veut-il dire que je dois créer une requête, et que celle-ci soit un objet de ma DB, ou dois-je simplement l'écrire dans mon code ?

Envoyé par argyronet

De là, avec un objet Recordset, tu lis ta requête ligne à ligne et tu écris dans ton fichier avant chaque MoveNext

=> Là, je ne comprends pas très bien comment faire...
Quel code taper en VBA ?

Envoyé par argyronet

Par contre, la méthode que tu as choisi avec ton fso n'est pas suffisante, il te faut un Textstream avec un paramètre ForAppending.
Sinon, tel que tu l'as écris, tu écraseras toujours ton fichier avec la dernière valeur.

=> Cela, je l'avais bien compris, ne t'inquiète pas...
J'y viendrai dès que ce qui précède sera résolu.

[argyronet]

Oui, dans le code.
Si possible, générique.

Par exemple :

 
Private Sub cmdWriteIntoFile_Click()
Dim oFSO                                As Scripting.FileSystemObject
Dim oTextStream                         As Scripting.TextStream
Dim oDB                                 As DAO.Database
Dim oRS                                 As DAO.Recordset
Dim SQLCommand                          As String
Dim strLine                             As String
Dim strFieldValue                       As String
Dim strFileName                         As String
Dim I                                   As Long
Dim F                                   As Long
 
    Set oFSO = New Scripting.FileSystemObject
    strFileName = "C:\_Test\Un fichier.txt"
    With oFSO
        Set oTextStream = .CreateTextFile(strFileName, True, False)
    End With
    SQLCommand = "SELECT * FROM [Détails commandes complets] _
WHERE [N° commande] = " & Me![N° commande]
    Set oDB = CurrentDb
    Set oRS = oDB.OpenRecordset(SQLCommand, dbOpenDynaset)
    With oRS
        Do While Not .EOF
            I = I + 1
            For F = 0 To .Fields.Count - 1
                strFieldValue = strFieldValue & .Fields(F).Value & ";"
            Next
            strLine = strFieldValue
            oTextStream.WriteLine strLine
            strFieldValue = vbNullString
            .MoveNext
        Loop
        .Close
    End With
    oDB.Close
    Set oRS = Nothing
    Set oDB = Nothing
End Sub

Argy

[damkre]

J'ai fait ceci :

Dim iRst As DAO.Recordset
    Set iRst = CurrentDb.OpenRecordset("SELECT etc FROM etc WHERE etc ", dbOpenDynaset)
 
While Not iRst.EOF
    a.WriteLine (MES LIGNES A INSÉRER)
    iRst.MoveNext
 
Wend
iRst.Close
Set iRst = Nothing

Et cela fonctionne...

( J'avais trouvé cela entretemps, en chipotant un peu )

Est-ce tout aussi correct, ou faut-il rectifier quelque chose pour rendre cela plus simple ?

Ah, et autre question ( tant qu'on y est) : peut-on prévoir des alignements ( avec par exemple des tabulations ), ou est-ce irréalisable ?

[argyronet]

Oui, on peu prévoir des alignement.
Il te faut formater le champ en fonction de sa longueur au momenet de la lecture et sa longueur désirée et ajouter des espaces à gauche ou à droite selon que c'est un numérique ou une chaîne.
Cela s'effectue au moment de la construction de la chaîne "strFieldValue" que je t'ai proposé hier.
Il te faut alors créer la fonction qui s'en charge, le mieux étant d'avoir une nomenclature préalable Type, LongueurChamp, LongueurFinale, Alignement.

Argy