exporter requete access vers fichier excel [Résolu]

[pmax35]

Bonjour,

Je développe un application Web en asp.
Je souhaite exporter certaines requêtes issues d'une base de données access vers un fichier excel.

Je n'ai pas trouver de script qui correspond à ma volonté.
Si quelqu'un peut m'aider...

[pmax35]

J'ai recherché sur le Web. Je sais que c'est possible.
Mais nulle part je n'ai trouvé de script ?!?!

[ryan]

Yop!

Voici comment créer un fichier xls sur le serveur et écrire une valeur numérique dans la premier cellule de la première ligne, et une valeur alphanumérique dans la seconde cellule de la première ligne

Code :

1
2
3
4
5
6
7
8
9
10
 
 
    set fsob = Server.CreateObject("Scripting.FileSystemObject")
    set xls = fsob.CreateTextFile("test.xls")    
    xls.writeLine "ID;PWXL;N;E" 
    xls.writeLine "C;Y1;X1;K" & "100"    
    xls.writeLine "C;Y1;X2;K" & chr(34) & "ceci est du texte" & chr(34)
    xls.writeLine "E"
    set xls = Nothing
    set fsob = Nothing

[pmax35]

Merci Ryan de t'intéresser à mon problème.

Le serveur plante au CreateTextFile... (J'ai fait un copier/coller de ton exemple)
"Erreur d'exécution Microsoft VBScript"

Je suis en train de chercher la cause de ce plantage...

[pmax35]

C'était simplement un problème d'URL.
En effet le server attends un chemin non relatif.

Code :

set xls = fsob.CreateTextFile(server.mappath("test.xls"),true,false)

Merci beaucoup Ryan.

Maintenant mon problème est de uploader ce fichier coté client...
par exemple si je remplace "server.mappath('test.xls')" par "C:\Documents and Setting\test.xls" ca ne marche pas

[ryan]

Yop!

Sorry pour le chemin d'accès, j'avais simplifié le code en oubliant ce détail.

Au client, tu proposes un lien vers le fichier xls en demandant d'utiliser le clic droit et l'option "enregistrer sous".

[agrotic]

bonjour,

sinon, tu as beaucoup plus simple :
tu fais une page qui génère un tableau HTML et tu change le content-type du document ! hop, pas besoin d'XLS sur le serveur ni de doc à créer

voici un code ASP qui récupère une requête SQL (db_sql), l'exécute grâce à la chaine de connexion (db_conn) et en fait un fichier XLS (exportAccess.xls)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
dim item
db_SQL = request("db_sql")
set oRSt = server.CreateObject("ADODB.RecordSet")
Response.ContentType="Application/xls"
Response.AddHeader "Content-Disposition", "filename=exportAccess.xls;" ' le nom du fichier
oRSt.open db_SQL, db_conn, 3, 1 
if not oRst.EoF then %>
	<table><tr><%
		for each item in oRst.fields
			response.write "<td>" & item.name & "</td>"
		next %>
	</tr><%
	do while not oRst.EoF
		response.write "<tr>"
		for each item in oRst.fields
			response.write "<td>" & item.value & "</td>"
		next
		response.write "</tr>"
		oRst.MoveNext
	Loop %>
	</table><%
else %>
	<table><tr><td>Rien à exporter</td></tr></table><%
end if 
set oRst = nothing

une belle page générique, facile à réutiliser, comme je les aime.
Nico.

[pmax35]

Les deux solutions me séduisent hmhmmm!
Je ne sais pas encore laquelle je vais choisir

Vraiment un grand merci à vous 2!!

Une dernière petite question pour toi Agrotic.
Sait-tu pourquoi lorsque que l'on veut "enregistrer-sous" le nom de la page par défaut se transforme en "_xls" (au lieu de ".xls")?
Ou
Sait-tu comment peut-on contourner ca pour enregistrer un fichier directement avec l'extension .xls?

Merci

[ryan]

Yop!

L'alternative au "clic droit / enregistrer sous" est d'envoyer le fichier avec l'objet response. J'ai donné le code dans la discussion "sécuriser les documents" initiée par babibel122.

[pmax35]

ca fait plaisir de se sentir écouter, merci!

[agrotic]

et au final, tu as fait comment ?

Envoyé par pmax35

Une dernière petite question pour toi Agrotic.
Sait-tu pourquoi lorsque que l'on veut "enregistrer-sous" le nom de la page par défaut se transforme en "_xls" (au lieu de ".xls")?
Ou
Sait-tu comment peut-on contourner ca pour enregistrer un fichier directement avec l'extension .xls?

ben, perso, avec mon code j'ai pas ce genre de soucis...
c'est quoi ton code ?

[pmax35]

et bien écoute je m'étais résolu à choisir la solution de Ryan mais je viens de réessayer ta solution et ca marche nikel!

alors c'est toi mon élu
euh enfin c'est ta solution agrotic que je vais choisir
car beaucoup plus légère et surtout, comme tu l'as dit : générique!!!

encore merci à vous 2 pour votre altruisme

tchao