Lister les fichiers d'un répertoire avec FSO avec ou sans liens hypertextes

[ouskel'n'or]

Ne nécessite pas d'activer la référence "Microsoft Scripting RunTime"

Sub ListeFichiers_avec_fso()
Dim fso As Object, NomFich As Object, i As Long, Chemin$
Chemin = InputBox("Saisir le chemin du répertoire ", "", "D:\Doc")
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    With fso.GetFolder(Chemin) 'Liste les fichiers du répertoire
        For Each NomFich In .Files
            Selection.TypeText Text:=NomFich.Name 'Place leurs noms ds le document
            Selection.TypeParagraph
        Next
    End With
End Sub

La même procédure avec Dir se trouve dans l'aide en ligne

Le même avec lien hypertexte sur le nom de fichier

Sub ListeFichiers_avec_fso()
Dim fso As Object, NomFich As Object, i As Long, Chemin$
Chemin = InputBox("Saisir le chemin du répertoire ", "", "D:\Doc")
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    With fso.GetFolder(Chemin) 'Liste les fichiers du répertoire
        For Each NomFich In .Files
            ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
            Chemin & "\" & NomFich.Name, TextToDisplay:=NomFich.Name
            Selection.TypeParagraph
        Next
    End With
End Sub
 

pour ouvrir le lien, appuyer sur Ctrl + sélection du nom de fichier

[ouskel'n'or]

Le même avec lien hypertexte à partir d'un combobox placé dans le document.

Ajouter un combobox issu de la barre d'outils "Boîte à outils contrôles" dans le document.

Dans un module standard, placer ce code :

Sub ListeFichiers_avec_hyperlink()
Dim fso As Object, NomFich As Object, Chemin$
    Chemin = InputBox("Saisir le chemin du répertoire ", "", "D:\Doc")
    Set fso = CreateObject("Scripting.FileSystemObject")
    ActiveDocument.ComboBox1.Clear
    With fso.GetFolder(Chemin) 'Liste les fichiers du répertoire
        For Each NomFich In .Files
            ActiveDocument.ComboBox1.AddItem Chemin & "\" & NomFich.Name
        Next
    End With
End Sub

Dans ThisDocument ( -> Editeur VBA -> 2 clics sur ThisDocument ouvre la feuille de code ) placer ce code

Private Sub ComboBox1_Click()
    ActiveDocument.Hyperlinks.Add Address:=ComboBox1, _
        Anchor:=Selection.Range
    ActiveDocument.Hyperlinks(1).Follow
End Sub

Pour que le combobox soit renseigné à l'ouverture du fichier, ajouter ce code dans ThisDocument

Private Sub Document_Open()
ListeFichiers_avec_hyperlink
End Sub