Discussion :

[drthodt]

Bonjour à tous,
j'aimerais affecter à une cellule une formule contenant un lien hypertexte (voir mon post http://www.developpez.net/forums/sho...d.php?t=430040 sur les liens dans un classeur partagé).

Ma macro: ouvre une boîte de dialogue, je sélectionne un fichier Word et j'aimerais insérer dans mon fichier EXCEL le nom du fichier + l'hyperlien pointant vers lui.

Je me heurte à une erreur d'exécution 1004, que j'aimerais esquiver de la manière suivante:
récupérer dans une variable String la formule contenant mon lien (de la forme =Lien_Hypertexte ("chemin";"nom du lien").
J'arrive bien à affecter cette valeur à mon String, mais dès que je veux recopier ça dans une cellule j'ai à nouveau l'erreur 1004! (je travaille sur un classeur non partagé pour le moment).
J'aimerais bien savoir d'ou vient cette erreur?

Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub InsererDemande()
 
'nécessite d'activer la référence Microsoft Word xx.x Object Library
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim Fichier As Variant
Dim Pos, DerniereLigne As Integer
Dim NomFichier, chemin, nomFichierSansExtension, Lien As String
 
 
'affichage boite de dialogue pour choisir un document Word
Fichier = Application.GetOpenFilename("Text Files (*.doc*), *.doc*")
If Fichier = False Then Exit Sub
 
 
 
'le document Word est supposé fermé avant le lancement de la macro
Set WordApp = CreateObject("Word.Application")
WordApp.Visible = False 'pour que word reste masqué pendant l'opération
Set WordDoc = WordApp.Documents.Open(Fichier) 'ouverture du fichier Word
WordDoc.Unprotect
 
    NomFichier = WordDoc
 
        Pos = InStr(1, NomFichier, ".", 1)
        nomFichierSansExtension = Left(NomFichier, Pos - 1)
        chemin = WordDoc.Path & "\" & WordDoc
 
'Identification de la première ligne vide pour y recopier les données
DerniereLigne = Range("A65535").End(xlUp).Row + 1
 
Lien = "=LIEN_HYPERTEXTE(" + "'" + "'" + WordDoc.Path + "\" + WordDoc + "'" 
Cells(DerniereLigne, 1) = "=LIEN_HYPERTEXTE(" + "'" + "'" + WordDoc.Path + "\" + WordDoc + "'" + "'" + ";" + "'" + "'" + nomFichierSansExtension + "'" + "'" + ")"
 
 
WordDoc.Close False 'ferme le document Word sans sauvegarde
WordApp.Quit 'ferme l'application Word
 
End Sub

Si je mets un msgbox de test "Msgbox Lien" juste après l'affectation de valeur à ma variable Lien j'ai le bon texte qui s'affiche (texte correspondant à la formule que je dois affecter à ma cellule).Hors si je rentre la formule en manuel ça marche très bien, mais par macro j'ai l'erreur 1004 à ce niveau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cells(DerniereLigne, 1)=Lien

(comme je l'ai dit la valeur de ma variable Lien est après test par msgbox EXACTEMENT celle qu'il faut;quand je recopie le texte qu'elle m'affiche à la main ma cellule l'accepte et mon lien fonctionne,mais jamais par macro juste en manuel).
Merci de votre attention et de vos remarques,
M

[Pierre Fauconnier]

Bonjour

Le problème se situe dans la création de la chaine à la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Lien = "=LIEN_HYPERTEXTE(" + "'" + "'" + WordDoc.Path + "\" + WordDoc + "'"

Tu utilises l'apostrophe doublée au lieu du guillemet, et tu ne fermes pas la parenthèse de fin de fonction.

De plus, il est préférable d'utiliser l'opérateur de concaténation & plutôt que l'opérateur d'addition +.

Utilise plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Lien = "=LIEN_HYPERTEXTE(""" & WordDoc.Path & "\" & WordDoc & """)"

[ouskel'n'or]

Déjà, si tu veux placer dans Excel un lien hypertexte avec un document Word, tu n'es pas obligé d'ouvrir le Doc Word. Suffit que tu le sélectionnes dans la boîte de dialogue pour avoir le nom et le path.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub test
Dim FL As Worksheet, DerniereLigne as long
Set FL = ActiveSheet
    fileToOpen = Application.GetOpenFilename("Text Files (*.Doc), *.Doc")
    DerniereLigne = FL.Range("A65535").End(xlUp).Row + 1
    FL.Hyperlinks.Add FL.Range("A1").Offset(DerniereLigne, 0), fileToOpen
End sub

Tu peux tester pour nous ?
A+

[drthodt]

Bonjour

Le problème se situe dans la création de la chaine à la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Lien = "=LIEN_HYPERTEXTE(" + "'" + "'" + WordDoc.Path + "\" + WordDoc + "'"

Tu utilises l'apostrophe doublée au lieu du guillemet, et tu ne fermes pas la parenthèse de fin de fonction.

De plus, il est préférable d'utiliser l'opérateur de concaténation & plutôt que l'opérateur d'addition +.

Utilise plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Lien = "=LIEN_HYPERTEXTE(""" & WordDoc.Path & "\" & WordDoc & """)"

Désolé erreur de copier/coller j'ai bien refermé ma parenthèse (comme je le dit ma syntaxe est correcte puisque je récupère dans ma msgbox de test exactement le même texte qui foncionne lorsque je l'entre en manuel,donc pourquoi une erreur lorsque je fais pas macro?).

Je fais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Lien = "=LIEN_HYPERTEXTE(" + "'" + "'" + WordDoc.Path + "\" + WordDoc + "'" + "'" + ";" + "'" + "'" + nomFichierSansExtension + "'" + "'" + ")"

puis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cells(DerniereLigne, 1) = Lien

.

Tu me dis d'utiliser plutôt & que +, mais j'ai un souci de syntaxe: tu as oublié la partie: Lien_Hypertexte( chemin; Nom Lien) dans ton exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Lien = "=LIEN_HYPERTEXTE(""" & WordDoc.Path & "\" & WordDoc & """)"

; il me manque donc le morceau de fin par rapport au lien que je veux créer mais je n'arrive pas à appliquer ta syntaxe pourrais-tu m'aider stp?

[drthodt]

Déjà, si tu veux placer dans Excel un lien hypertexte avec un document Word, tu n'es pas obligé d'ouvrir le Doc Word. Suffit que tu le sélectionnes dans la boîte de dialogue pour avoir le nom et le path.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub test
Dim FL As Worksheet, DerniereLigne as long
Set FL = ActiveSheet
    fileToOpen = Application.GetOpenFilename("Text Files (*.Doc), *.Doc")
    DerniereLigne = FL.Range("A65535").End(xlUp).Row + 1
    FL.Hyperlinks.Add FL.Range("A1").Offset(DerniereLigne, 0), fileToOpen
End sub

Tu peux tester pour nous ?
A+

Merci pour ton exemple mais ma macro ne fait pas uniquement cela (j'ai enlevé la partie qui fonctionne pour qu'on se concentre uniquement sur mon problème de lien): à savoir que par ma macro j'ouvre un formulaire standard Word, et je récupère certains champs (nom du demandeur,date) que je liste dans une mini base de données Excel pour effectuer un suivi de ces demandes qui ont été faites par formulaire.Je suis donc bien obligé d'ouvrir le Word.

Pour mon besoin de lien: sur chaque ligne je désire en fait créer un raccourci automatique vers le formulaire d'origine,et donc récupérer le chemin afin de l'inscrire sur mon fichier Excel: ce fichier Excel étant partagé et Excel n'acceptant pas l'insertion de lien hypertexte en mode partagé,je suis obligé de passer par l'insertion d'une formule lien hypertexte car celle-ci fonctionne lorsqu'on l'applique en manuel (même en mode partagé);par contre comme vous avez pu voir j'ai quelques difficultés à l'insérer en mode automatique.
Merci pour votre aide en tout cas,
Bon appétit ,
M

[ouskel'n'or]

Ah ben si tu dis pas tout...
As-tu essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
Dim FL1 As Worksheet
Set FL1 = ActiveSheet
    fileToOpen = Application.GetOpenFilename("Text Files (*.Doc), *.Doc")
    DerniereLigne = FL1.Range("A65535").End(xlUp).Row + 1
    FL1.Range("A1").Offset(DerniereLigne, 0).FormulaLocal = _
                 "=LIEN_HYPERTEXTE(""" & fileToOpen & """;"""")"
End Sub

A+

[drthodt]

Ah ben si tu dis pas tout...
As-tu essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
Dim FL1 As Worksheet
Set FL1 = ActiveSheet
    fileToOpen = Application.GetOpenFilename("Text Files (*.Doc), *.Doc")
    DerniereLigne = FL1.Range("A65535").End(xlUp).Row + 1
    FL1.Range("A1").Offset(DerniereLigne, 0).FormulaLocal = _
                 "=LIEN_HYPERTEXTE(""" & fileToOpen & """;"""")"
End Sub

A+

Il ne se passe rien (désolé je débute: ça correspond à quoi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Offset(DerniereLigne, 0).

).

Pour mon lien hypertexte: il faut qu'il ait impérativement le nom du fichier en plus de pointer vers lui.

[ouskel'n'or]

Il ne se passe rien (désolé je débute: ça correspond à quoi

C'est une impression fausse ! Fais un clic sur la dernière ligne ou celle d'en dessous, tu verras que ton lien s'y trouve bien mais est "transparent"
FL1.Range("A1").Offset(DerniereLigne, 0) désigne la dernière ligne + 1 de la colonne A.

NB - Pour entrer dans la cellule sans ouvrir le lien, utilise les flêches de direction, pas la souris
Tu dis

Edit
Tu peux voir ton champ en faisant dans Excel -> Outils -> Options -> Affichage -> Formules
Juste pour voir

[drthodt]

C'est une impression fausse ! Fais un clic sur la dernière ligne ou celle d'en dessous, tu verras que ton lien s'y trouve bien mais est "transparent"
FL1.Range("A1").Offset(DerniereLigne, 0) désigne la dernière ligne + 1 de la colonne A.

NB - Pour entrer dans la cellule sans ouvrir le lien, utilise les flêches de direction, pas la souris
Tu dis

Edit
Tu peux voir ton champ en faisant dans Excel -> Outils -> Options -> Affichage -> Formules
Juste pour voir

Autant pour moi: ça fonctionne,même en mode partagé.
Par contre le lien est bien transparent comme tu dis, mais comment puis-je écrire du texte dans ma cellule (pour nommer le lien) sans effacer les infos?
Si j'écris du texte dans la cellule après y avoir inséré le lien,le texte a bien la mise en forme d'un lien hypertexte (texte souligné) mais le lien ne pointe plus vers mon fichier.
Merci d'avance,
M

[drthodt]

Ok j'ai trouvé la bonne syntaxte;
par rapport à ma macro ça donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Cells(DerniereLigne, 1).FormulaLocal = _
                 "=LIEN_HYPERTEXTE(""" & Fichier & """;""" & nomFichierSansExtension & """)"

Comme quoi on peut mettre des liens hypertexte même en mode partagé!
Grand merci pour ton aide.
Bonne après-midi ,
M

[SilkyRoad]

http://www.developpez.net/forums/sho...9&postcount=13

est ce qu'on peut m'expliquer pourquoi il y a deux fils de discussion pour un meme sujet ?

[ouskel'n'or]

http://www.developpez.net/forums/sho...9&postcount=13
est ce qu'on peut m'expliquer pourquoi il y a deux fils de discussion pour un meme sujet ?

Bonjour Michel,
On peut suggérer une raison à cette question : Les guillemets dans l'utilisation de variables dans la formule... (?)
Mais peut-on m'expliquer pourquoi il y a deux discussions sur le même sujet ?
Bonne journée