Discussion :

[vallgui]

Bonjour,

Alors voilà mon problème, j'ai une liste d'IP à pinger mais le problème c'est que pour pinger ces adresses cela met beaucoup de temps!

C'est pourquoi j'aurais voulu savoir si il était possbile de pinger l'adresse broadcast et voir qu elles IP sont atteignable. Je ne sais pas du tout si c'est possbile!


merci de vos commentaires et de votre aide

[Emmanuel Lecoester]

Plus un problème réseau que WinDev...

[danielsoft]

Pour répondre à cette question et au temps de réponse du ping voici une petite fonction maison.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
// Syntaxe :
//PING1 (<pAdresse> est chaîne [, <pBoucle> est entier [, <pTimeOut> est entier]])
//
// Paramètres :
//	pAdresse (chaîne) : adresse IP
//	pBoucle (entier - valeur par défaut=1) : nombre de ping
//	pTimeOut (entier - valeur par défaut=250) : timeout du ping en ms
// Valeur de retour :
// 	Aucune
 
PROCEDURE PING1(pAdresse est une chaîne,pBoucle est entier  = 1,pTimeOut est entier  =250)
j est entier
 
//exemple d'utilisation PING1(NetAdresseIP("www.free.fr"),100)
//exemple d'utilisation PING1("192.168.1.14",1,1)
 
XIpAdress est un entier sans signe
XretVal est un entier
XSize est un entier
XhIcmp est un entier sans  signe
Xerror est entier
XVmoy est entier
XReplyData est un entier sans signe
 
 
IP_OPTION_INFORMATION est une structure
	TTL est un entier sans signe sur 1 octet
	Tos est un entier sans signe sur 1 octet
	Flags est un entier sans signe sur 1 octet
	OptionsSize est un entier sans signe
	OptionsData est une chaîne fixe sur 128
FIN
 
IP_ECHO_REPLY est une structure
	Address est un tableau fixe de 4 entier sur 1 octet sans signe
	Status est un entier sans signe
	RoundTripTime est un entier sans signe
	DataSize est entier sans signe
	Reserved est un entier sans signe
	data est un entier sans signe
	Options est un  IP_OPTION_INFORMATION
FIN 
XL_EchoReply est un IP_ECHO_REPLY
XL_OptInfo est un IP_OPTION_INFORMATION
 
 
 
XSize = Dimension(XL_EchoReply)
 
XIpAdress = AppelDLL32("Wsock32", "inet_addr", pAdresse)
SI XIpAdress = 0xFFFFFFFF ALORS 
	Info("Adresse non conforme")
	RETOUR
FIN
 
 
POUR j= 1 A pBoucle
	XIpAdress = AppelDLL32("Wsock32", "inet_addr", pAdresse)
	XhIcmp = AppelDLL32("icmp", "IcmpCreateFile")
	XretVal = AppelDLL32("icmp", "IcmpSendEcho", XhIcmp, XIpAdress,Répète("A",32), 32, Null, &XReplyData, XSize, pTimeOut)
	Transfert(&XL_EchoReply,&XReplyData,XSize)
	SELON XL_EchoReply:Status
		CAS 0 :
			trace("Réponse de "+XL_EchoReply:Address[1]+"."+XL_EchoReply:Address[2]+"."+XL_EchoReply:Address[3]+"."+...
			XL_EchoReply:Address[4]+" : Octets="+XL_EchoReply:DataSize+" temps="+XL_EchoReply:RoundTripTime+" ms"+" Satut :"+Remplace(XL_EchoReply:Status[[1]],0,"Ok"))
			XVmoy+=XL_EchoReply:RoundTripTime
		AUTRE CAS :
			Xerror++
	FIN
FIN
AppelDLL32("icmp", "IcmpCloseHandle", XhIcmp)
Info("Succes : "+Val(j-1-Xerror),"Erreur : "+Xerror,"Vitesse Moyenne : "+PartieEntière(Val(XVmoy/(j-1))))

[Bowen]

Imaginons:
Tu pingues un réseau complet.
Tous les postes reçoivent donc le ping en même temps
Tous les postes répondent donc à ton adresse IP en même temps.
(selon le nombre de poste, ça peut faire un sacré nombre...)
Maintenant essayes de savoir combien de collisions de paquets IP tu auras sur ton tronçon réseau avant de recevoir un paquet sur ton poste (rappel: collision = 2 paquets qui essayent de passer en même temps sur le même câble réseau)
Ça donne la réponse à ta question: non, un ping multicast n'est pas possible.
Pour info, tous les logiciels de découverte de réseau fonctionnent en pingant les adresses IP une à une, sur une plage déterminée. Plus la plage est grande et plus le traitement est long.

[danielsoft]

C'est possible sauf que je ne sais pas le faire sous Windows.

Sur linux il suffit de faire :
ping -b 192.168.1.255 ou ping -b 255.255.255.255

sachant que les routeurs bloquent le broadcast, nous avons uniquement les machines du réseau.

Concernant Windows, par défaut il ne répond pas à un ping broadcast, et il faut pour cela changer les paramètres de l'adaptateur réseau dans la base de registre (http://www.tech-faq.com/broadcast-address.shtml)

Le plus simple est donc de faire un ping à chaque machine du réseau avec la procédure ci dessus, qui permet de paramétrer le nombre de ping par adresse et le temps d'attente.

[Bowen]

Sur linux il suffit de faire :
ping -b 192.168.1.255 ou ping -b 255.255.255.255

Je ne savais pas, mais je serais curieux de connaitre le nombre de collisions lors des réponses sur un réseau d'entreprise.
Je sais que ça ne passe pas les routeurs, mais sur ne serais-ce qu'une dizaine de postes, je pense que ça doit saturer.

[danielsoft]

Sur un classe C il n'y a aucun problème. Regarde le lien que j'ai indiqué au-dessus pour avoir une idée du fonctionnement.

De toute façon comme sous windows il faut pour chaque adaptateur faire une modif dans la base de registre de chaque machine pour qu'elle réponde, il vaut mieux faire un ping IP.

[vallgui]

Merci de vos réponses!!!

Désolé du retard.... Mais merci pour toutes vos indications