Probleme Trigger et curseur

[snkyo]

Bonjour,

Je voudrai verifier sur ma base que les prenoms inseré dans ma table etudiant sont bien des prenom de garcons. Pour cela j'ai crée une table prenom contenant un dictionnaire de prenom de garcon. J'ai ensuite crée ce trigger qui se compile bien mais fait finalement l'inverse de ce que je veux:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
CREATE OR REPLACE TRIGGER TRIGG_PRENG
BEFORE INSERT OR UPDATE ON ETUDIANTS
FOR EACH ROW
declare cursor PREN_CUR IS
SELECT DISTINCT id,prenom FROM PRENOMS_GARCONS;
PREN etudiants.prenom%TYPE;
Id PRENOMS_GARCONS.id%TYPE;
erreur EXCEPTION;
begin
open PREN_CUR;
loop
fetch PREN_CUR INTO Id,PREN;
exit when PREN_CUR%NOTFOUND;
IF (:new.civ='Monsieur') OR (:new.civ='Mr') AND :new.PRENOM NOT LIKE PREN then
RAISE erreur;
end IF ;
end loop;
close PREN_CUR;
EXCEPTION
	WHEN erreur THEN
		RAISE_application_error(-20002,'Ce n est pas un prenom de garcon');
end;
/

Code :

INSERT INTO ETUDIANTS (NUMETUDIANT,CIV,NOM,PRENOM,TELFIXE,TELMOB,DNETUD,ADRNUM,ADRRUE,ADRCP,ADRVILLE) VALUES('E48','Mr','Clement','Clement','0157708080','0653777780','vendredi, octobre 16, 1987','105','Rue de Belleville', '75019','PARIS');

Cette insertion passe dans l'exception je ne vois pas pourquoi alors que le prenom Clement figure bien dans ma table prenom.

Merci pour vos reponses

[Michel SALAIS]

Envoyé par snkyo

IF (:new.civ='Monsieur') or (:new.civ='Mr') AND :new.PRENOM NOT LIKE PREN

Je n'ai pas regardé le reste attentivement mais ici il y deux points
- Pourquoi "not like"? "!=" suffirait normalement
- l'erreur par contre est la non utilisation de parenthèses!

Ce qui est écrit sera exécuté ainsi :

Code :

1
2
IF (:new.civ='Monsieur') or ( (:new.civ='Mr') AND :new.PRENOM NOT LIKE PREN )

Or je suppose que ce qui est attendu est ceci :

Code :

1
2
IF ( (:new.civ='Monsieur') or (:new.civ='Mr') ) AND :new.PRENOM NOT LIKE PREN

[orafrance]

c'est pas plus simple de faire:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
CREATE OR REPLACE TRIGGER TRIGG_PRENG
BEFORE INSERT OR UPDATE ON ETUDIANTS
FOR EACH ROW
DECLARE
dummy INTEGER;
BEGIN
IF (:new.civ='Monsieur') OR (:new.civ='Mr') THEN
  SELECT 1
     INTO dummy
    FROM DUAL
  WHERE EXISTS (
           SELECT 1 
             FROM PRENOMS_GARCONS
           WHERE prenom = :new.PRENOM
                       );
END IF;
EXCEPTION WHEN NO_DATA_FOUND THEN 
RAISE_application_error(-20002,'Ce n est pas un prenom de garcon');
END;
/

[snkyo]

Merci beaucoup cette solution fonctionne parfaitement et est bien moins lourde

Bonne soirée

[LBO72]

La solution du grand Maitre OraFrance me convient très bien. Est-ce qu'on ne peut pas l'écrire comme suit :

CREATE OR REPLACE TRIGGER TRIGG_PRENG
BEFORE INSERT OR UPDATE ON ETUDIANTS
FOR EACH ROW
DECLARE
dummy INTEGER;
BEGIN
IF (:new.civ='Monsieur' OR :new.civ='Mr') THEN
SELECT 1 INTO dummy
FROM PRENOMS_GARCONS
WHERE prenom = :new.PRENOM;
END IF;
EXCEPTION WHEN NO_DATA_FOUND THEN
RAISE_application_error(-20002,'Ce n est pas un prenom de garcon');
END;
/

Merci.
LBO72.

[LBO72]

Je pense que ma solution ne fonctionnerait pas s'il y'a plusieurs même PRENOM

LBO72.

[orafrance]

en effet, d'où le EXISTS

mais tu peux aussi ajouter :

Code :

EXCEPTION WHEN NO_MANY_ROWS THEN NULL;

pour éviter de générer une erreur si le prénom est plusieurs fois présent... tu peux aussi ajouter un DISTINCT à ton SELECT mais çà impose un tri