Ribbon editBox et mot de passe

[tanith]

Bonjour,

Je suis à développer un nouvel onglet dans le Ruban d'Office 2007, et un problème se pose :

comment gérer un mot de passe avec un RibbonEditBox ?

Ou quel control intégrable à un ruban office peut transformer le mot de passe en '*' ?

Merci de vous pencher sur ma question

[tanith]

A ce que je vois, mon problème reste sans solution. Mes recherches tendent à cette conclusion en tout cas...

[Heureux-oli]

Je n'ai rien trouvé qui permet une substitution de caractère dans un textbox du ruban.

[tanith]

Je poste le lien d'un travail intéressant...mais inutilisable dans mon cas : http://www.codeproject.com/KB/WPF/ribboncontrol.aspx

[SilkyRoad]

bonjour


Cela ne répondra peut-être pas totalement à ta demande mais peux essayer d'adapter cet exemple de substitution:
Tu sélectionnes des caractères dans une galerie et qui vont s'afficher sous forme d'astérique dans un contrôle "Label".
Il faut ensuite cliquer sur le bouton "Valider le mot de passe" pour confirmer.


Dans le module objet "ThisWorkbook" du classeur:

Code :

1
2
3
4
5
6
7
8
Option Explicit
 
'Définit les caractère utilisables pour la saisie du mot de passe
Private Sub Workbook_Open()
    Tableau = Array("A", "B", "C", "D", "E", "F", "G", "H", "I", "J", _
        "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", _
        "W", "X", "Y", "Z", "0", "1", "2", "3", "4", "5", "6", "7", "8", "9")
End Sub

Dans un module standard du classeur :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Option Explicit
Option Base 1
 
Public Cible As String
Public MonRuban As IRibbonUI
Public Tableau As Variant
 
 
 
'Callback for customUI.onLoad
'Définit l'objet ruban
Sub objRuban(ribbon As IRibbonUI)
    Set MonRuban = ribbon
End Sub
 
 
'Callback for gallery01 getItemCount
'Définit le nombre d'élément dans la galerie
Sub NbCaracteres(control As IRibbonControl, ByRef returnedVal)
    returnedVal = UBound(Tableau) + 1
End Sub
 
 
'Callback for gallery01 getItemLabel
'Création des éléments dans la galerie
Sub LabelCaractere(control As IRibbonControl, index As Integer, ByRef returnedVal)
    returnedVal = Tableau(index)
End Sub
 
 
'Callback for gallery01 onAction
'Met à jour le label après avoir sélectionné un caractère dans dans la galerie
Sub SelectCaractere(control As IRibbonControl, id As String, index As Integer)
    Cible = Cible & Tableau(index)
    MonRuban.InvalidateControl "LC01"
End Sub
 
 
'Callback for LC01 getLabel
'Affiche des asteriques dans le label en lieu et place des caractères
Sub ContenuLabel(control As IRibbonControl, ByRef returnedVal)
    returnedVal = Application.WorksheetFunction.Rept("*", Len(Cible))
End Sub
 
 
'Callback for Bt01 onAction
'Validaton du mot de place
Sub ValidationMdP(control As IRibbonControl)
    MsgBox "Confirmation du mot de passe : (" & Cible & ")"
 
    Cible = ""
    MonRuban.InvalidateControl "LC01"
End Sub
 
 
'Callback for Bt02 onAction
'réinitialisation: Efface le contenu du label en cas d'erreur
'de saisie.
Sub EffaceContenuLabel(control As IRibbonControl)
    Cible = ""
    MonRuban.InvalidateControl "LC01"
End Sub

Dans le fichier xml de personnalisation :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
<customUI xmlns="http://schemas.microsoft.com/office/2006/01/customui" onLoad="objRuban"> 
 
  <ribbon>
    <tabs>
      <tab id="Essai" label="Essai" >
        <group id="MdP" label="Mot de passe">
 
		<gallery id="gallery01" 
			size="normal"
			imageMso="CalculateNow" 
			label="Saisissez le mot de passe:"
			columns="6" 
			rows="6"
			getItemCount="NbCaracteres"
			showItemLabel="true"
			getItemLabel="LabelCaractere"
			screentip="Sélectionnez les caractéres dans la galerie,
 
				puis validez le mot de passe."
			onAction="SelectCaractere" > 
 
			<button id="Bt02" label="Effacer la saisie." 
				imageMso="ClearMenu" onAction="EffaceContenuLabel"/> 
 
		</gallery> 
 
		<box id="Box01" boxStyle="horizontal">
			<labelControl id="LC01" getLabel="ContenuLabel" /> 
 
		</box> 
 
		<button id="Bt01" imageMso="FileStartWorkflow" size="normal" 
			label="Validez le mot de passe" visible="true" onAction="ValidationMdP" /> 
 
        </group>
      </tab>
    </tabs>
  </ribbon>
</customUI>

bonne journée
michel