rafraichir formulaire avec critere (liste déroulante)

[Aureli]

Bonjour,
J'ai un formulaire, relié à une table, dont un des champs est une liste déroulante.

Je souhaite rafraichir les champs du formulaire et n'afficher que les enregistrements correspondant au critère séléctionné de ma liste.

dans l'évènement "on change", j'ai mis le code suivant :

Private Sub RegionAdherent_Change()
Dim strTable As String, strField As String, strCriteria As String, strSql As String
    Dim Criter As Variant
 
    strTable = "T1Adherents"         ' recupère le nom de la table
    strField = "RegionAdherent"         ' recupère le nom du champ
 
    ' compose le critere de recherche
    strCriteria = strTable & "." & strField & " = " & Me.RegionAdherent
    
 
    ' construit la requête sql
    strSql = strTable & ".*"
    strSql = strSql & " FROM " & strTable
    strSql = strSql & " WHERE ((" & strCriteria & "));"
    
 
    Me.Query = strSql  ' affecte sql a lst_Resultat
    Me.Requery
    Me.Refresh
End Sub

Il ne me rafraichit rien, m'affiche toujours tous mes enregistrements

[argyronet]

Bonjour,

Dans l'absolu, cette routine suffit amplement :

 
Private Sub RegionAdherent_AfterUpdate()
    Me.RecordSource = "SELECT * FROM T1Adherents WHERE RegionAdherent = " & _
        Me!RegionAdherent & ";"
End Sub
 

Avec un peu de zèle tu peux écrire :

 
Private Sub RegionAdherent_AfterUpdate()
Dim lngCountBefore                                          As Long
    If Not IsNull(Me.RegionAdherent) Then
        lngCountBefore = DCount("*", "T1Adherents", "[RegionAdherent]=" & _
            Me!RegionAdherent)
        If lngCountBefore Then
            Me.RecordSource = _
                "SELECT * FROM T1Adherents WHERE RegionAdherent = " & _
                Me!RegionAdherent & ";"
        Else
            MsgBox "Aucun enregistrement ne correspond à cette région !", _
                vbExclamation
        End If
    End If
End Sub
 

Argy

P.S. Ta procédure initila n'étant pas générique, ne perds pas de temps à créer des variable pour définir ta table et ton champ. Comme tu le vois, une seule ligne de code suffit...