API Windows => Base de Registre

[Apocalyps]

Après de longues recherches sur mon ami ( ), je vous demande de l'aide car celui ci ne me répond qu'en VB .

Savez vous quelle DLL et quelles fonctions faut-il utiliser pour accéder (Lecture/Ecriture) sur la Base de Registre.

Merci de votre Aide

[supersnail]

Pour importer les APIs,déjà lis ça : http://comtois.developpez.com/tutori.../presentation/

Ensuite tu n'auras qu'à impoerter les APIs pour lire dans le registre (qu'on peut trouver sur )

[ram-0000]

Point d'entrée de l'API Win32 pour accèder à la base de registres

[comtois]

et un exemple de code avec PureBasic, je ne sais pas ce que ça vaut, je n'ai pas testé et je ne connais la BDR. Mais tu pourras t'en inspirer

; Lire une chaine dans le registre
Procedure.s ReadRegKey(OpenKey.l,SubKey.s,ValueName.s) ; ====================================== ReadRegKey
    
     ; key.s=ReadRegKey(#HKEY_LOCAL_MACHINE,"SOFTWARE\Zone Labs\ZoneAlarm","InstallDirectory")
     ;
    hKey.l=0
    keyvalue.s= Space (255)
    DataSize.l=255
    
     If RegOpenKeyEx_ (OpenKey,SubKey,0, #KEY_READ ,@hKey)
        keyvalue= ""
     Else
         If RegQueryValueEx_ (hKey,ValueName,0,0,@keyvalue,@DataSize)
            keyvalue= ""
         Else
            keyvalue= Left (keyvalue,DataSize-1)
         EndIf
         RegCloseKey_ (hKey)
     EndIf
    
     ProcedureReturn keyvalue
EndProcedure
 
; ecrire une chaine dans le registre
Procedure.l WriteRegKey(OpenKey.l,SubKey.s,keyset.s,keyvalue.s) ; ------------------------ WRITE KEY
    
     ; result.l=WriteRegKey(#HKEY_LOCAL_MACHINE,"SOFTWARE\Test Program Name","Test","TestValue")
    
    hKey.l=0
     If RegCreateKey_ (OpenKey,SubKey,@hKey)=0
        Result=1
        DataSize.l= Len (keyvalue)
         If RegSetValueEx_ (hKey,keyset,0, #REG_SZ ,@keyvalue,DataSize)=0
            Result=2
         EndIf
         RegCloseKey_ (hKey)
     EndIf
     ProcedureReturn Result
     ;returns 0 if error / could not open or create SubKey
     ;returns 1 if error / could not write new value
     ;returns 2 if Success!!
    
EndProcedure
 
; ecrire un long dans le registre
Procedure.l WritebinaryRegKey(OpenKey.l,SubKey.s,keyset.s,keyvalue.l) ; ------------------------ WRITE KEY
    
     ; result.l=WriteRegKey(#HKEY_LOCAL_MACHINE,"SOFTWARE\Test Program Name","Test","TestValue")
    
    hKey.l=0
     If RegCreateKey_ (OpenKey,SubKey,@hKey)=0
        Result=1
        DataSize.l=4 ; nombre d'octets ecrit !!
         If RegSetValueEx_ (hKey,keyset,0, #REG_BINARY ,@keyvalue,DataSize)=0
            Result=2
         EndIf
         RegCloseKey_ (hKey)
     EndIf
     ProcedureReturn Result
     ;returns 0 if error / could not open or create SubKey
     ;returns 1 if error / could not write new value
     ;returns 2 if Success!!
    
EndProcedure

[comtois]

un autre exemple pour la lecture.
Les fonctions de l'API sont déjà déclarées dans PureBasic, tu peux les utiliser directement. Pour les distinguer des fonctions du langage, elles se terminent par un underscore.

Procedure.s Reg_GetValue(topKey, sKeyName.s, sValueName.s, ComputerName.s)
  lpData.s
  GetValue.s =""
 
  If Left(sKeyName, 1) = "\"
    sKeyName = Right(sKeyName, Len(sKeyName) - 1)
  EndIf
 
  If ComputerName = ""
    GetHandle = RegOpenKeyEx_(topKey, sKeyName, 0, #KEY_ALL_ACCESS, @hKey)
  Else
    lReturnCode = RegConnectRegistry_(ComputerName, topKey, @lhRemoteRegistry)
    GetHandle = RegOpenKeyEx_(lhRemoteRegistry, sKeyName, 0, #KEY_ALL_ACCESS, @hKey)
  EndIf
 
  If GetHandle = #ERROR_SUCCESS
    lpcbData = 60000
    lpData = Space(60000)
   
    GetHandle = RegQueryValueEx_(hKey, sValueName, 0, @lType, @lpData, @lpcbData)
   
    If GetHandle = #ERROR_SUCCESS
      Select lType
        Case #REG_SZ
          GetHandle = RegQueryValueEx_(hKey, sValueName, 0, @lType, @lpData, @lpcbData)
         
          If GetHandle = 0
            GetValue = Left(lpData, lpcbData - 1)
          Else
            GetValue = ""
          EndIf
         
         
        Case #REG_MULTI_SZ
          GetHandle = RegQueryValueEx_(hKey, sValueName, 0, @lType, @lpData, @lpcbData)
         
          If GetHandle = 0
            ptr=@lpData
           
           
            ;/ Renvoie chaine terminée par deux Chr nul
            For n=ptr To ptr+lpcbData-2
              If PeekB(n)=0
                GetValue+Chr(13)
              Else
                GetValue+Chr(PeekB(n))
              EndIf
            Next
           
          Else
            GetValue = ""
          EndIf
         
        Case #REG_DWORD
          GetHandle = RegQueryValueEx_(hKey, sValueName, 0, @lpType, @lpDataDWORD, @lpcbData)
         
          If GetHandle = 0
            GetValue = Str(lpDataDWORD)
          Else
            GetValue = "0"
          EndIf
         
      EndSelect
    EndIf
  EndIf
  RegCloseKey_(hKey)
  ProcedureReturn GetValue
EndProcedure
 
Debug Reg_GetValue(#HKEY_LOCAL_MACHINE,"SYSTEM\CurrentControlSet\Control\ServiceGroupOrder","List",".")
 

[Apocalyps]

Merci de vos réponses, j'ai essayé la méthode de comtois et elle marche à merveille.

Merci pour vos conseils ...

Cette discussion est Résolue