Faire des copies de Sauvegarde facilement pendant le développement [Sources]

[mout1234]

Bonjour à tous,

On ne le conseillera jamais assez, prenez la précaution de faire de copies de sauvegarde très fréquemment durant vos phases de développement.

Même si vos fichiers sont sauvegardés tous les soirs sur un serveur, c'est bien souvent insuffisant car en cas de problème, vous perdez parfois une journée de travail... voire tout si vous n'avez pas archivé plusieurs sauvegardes...


En complément, il me parait donc judicieux de faire une copie intermédiaire régulièrement.

Pour faire cela facilement, pour chaque projet je crée dans le répertoire du projet deux sous répertoires:
MonProjet

• Dev
• Save

Le répertoire Dev contient tous les fichiers en cours de développement.
Le répertoire Save contient des copies de ce répertoire Dev, classés dans des sous répertoires rappelant la date de cette sauvegarde.

Pour effectuer rapidement ces sauvegardes, je lance dés que je le juge nécessaire (plusieurs fois par jour et lors de grosses modifications) un petit script vbs:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Dim oFSO
Dim sSrcPath
Dim sDestPath
 
 
Dim oFold
Dim sProjectName
 
 
Set oFSO = CreateObject("Scripting.FileSystemObject")
 
 
sSrcPath = oFSO.GetParentFolderName(Wscript.ScriptFullName)
set oFold= oFSO.GetFolder(oFSO.GetParentFolderName(sSrcPath))
sProjectName = oFold.Name
 
sDestPath = oFSO.BuildPath(oFold.Path,"Save") 
sDestPath = sDestPath  &  "\" & sProjectName &  Year(Date) & Right("00" & Month(Date), 2) & Right("00" & Day(Date), 2) & "_" & Right("00" & Hour(Now()), 2) & "h" & Right("00" & Minute(Now()), 2)
msgbox sDestPath
oFSO.CreateFolder sDestPath
 
 
' Dupliquer le répertoire
    oFSO.CopyFolder sSrcPath, sDestPath, True
    MsgBox "Copie effectuée dans " &  sDestPath, 64
 
Set oFSO = Nothing

Bien sur, au fur et à mesure de l'avancement du projet, je supprime les sauvegardes intermédiaires.

Bon dev et bonnes sauvegardes

[Philippe JOCHMANS]

Super, j'en fait réguliérement mais manuellement.

Question : Est-ce que ta base doit être fermée ? Il me semble qu'avec FSO ce n'est pas obligatoire. Peux-tu le confirmer.

Starec

[mout1234]

Envoyé par Starec

Super, j'en fait réguliérement mais manuellement.

Question : Est-ce que ta base doit être fermée ? Il me semble qu'avec FSO ce n'est pas obligatoire. Peux-tu le confirmer.

Starec

Non pas obligatoirement.

[Domi2]

Bonjour Mout,

Cela m'intéresse aussi...

Depuis où lances-tu ton code ? Un ou des conseils ?

Domi2

[mout1234]

Bonjour,

Envoyé par Domi2

Bonjour Mout,

Cela m'intéresse aussi...

Depuis où lances-tu ton code ? Un ou des conseils ?

Domi2

Crée simplement un fichier Texte dans le notepad par exemple, et sauvegarde le avec une extension .vbs

Ensuite un double-clic dessus suffira

[Lou Pitchoun]

Question c** ?

Code :

oFSO.GetParentFolderName(Wscript.ScriptFullName)

Ton script tu le mets dans le répertoire MonProjet ?

[Domi2]

Merci Mout,

Comme j'ai plusieurs fichiers (application, librairie, fichiers textes, dll et j'en passe), plus besoin de se creuser la tête...

Tout est copié d'un coup, c'est

Domi2

[mout1234]

Envoyé par Lou Pitchoun

Question c** ?

Code :

oFSO.GetParentFolderName(Wscript.ScriptFullName)

Ton script tu le mets dans le répertoire MonProjet ?

Il est prévu pour être dans le sous répertoire Dev. Comme çà, je l'ai "sous la main"

[bernardmichel]

Génial Mout ! enfin on met un terme au bricolage !!!

Super et merci pour cet apport

[mout1234]

Bonjour à tous,


En passant, je n'ai toujours pas trouvé le moyen de mettre un sablier comme souris (l'équivalent du bon vieux Hourglass VBA) durant l'exécution du script.

Quelqu'un a une idée?

[bernardmichel]

Voilà ce que j'ai trouvé sur le sujet :

Change Cursor to Hour Glass in VB



This little ditty really helps when you want set an HourGlass cursor. There is no need to worry about setting the cursor back because when the routine goes out of scope the class will destroy itself and the cursor will be back to normal.

USE: Dim Hourglass as HourGlass Set HourGlass = New HourGlass Thats it.

Code :

Est-ce que cela correspond à ta demande ?

[mout1234]

Envoyé par bernardmichel

Voilà ce que j'ai trouvé sur le sujet :
Est-ce que cela correspond à ta demande ?

Salut Bernard,
Merci pour vos propositions.... mais sauf erreur de ma part, elles ne sont pas applicables ici: Nous sommes dans un contexte VBSCRIPT et non VB

[alassanediakite]

Salut
Mout je croie avoir quelque chose pour toi (ou plutôt pour nous tous).Ta contribution ne pas laisser le choix.
Je n'ai pas encore tester.
@+

[mout1234]

Envoyé par alassanediakite

Salut
Mout je croie avoir quelque chose pour toi (ou plutôt pour nous tous).Ta contribution ne pas laisser le choix.
Je n'ai pas encore tester.
@+

Merci

[mout1234]

Bonsoir,

Avec l'aide initiée par alassanediakite (voir le code proposé par bbil ici) , voici une nouvelle version du script incluant une fenêtre patienter et un curseur sablier... (à peaufiner ... quand j'aurai le temps )

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Option Explicit
Dim oFSO			'File System Object
Dim oIE				'Internet Explorer
Dim oFold			'Folder
 
Dim sSrcPath		'source Path
Dim sDestPath		'destination path
Dim sProjectName
Dim doc 
 
 
'repérage des dossiers source et destination 
	Set oFSO = CreateObject("Scripting.FileSystemObject")
	sSrcPath = oFSO.GetParentFolderName(Wscript.ScriptFullName) 	'dossier où est stocké le présent script
	set oFold= oFSO.GetFolder(oFSO.GetParentFolderName(sSrcPath))	'dossier parent = racine du projet
	sProjectName = oFold.Name		'le nom du répertoire racine est utilisé comme nom de projet
	sDestPath = oFSO.BuildPath(oFold.Path,"Save")  'destination = sous dossier de SAVE
 
'création du nom du fichier de destination = nom du projet  + YYYYMMDD_HHhNN
'l'ajout du nom du projet n'est pas indispensable: il permet de copier la sauvegarde sur un autre support (clé usb par exemple)  sans se soucier du nom du dossier
	sDestPath = sDestPath  &  "\" & sProjectName &  Year(Date) & Right("00" & Month(Date), 2) & Right("00" & Day(Date), 2) & "_" & Right("00" & Hour(Now()), 2) & "h" & Right("00" & Minute(Now()), 2)
 
'affiche une fenetre d'attente  + sablier
	 Set oIE = CreateObject("InternetExplorer.Application")
 
	 oIE.Navigate "about:blank"
	 oIE.Height = 120
	 oIE.Width = 600
	 oIE.MenuBar = False
	 oIE.Toolbar = False
	 oIE.StatusBar = False
	 oIE.Resizable = False
	 Set doc = oIE.Document
 
	 doc.write "<head><title>-</title></head>"
	 doc.write "<body style=""color: rgb(255, 255, 0); background-color: rgb(0, 0, 0)"">"
	 doc.write "Sauvegarde en cours, veuillez patienter.....<br/><br/>"
	 doc.write sDestPath & "<br/>"
	 doc.write "</body>"
	 doc.body.Style.Cursor = "wait" ' ==> LE Fameux sablier 
	 oIE.Visible = True
 
 
'création du répertoire de sauvegarde
	oFSO.CreateFolder sDestPath 
 
' Dupliquer le répertoire
    oFSO.CopyFolder sSrcPath, sDestPath, True
    MsgBox "Sauvegarde terminée.", 64
 
'fin de la sauvegarde
	oIE.Quit:  set oIE = Nothing
	Set oFSO = Nothing

Merci à tous et... bonnes sauvegardes

[Tofalu]

Plutot qu'un vbs, faudrait en faire un complément Access, comme ça on l'a vraiment sous la main

[Arkham46]

Envoyé par Tofalu

Plutot qu'un vbs, faudrait en faire un complément Access, comme ça on l'a vraiment sous la main

J'osais pas le demander....

Avec un petit formulaire de configuration on pourrait demander une sauvegarde automatique à intervalle régulier.
J'aimerais bien qu'access me dérange avec un message du style :
"Attention ! Vous n'avez pas fait de copie de sauvegarde depuis 15 min
Voulez vous faire une copie de sauvegarde maintenant?"

[Tofalu]

Et une partie permettant de supprimer les sauvegardes. On pourrait même stocker dans une table des commentaires sur les différentes versions

[Arkham46]

Envoyé par Tofalu

Et une partie permettant de supprimer les sauvegardes. On pourrait même stocker dans une table des commentaires sur les différentes versions

Ah oui bien ça!
Du style :
- "sauvegarde avant idée stupide du chef"
- "sauvegarde avant test d'un code copier-coller du net sans rien y comprendre"

Et pis comme ça avec un complément on n'a plus besoin d'internet explorer pour afficher un sablier

J'ai fait un test rapide, le timer dans un complément à l'air de bien se passer, sans être trop perturbé par des activités de débogage dans la base de données en cours de développement.

Pour la suite je n'ai pas le temps pour l'instant....

NB en passant : bonne idée de départ que de faire un outil de sauvegarde pour le développeur

[Domi2]

Bonsoir,

Si je peux me permettre...

L'idée serait de faire tourner une sauvegarde à intervalle régulier (au moyen d'un .mda je suppose) pendant qu'on développe ?

Domi2