[Sources]IP [Fait] [Résolu]

[Ric500]

Bonjour!

Après recherche dans la FAQ ( j'ai trouvé une fonction qui me rend l'IP de mon poste (http://access.developpez.com/faq/?page=API#ip ) c'est exactement ce que je voulais) sauf... qu'elle me rend l'IP de pon PC dans le réseau local. J'avoue que là je bloque un peu pour l'adapter afin d'avoir l'IP Internet réelle, je suis derrière un routeur livebox.

Quelqu'un pourrait-il m'aider à interpréter le code de Morsi ?

Merci d'avance...

[=JBO=]

Bonjour,

Envoyé par Ric500

...je bloque un peu pour l'adapter afin d'avoir l'IP Internet réelle, je suis derrière un routeur livebox.

Quelqu'un pourrait-il m'aider à interpréter le code de Morsi ?

C'est mal parti !
Si j'ai bien compris, tu veux connaître l'adresse IP que ton routeur a obtenu dynamiquement pour communiquer sur l'internet.

As-tu vraiment besoin de cette adresse ?
Tu veux peut-être rendre ton PC joignable de l'extérieur ??
Ou alors c'est autre chose ???

Sinon, il existe un forum pour la livebox...

Bonne chance !

[Maxence HUBICHE]

ben ... je vois bien un petit truc sympa à faire ...
Mais il faudrait une page web.
il y a plein de site qui, lorsque tu t'y connecte, te donnent l'adresse IP sous laquelle tu te connecte.
par exemple :
http://www.anonymat.org/vostraces/index.php

Ensuite, il conviendrait de faire un petit bout de code qui utilise la bibliothèque "Microsoft XML, vx,x" (tu prends la version la plus récente. Chez moi, c'est la version v5.0 => http://msdn.microsoft.com/XML/XMLDownloads/default.aspx)

Tu te fais un module.
Dedans, tu colles ce code :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Option Compare Database
Option Explicit
 
Function GetCleanHTML(ByVal sLink As String) As String
    'Déclarer les variables
    Dim oHttp   As MSXML2.XMLHTTP
    Dim sHTML   As String
    Dim i       As Long
 
    'Déclarer les constantes
    Const XMLHTTP_STATUSOK As Long = 200
    'Créer l'instance de l'objet
    Set oHttp = New MSXML2.XMLHTTP
 
    'Se connecter au site, et récupérer le code HTML
    With oHttp
        .Open "GET", sLink, False
        .send
        sHTML = .responseText
        'Vérifier que tout s'est bien passé
        If .Status = XMLHTTP_STATUSOK Then
            'Si oui, nettoyer le code HTML pour retirer tous les caractères bidons
            For i = 0 To 31
                sHTML = Replace(sHTML, Chr(i), "")
            Next
            sHTML = Replace(sHTML, "     ", " ")
            sHTML = Replace(sHTML, "    ", " ")
            sHTML = Replace(sHTML, "   ", " ")
            sHTML = Replace(sHTML, "  ", " ")
            sHTML = Replace(sHTML, "> <", "><")
 
            'Si non, vider shtml et  générer une erreur
        Else
            sHTML = ""
            Err.Raise 65000, "GetHTML", "Erreur lors de la récupération du HTML : " & oHttp.statusText
        End If
        GetCleanHTML = sHTML
        On Error Resume Next
        .abort
     End With
    Set oHttp = Nothing
End Function
 
Function GetIPFromHTML()
    'Cette procédure a été construite après un examen du code de la page passée en paramètre.
    'Elle n'est donc valide que pour cette page...
 
    'Déclaration des variables
    Dim sHTML_Base As String
    Dim i1 As Long
    Dim i2 As Long
 
    'Déclaration des constantes
    Const HTMLDEBUT As String = "l'adresse IP :</font><br><br><b>"
 
    'Récupérer le HTML propre de la page
    sHTML_Base = GetCleanHTML("http://www.anonymat.org/vostraces/index.php")
 
    'Trouver le début de l'adresse IP
    i1 = InStr(1, sHTML_Base, HTMLDEBUT, vbTextCompare) + Len(HTMLDEBUT)
 
    'Trouver la fin de l'adresse IP
    i2 = InStr(i1 + 1, sHTML_Base, "<")
 
    'Renvoyer l'adresse IP ainsi définie :
    GetIPFromHTML = Trim(Mid(sHTML_Base, i1, i2 - i1))
End Function

Il ne te reste plus qu'à utiliser la fonction GetIPFromHTML et cela devrait être bon
Cool non ?

[=JBO=]

Une réponse juste pour dire à Maxence HUBICHE...

VOILA UN TRES BON PLAN !!!!

[Maxence HUBICHE]

Merci

[Ric500]

Merci Maxence !