Discussion :

[koKoTis]

Bonjour, pouriez vous me dire comment obtenir le(s) nom(s) de la (des) connection(s) réseau ?

[ced600]

Essaye ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
strComputer = "."
Set objWMIService = GetObject _
    ("winmgmts:\\" & strComputer & "\root\microsoft\homenet")
Set colItems = objWMIService.ExecQuery("Select * from HNet_Connection")
For Each objItem in colItems
    Wscript.Echo "GUID: " & objItem.GUID
    Wscript.Echo "Is LAN Connection: " & objItem.IsLANConnection
    Wscript.Echo "Name: " & objItem.Name
    Wscript.Echo "Phone Book Path: " & objItem.PhoneBookPath
Next

[koKoTis]

Salut cedi

Ca m'affiche bien le nom de ma connaction réseau, mais je verai cette aprém sur mon pc si ca affiche toutes le connections.

[RadPAT]

Salut,

tu as un lien sympa ici :

http://www.activxperts.com/activmoni...tworking/home/

A++

[koKoTis]

Donc voici une petite modif:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
strComputer = "."
Set objWMIService = GetObject _
    ("winmgmts:\\" & strComputer & "\root\microsoft\homenet")
Set colItems = objWMIService.ExecQuery("Select * from HNet_Connection")
For Each objItem in colItems
    vrNomConnection = vrNomConnection & vbCrLf & objItem.Name
Next
 
Wscript.Echo vrNomConnection

Maitenant, je voudrai que le script créer un menu avec les noms des connaction donc un menu pour choisir la connection.

C'est pour ajouter a un script qui étein ou demarre une connection.

[ced600]

Salut,

tu as un lien sympa ici :

http://www.activxperts.com/activmoni...tworking/home/

A++

Mon code est tirée de cette page

Maitenant, je voudrai que le script créer un menu avec les noms des connaction donc un menu pour choisir la connection.

C'est pour ajouter a un script qui étein ou demarre une connection.

A ma connaissance une connexion réseau ne se démarre pas et ne s'éteins pas. Va faloir que tu m'explique ce que tu entends par la :
- Activer/désactiver la connexion ?
- Afficher l'état de la connection ?
- Se connecter/se déconnecter sur un site ?

[koKoTis]

Activer/désactiver la connexion bien entendu

regarde:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
' http://astase.com/forums/viewtopic.php?id=3094
 
 
Const ssfCONTROLS = 3
 
'"Connexion au réseau local" pour une connexion réseau classique RJ45 ou "Connexion réseau sans fil" pour la connexion Wifi
sConnectionName = "Connexion au réseau local"
sConnectionDir = "Connexions réseau"                        'Pour Windows XP
'sConnectionDir = "Connexions réseau et accès à distance"   'Pour Windows 2000
 
sEnableVerb = "&Activer"
sDisableVerb = "&Désactiver"
 
set shellApp = createobject("shell.application")
set oControlPanel = shellApp.Namespace(ssfCONTROLS)
 
set oNetConnections = nothing
for each folderitem in oControlPanel.items
  if folderitem.name  = sConnectionDir then
    set oNetConnections = folderitem.getfolder: exit for
  end if
next
 
if oNetConnections is nothing then
  msgbox "Ne peut trouver le dossier '"+sConnectionDir+"'"
  wscript.quit
end if
 
set oLanConnection = nothing
for each folderitem in oNetConnections.items
  if lcase(folderitem.name)  = lcase(sConnectionName) then
    set oLanConnection = folderitem: exit for
  end if
next
 
if oLanConnection is nothing then
  msgbox "Impossible de trouver la connection :  '" & sConnectionName & "'"
  wscript.quit
end if
 
bEnabled = true
set oEnableVerb = nothing
set oDisableVerb = nothing
s = "Verbs: " & vbcrlf
for each verb in oLanConnection.verbs
  s = s & vbcrlf & verb.name
  if verb.name = sEnableVerb then
    set oEnableVerb = verb 
    bEnabled = false
  end if
  if verb.name = sDisableVerb then
    set oDisableVerb = verb 
  end if
next
 
'debugging displays left just in case...
'
'MsgBox s ': wscript.quit
'MsgBox "Enabled: " & bEnabled ': wscript.quit
 
'not sure why, but invokeverb always seemed to work
'for enable but not disable. 
'
'saving a reference to the appropriate verb object
'and calling the DoIt method always seems to work.
'
if bEnabled then
'  oLanConnection.invokeverb sDisableVerb
  oDisableVerb.DoIt
else
'  oLanConnection.invokeverb sEnableVerb
  oEnableVerb.DoIt
end if
 
'adjust the sleep duration below as needed...
'
'if you let the oLanConnection go out of scope
'and be destroyed too soon, the action of the verb
'may not take...
'
wscript.sleep 1000

[ced600]

ha ok, ça c'est fait :

C'est pour ajouter a un script qui étein ou demarre une connection.

Et tu veux faire cela :

Maitenant, je voudrai que le script créer un menu avec les noms des connaction donc un menu pour choisir la connection.

Sous console dos où en utilisant les message box ?

[koKoTis]

message box

[RadPAT]

Et tu veux faire cela : Sous console dos où en utilisant les message box ?

Je crois que c'est le bon moment pour se mettre au HTA !!

Je regarde vite fait si j'ai le temps de vous préparer qquechose.

A++

[koKoTis]

Je crois que c'est le bon moment pour se mettre au HTA !!

Je regarde vite fait si j'ai le temps de vous préparer qquechose.

A++

merci

[ced600]

En comparaison avec la solution HTA que RadPat va nous proposer, pour faire ton menu en messagebox, il faut utiliser donc les messagebox et les inputbox.

Pas terrible en VBS car ces composants sont basique, MAIS dans les contributions, un membre habitué au forum vbs nous a donné quelque chose d'intéressant : InputBox Etendu

[koKoTis]

Mais il faudrai que j'installe son outils ou que je renome un fichier non ?

[ced600]

Nop juste besoin de placer les dll dans le répertoire où se trouve les scripts comme il le dit dans le pdf.
Par contre je ne sais pas si cela marche sous vista, je n'y pensais plus.

[koKoTis]

Il me faudrai un scipt qui ne demande pas d'ajouter des fichier dll

[RadPAT]

Voilà, tu copies ca dans un fichier que tu nommes .HTA.
Ensuite tu insères tes lignes d'arret et de redémmarrage (de ton post précedent) au niveau des lignes taggées :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
 
<html>
<head>
<title>ActiveDesactiveComm</title>
<HTA:APPLICATION
     ID="ActiveDesactiveComm"
     APPLICATIONNAME="ActiveDesactiveComm"
     SCROLL="no"
     SINGLEINSTANCE="yes"
     WINDOWSTATE="normal"
     CAPTION="yes"
>
</head>
<style>
BODY
{
   background-color: buttonface;
   font-family: Helvetica;
   font-size: 10pt;
   margin-top: 10px;
   margin-left: 20px;
   margin-right: 20px;
   margin-bottom: 10px;
}
 
.button
{
   font-family: Helvetica;
   font-size: 8pt;
}
</style>
 
<SCRIPT Language="VBScript">
Sub Window_Onload
    On error resume next
    ListView1.font = "arial"
    ListView1.View = 3
    ListView1.GridLines = True
    ListView1.ColumnHeaders.Add , , "Name", 200
    ListView1.ColumnHeaders.Add , , "IsLANConnection", 100
    ListView1.ColumnHeaders.Add , , "GUID", 150
    ListView1.ColumnHeaders.Add , , "PhoneBookPath", 300
 
 
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor")
    For Each objItem in colItems
        intHorizontal = objItem.ScreenWidth
        intVertical = objItem.ScreenHeight
    Next
 
    XPos = 800
    YPos = 390
 
    intLeft = (intHorizontal - XPos) / 2
    intTop = (intVertical - YPos) / 2
 
    self.ResizeTo Xpos,YPos
    window.moveTo intLeft, intTop
    strComputer = "."
    Set objWMIService = GetObject _
    ("winmgmts:\\" & strComputer & "\root\microsoft\homenet")
    Set colItems = objWMIService.ExecQuery("Select * from HNet_Connection")
    For Each objItem in colItems
        Set itmx = ListView1.ListItems.Add(, ,objItem.Name)
        If objItem.IsLANConnection = True Then
           itmX.SubItems(1) = "Enabled"
        Else
           itmX.SubItems(1) = "Disabled"
        End If
        itmX.SubItems(2) = objItem.GUID
        itmX.SubItems(3) = objItem.PhoneBookPath
    Next
 
End Sub
 
Sub Refresh
 
    ListView1.ListItems.Clear()
    Window_Onload
 
End Sub
 
Sub ListView1_ColumnClick(ColumnHeader)
	With ListView1
		.Sorted = False
		.SortKey = ColumnHeader.Index - 1
		If .SortOrder = 0 Then
			.SortOrder = 1
		Else
			.SortOrder = 0
		End If
		.Sorted = True
	End With
End Sub
 
Sub ListView1_Click
 
 
    If ListView1.SelectedItem.SubItems(1) = "Disabled" Then
       strAction = "enable"
    Else
       strAction = "disable"
    End if
    Quest = MsgBox("The connexion " & ListView1.SelectedItem & " is actually " & ListView1.SelectedItem.SubItems(1) & ", do you want to " &  strAction & " it ?",vbQuestion + vbYesNoCancel + vbApplicationModal + 0,"Action")
 
    If Quest = VbYes Then
       If strAction = "enable" Then
       'mettre ici le script de démarrage avec ListView1.SelectedItem comme nom de connexion
       Else
 
       'mettre ici le script d'arret avec ListView1.SelectedItem comme nom de connexion
 
       End If
       Refresh
    Else
       Msgbox "Command aborted."
    End If
 
 
End Sub
 
 
Sub Quitter
 
    self.Close()
 
End sub
 
</SCRIPT>
 
<body bgcolor="buttonface">
 
<table WIDTH="100%" BORDER=1>
<td VALIGN=TOP WIDTH="18%" COLUMN=1>
 
<td width="750" height="240" style="border: 1px solid #C0C0C0">
<OBJECT ID="ListView1" style="font-size:8pt" WIDTH=750 HEIGHT=250 CLASSID="CLSID:BDD1F04B-858B-11D1-B16A-00C0F0283628">
		        <PARAM NAME="SortKey" VALUE="0">
		        <PARAM NAME="View" VALUE="3">
		        <PARAM NAME="Arrange" VALUE="0">
		        <PARAM NAME="LabelEdit" VALUE="1">
		        <PARAM NAME="SortOrder" VALUE="0">
		        <PARAM NAME="Sorted" VALUE="-1">
		        <PARAM NAME="MultiSelect" VALUE="0">
		        <PARAM NAME="LabelWrap" VALUE="-1">
		        <PARAM NAME="HideSelection" VALUE="0">
		        <PARAM NAME="HideColumnHeaders" VALUE="0">
		        <PARAM NAME="OLEDragMode" VALUE="0">
		        <PARAM NAME="OLEDropMode" VALUE="0">
		        <PARAM NAME="AllowReorder" VALUE="-1">
		        <PARAM NAME="Checkboxes" VALUE="0">
		        <PARAM NAME="FlatScrollBar" VALUE="0">
		        <PARAM NAME="FullRowSelect" VALUE="-1">
		        <PARAM NAME="GridLines" VALUE="-1">
		        <PARAM NAME="HotTracking" VALUE="0">
		        <PARAM NAME="HoverSelection" VALUE="0">
		        <PARAM NAME="PictureAlignment" VALUE="0">
	                <PARAM NAME="TextBackground" VALUE="0">
                        <PARAM NAME="ForeColor" VALUE="-2147483640">
	                <PARAM NAME="BackColor" VALUE="-2147483624">
		        <PARAM NAME="BorderStyle" VALUE="0">
		        <PARAM NAME="Appearance" VALUE="0">
		        <PARAM NAME="MousePointer" VALUE="0">
		        <PARAM NAME="Enabled" VALUE="1">
		        <PARAM NAME="NumItems" VALUE="0">
	   		<param name="OLEDragMode" value="0">
			<param name="OLEDropMode" value="0">
</OBJECT>
 
 
</Table>
</p>
 
<fieldset>
<br>
<Center>
<input id=Quitbutton  class="button" type="button" value="   Quit   " name="Quitter_Button"  onClick="Quitter">
</center>
<br>
</fieldset>
</body>
</html>

Dans la listview, tu cliques sur une ligne pour avoir une msgbox de confirmation d'action et tu confirmes ou pas.
Ce qu'il y a de bien avec le HTA c'est que tous les pc windows sont capable de comprendre sans add on ou ajout.

A++

[koKoTis]

Ou fada, c'est genial ton truc

Merci beaucoup

Je n'imagine pas qu'on pouvai faire ce genre de truc

vbs & hta, quel melange

[RadPAT]

Et à coder c'est tout con.
Tu as été voir le scriptomatic comme je te l'ai conseillé ? Et ben c'est du HTA.
Si tu veux en savoir plus sur le HTA, télécharge le HelpoMatic.HTA de chez crosoft, ca t'apprendra les bases comme les listboxes, les cases à cocher, boutons radio...

http://www.microsoft.com/downloads/d...displaylang=en

A++

[koKoTis]

Et à coder c'est tout con.
Tu as été voir le scriptomatic comme je te l'ai conseillé ? Et ben c'est du HTA.
Si tu veux en savoir plus sur le HTA, télécharge le HelpoMatic.HTA de chez crosoft, ca t'apprendra les bases comme les listboxes, les cases à cocher, boutons radio...

http://www.microsoft.com/downloads/d...displaylang=en

A++

Merci beaucoup je vai étudier ce language hta & vbs

[koKoTis]

mais pourai tu m'aider a intégrer mon vbs dans ton hta ?

Sur cette ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
sConnectionName = "Connexion au réseau local"

Il faut que je determine le nom de la connection sur la quel on clique, il est stocker dans une variable ce nom ?

Et je ne sui pas capable de dire quel partie du vbs active la connection est quelle partie la désactive