compacte base sans access [Résolu]

[popofpopof]

bonjour

je suis sous windows serveur 2003 et access n'est pas installe.

je sais que ci access est installe on peux faire :
"C:\Program Files\Microsoft Office\Office\MSACCESS.EXE" "C:\.....\bd1.mdb" /compact

avec une programmation de nuit.

je souhaite savoir ci on peux ce passe d'access pour compacte une base??

[LedZeppII]

Bonjour popofpopof,

tu peux essayer Comment compacter une base de données avec ADO ?

Exemple d'exploitation en VB Script

Code vbs :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Dim jro, fso
Dim strBD, strBDCPCT, strBDBAK, ErrNum, ErrDesc, ErrFile
Dim strBDwoExt, strBDext, pos
 
strBD = "E:\base2-2000-.mdb"
 
' Coupe nom complet en nom + extension
pos = InStrRev(strBD, ".")
If pos < 1 Then pos = Len(strBD) + 1
strBDwoExt = Left(strBD, pos - 1)
strBDext = Mid(strBD, pos, Len(strBD) + 1 - pos)
 
' Crée nom base compactée, nom base sauvegardée
strBDCPCT = strBDwoExt & "Cpct" & strBDext
strBDBAK = strBDwoExt & ".bak" & strBDext
 
' Supprime base compactée si existe
Set fso = CreateObject("Scripting.FileSystemObject")
If fso.FileExists(strBDCPCT) Then fso.DeleteFile strBDCPCT
 
' Compacte base dans base compactée
Set jro = CreateObject("jro.JetEngine")
ErrNum = 0
On Error Resume Next
' Si mot de passe, ajouter ;Jet OLEDB:Database Password=
' Pour spécifier format base compactée ajouter ;Jet OLEDB:Engine Type=
'	4 pour jet 3.x
'       5 pour Jet 4.0
jro.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strBD , _
 		    "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strBDCPCT 
ErrNum = Err.Number: ErrDesc = Err.Description
On Error GoTo 0
 
' Si pas d'erreur renomme base en base sauvegardée
'                 renomme base compactée en base
If ErrNum = 0 Then
   If fso.FileExists(strBDBAK) Then fso.DeleteFile strBDBAK
   fso.MoveFile strBD, strBDBAK
   fso.MoveFile strBDCPCT, strBD
else
   Set ErrFile = fso.CreateTextFile(strBDwoExt & "ERR.txt", True, False)
   ErrFile.Write FormatDateTime(Now, 2) & "  " & FormatDateTime(Now, 3) & _
                 "  Erreur " & CStr(ErrNum) & " : " & ErrDesc
   ErrFile.Close
End If

A+

[popofpopof]

merci bcp sa marche super bien je le recommande a tout le monde et encore merci a toi pour change .... ( toujours le même a trouvé les idées)