[Macro] Partage des macros [Résolu]

[green_fr]

Bonjour,
Je créé mes macros avec l'option de sauvegarde de la version compilée dans une bibliothèque :

Code :

1
2
3
4
5
libname macros "mon chemin";
options mstored sasmstore=macros;
%macro createTriangleSin /store source;
/*blabla de mon macro*/
%mend createTriangleSin;

Apparemment au moment de compilation de mon macro SAS vérouille la bibliothèque "macros". Au point que je ne peux y accéder qu'à partir la session dans laquelle j'ai compilé les macros.
Si je ferme cette session, c'est OK, le macro est créé, la bibliothèque est libre, tout le monde peut utiliser mes macros.

Question : comment libérer le vérouillage de la bibliothèque sans fermer SAS ? Click droit, "Annuler l'affectation" ne marche pas, il dit

Code :

Impossible de supprimer ou de réaffecter la biblio. MACROS car elle est encore en cours d'utilisation.

[bahraoui]

Essaye de libérer le libname après la compilation

Code :

1
2
 
libname toto clear;

[olivier.decourt]

C'est un peu vicieux comme fonctionnement. Pour libérer les droits sur le catalogue de macros, il faut que la session SAS qui compile les macro-programmes ait été occupée à compiler ailleurs.
C'est à dire qu'en pratique, après le programme que tu décris, tu ne peux pas directement faire un LIBNAME CLEAR. Il faut aller compiler une macro ailleurs. Même une macro bidon. C'est ce que suggère SAS (http://support.sas.com/kb/9/807.html) et du coup, ça donne du code un peu étrange, comme ça...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
libname macros "c:\temp"; /* bibliothèque normale pour stockage */
options mstored sasmstore=macros;
%macro createTriangleSin /store source;
/* du code de la macro */
%mend createTriangleSin;
/* maintenant que c'est stocké, on fait une bibliothèque vers le répertoire de la Work */
LIBNAME tmp "%SYSFUNC(GETOPTION(work))" ACCESS=temp ;
/* on branche le compilateur macro vers la bibliothèque TMP */
OPTION MSTORED sasmstore=tmp ;
/* et on le "distrait" en lui faisant compiler une macro bidon dans TMP */
%MACRO rien / STORE ;
%MEND rien ;
/* ça y est, il a lâché la bibliothèque du début, on peut la libérer */
LIBNAME macros CLEAR ;
/* si on veut la réaffecter, le faire en lecture seule */
LIBNAME macros "c:\temp" ACCESS=READONLY ;

Olivier

[green_fr]

Arrhhhh.... J'aime SAS....
C'est bien ça, merci Olivier !

[steelspirit]

oui c'est un problème récurrent de gestion concurrente

Moi je te conseil d'oublier les mstored, sasmstore et compagnie... il vaut mieux utiliser des %include dans l'autoexec pour compiler tes macros en live à l'ouverture de la session.

[bahraoui]

C'est ce que je fais moi aussi.
Attention à ne pas perdre les sources.(mstored...)