Sélectionner une page précise & Copie - Explications

[ouskel'n'or]

Trois conditions peuvent se rencontrer :
- La page demandée n'existe pas,
- La page demandée existe et ce n'est pas la dernière du document
- La page demandée est la dernière du document

Le code :

Sub SelectionDePage(NoPage As Integer)
Dim Nb As Integer
    Nb = Selection.Information(wdNumberOfPagesInDocument)
    If NoPage > Nb Then
        MsgBox "Page " & NoPage & " demandée." & vbCr & _
           "Votre document ne comporte que " & _
           Selection.Information(wdNumberOfPagesInDocument) & _
           " pages.", 0, "PAGE DEMANDÉE INEXISTANTE"
        Exit Sub
    End If
    With Selection
        .GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=NoPage
        .ExtendMode = True
        If NoPage < Nb Then
            .GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=NoPage + 1
        Else
            .EndKey Unit:=wdStory
        End If
    End With
    Selection.Copy
End Sub

Explications :

Sub SelectionDePage(NoPage As Integer)
Dim Nb As Integer
    'Pour connaître le nombre de pages
    Nb = Selection.Information(wdNumberOfPagesInDocument)
 
    'Si la page n'existe pas, on le dit et on sort
    If NoPage > Selection.Information(wdNumberOfPagesInDocument) Then
        Msgbox "Page " & NoPage & " demandée." & vbcr & _
           "Votre document ne comporte que " & _
           Selection.Information(wdActiveEndPageNumber)  & _
           "pages.",0,"PAGE DEMANDÉE INEXISTANTE"
        Exit sub
    Endif
 
    With Selection
 
        'Conduit au début de la page NoPage
        .GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=NoPage
 
        'Active le mode de sélection étendu 
        .ExtendMode = True
        
        'Si la Page n'est pas la dernière, la sélection s'étendra à la page suivante...
        If NoPage < Nb Then
            .GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=NoPage + 1
 
           'Si la Page est la dernière, la sélection s'étendra à la fin du document            
           Else 
            .EndKey Unit:=wdStory
        End If
    End With
 
    'Copie de la page
    Selection.Copy
End Sub

Appel de la procédure :

Sub appel() 'la procédure est appelée avec le paramètre NoPage
     SelectionDePage InputBox("Saisir le N° de page", "")
End Sub