Discussion :

[thiblightt]

Bonjour,

Dans ma programmation, je donne des valeurs à plusieurs variables :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
%let inf_piece_2002=1.017;
%let inf_piece_2003=1.013;
%let inf_piece_2004=1.033;
%let inf_piece_2005=1.028;
%let inf_piece_2006=1.032;
%let inf_piece_2007=1.044;
%let inf_piece_2008=1.044;

Puis, j'essaie d'appeler ces variables au sein d'une boucle du type "do" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
do i=2002 to 2007; 		
do j=i+1 to 2008;
var=var*&inf_piece_&j;
end; end;

J'essaie ainsi d'utiliser les valeurs inf_piece_2002, inf_piece_2003, ... de façon automatisée.
Malheureusement, la syntaxe &inf_piece_&j n'est pas bonne. Quelle syntaxe faut il utiliser ?

Merci d'avance !

[bahraoui]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
 
%macro test;
%let inf_piece_2002=1.017;
%let inf_piece_2003=1.013;
%let inf_piece_2004=1.033;
%let inf_piece_2005=1.028;
%let inf_piece_2006=1.032;
%let inf_piece_2007=1.044;
%let inf_piece_2008=1.044;
 
 
%let var=1;
%do i=2002 %to 2007; 
	%do j=&i+1 %to 2008;
 
		%let var=%sysevalf(&var*&&inf_piece_&j);
	%end; 
%end;
%put &var;
%mend;
%test;

[olivier.decourt]

Bonjour thiblightt.

Plusieurs problèmes se superposent dans le code proposé.

1) l'utilisation de la variable J comme si c'était une macro-variable : les deux types d'information ont des vies très différentes, la variable J étant stockée dans une table, et voyant ses valeurs changer dans la boucle de l'étape Data, pendant qu'une macro-variable &J est stockée en mémoire (pas dans une table) et voit sa valeur modifiée par des %LET ou une boucle %DO dans un macro-programme (d'où la solution proposée par Bahraoui).

2) est-ce que la solution toute en macro proposée par Bahraoui est vraiment optimale dans le genre de programme proposé ? En tout cas, ce n'est pas forcément la seule solution. A partir de la forme proposée initialement, en gardant les 7 macro-variables, on peut utiliser la fonction SYMGET dans l'étape Data pour récupérer la valeur d'une macro-variable. SYMGET a comme argument le nom de la macro-variable, sous forme d'une chaîne de caractères, qui peut être construite par concaténation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
do i=2002 to 2007; 
do j=i+1 to 2008;
var=var*SYMGET(COMPRESS("inf_piece_"!!j)) ;
end; end;

3) une autre piste, vu le code proposé, serait d'abandonner le côté macro-langage pour utiliser plutôt des Arrays. Ce sont des séries de valeurs indexées par un nombre, et ici J jouerait ce rôle dans le même esprit que le code initial. Ca deviendrait (en adaptant les valeurs de J pour qu'elles commencent à 1 pour l'année 2002) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
ARRAY inf_piece (7) (1.017 1.013 1.033 1.028 1.032 1.044 1.044) ;
do i=2002 to 2007; 
do j=(i-2002)+1 to 7 ;
var=var*inf_piece(j) ;
end; end;

4) enfin, comme l'indique Bahraoui, si on utilise des macro-variables à l'intérieur d'une boucle %DO, on n'obtient pas le résultat escompté avec &var&i. En effet, le compilateur macro transforme les expressions en utilisant les 5 règles suivantes :
a) l'expression est lue de la gauche vers la droite, et à chaque fois qu'on rencontre un des motifs (b) à (e), il est remplacé et on passe au motif suivant. Si, une fois la lecture terminée, il reste des signes & dans le résultat des transformations, une autre lecture sera effectuée sur le même principe.
b) le motif &MV est remplacée par la valeur de la macro-variable MV
c) le motif &MV. est remplacée par la valeur de la macro-variable MV
d) le motif && est remplacée par la valeur &
e) le motif composé d'un texte sans &, par exemple MV, est conservé tel quel.

Par exemple, avec
%LET var = annee ;
%LET var1 = 2008 ;
%LET j = 1 ;

&var&j --> annee1 (règle b pour &var et règle b pour &j)
&&var&j --> &var1 --> 2008
(règle d pour &&, règle e pour var, règle b pour &j
puis règle a, 2e lecture : règle b pour &var1)

Olivier

[thiblightt]

Ok, ca marche, merci pour toutes ces réponses rapides, claires, et précises