Fichier 500-100.asp buggué

Neuromancien2 · 18/06/2007, 10h51

Bonjour,

Sous Windows XP, le fichier 500-100.asp qui gère les erreurs ASP est buggué. Où peut-on trouver le fichier 500-100.asp de Windows 2000 ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Erreur de compilation Microsoft VBScript error '800a0401'
 
Fin d'instruction attendue
 
/iisHelp/common/500-100.asp, line 11
 
Dim objASPError, blnErrorWritten, strServername, strServerIP, strRemoteIP Dim strMethod, lngPos, datNow, strQueryString, strURL
--------------------------------------------------------------------------^
 
Provider error '80004005'
 
Erreur non spécifiée
 
/webdoc/scripts/menu.asp, line 10

jmulans · 19/06/2007, 10h07

c'est courant apparement sous XP, je savais pas qu'elle y etais aussi sous 2000
tu le trouve dans C:\WINDOWS\Help\iisHelp\common
il faut juste passer des lignes sur la ligne indiquer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
  Dim objASPError, blnErrorWritten, strServername, strServerIP, strRemoteIP 
 
  Dim strMethod, lngPos, datNow, strQueryString, strURL
 
  If Response.Buffer Then Response.Clear Response.Status = "500 Erreur interne du serveur" 
 
  Response.ContentType = "text/html" 
 
  Response.Expires = 0 
 
  End If

apres il montre toujours l'erreur sur les pafes de debug, mais ça fonctionne bien (enfin bien

)

Neuromancien2 · 19/06/2007, 11h30

Le problème c'est qu'il y a des dizaines d'erreurs. C'est pourquoi je préfère récupérer le fichier de Windows 2000.

Manatane · 05/09/2007, 17h26

Bon le post est vieux mais moi aussi je voudrais le détail sur la page d'erreur 500,

si une âme charitable sous windows 2000 pouvait nous mettre son "C:\WINDOWS\Help\iisHelp\common\500-100.asp" en ligne

J'ai beau décocher "Afficher des messages d'erreur HTTP simplifiés" je me tape toujours "Internal Server Error" sans plus de détail.

roro06 · 10/09/2007, 13h59

Bonjour

... et voici l'âme charitable :

Je mets ici le 500-100.asp de mon windows 2003 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
<%@ language="VBScript" %>
<%
  Option Explicit
 
  Const lngMaxFormBytes = 200
 
  Dim objASPError, blnErrorWritten, strServername, strServerIP, strRemoteIP
  Dim strMethod, lngPos, datNow, strQueryString, strURL
 
  If Response.Buffer Then
    Response.Clear
    Response.Status = "500 Internal Server Error"
    Response.ContentType = "text/html"
    Response.Expires = 0
  End If
 
  Set objASPError = Server.GetLastError
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN" "http://www.w3.org/TR/html4/strict.dtd">
<HTML>
<HEAD>
<TITLE>Impossible d'afficher la page</TITLE>
<META HTTP-EQUIV="Content-Type" Content="text/html; charset=windows-1252">
<STYLE type="text/css">
  BODY { font: 8pt/12pt verdana }
  H1 { font: 13pt/15pt verdana }
  H2 { font: 8pt/12pt verdana }
  A:link { color: red }
  A:visited { color: maroon }
</STYLE>
<style type="text/css">
<!--
.errDescription {
    font-family: "Courier New", Courier, mono;
    font-weight: bold;
    border: 2px dotted #FF0000;
    font-size: 14px;
    padding: 4px;
}
-->
</style>
</HEAD>
<BODY>
<TABLE border=0 cellspacing=10>
  <TR><TD>
 
<h1>Un gros gros bug est survenu sur votre tentative pitoyable de cr&eacute;er 
        un programme qui fonctionne !</h1>
Un problème est survenu dans la page que vous essayez d'ouvrir et vous ne pouvez donc pas afficher cette page.
<hr>
<p>Essayez les opérations suivantes&nbsp;:</p>
<ul>
        <li>Contactez l'administrateur du site Web (<em>c'est-&agrave;-dire vous-m&ecirc;me 
          - lol</em>) pour lui indiquer que cette erreur s'est produite pour cette 
          adresse URL.</li>
</ul>
      <h2>Erreur HTTP 500.100 - Erreur interne du serveur&nbsp;: Erreur ASP. <em>(ptdr 
        ;-)</em> <br>
        Services Internet (IIS) (<em>vachement avanc&eacute;, hein ?</em>)</h2>
<hr>
<p>Informations techniques (destinées au personnel du Support technique qui va 
        essayer d'y comprendre quelque-chose)</p>
<ul>
<li>Type d'erreur&nbsp;:<br> 
<div class="errDescription"><%
  Dim bakCodepage
  on error resume next
    bakCodepage = Session.Codepage
    Session.Codepage = 1252
  on error goto 0
  Response.Write Server.HTMLEncode(objASPError.Category)
  If objASPError.ASPCode > "" Then Response.Write Server.HTMLEncode(", " & objASPError.ASPCode)
    Response.Write Server.HTMLEncode(" (0x" & Hex(objASPError.Number) & ")" ) & "<br>"
  If objASPError.ASPDescription > "" Then 
    Response.Write Server.HTMLEncode(objASPError.ASPDescription) & "<br>"
  elseIf (objASPError.Description > "") Then 
    Response.Write Server.HTMLEncode(objASPError.Description) & "<br>" 
  end if
  blnErrorWritten = False
  ' Only show the Source if it is available and the request is from the same machine as IIS
  If objASPError.Source > "" Then
    strServername = LCase(Request.ServerVariables("SERVER_NAME"))
    strServerIP = Request.ServerVariables("LOCAL_ADDR")
    strRemoteIP =  Request.ServerVariables("REMOTE_ADDR")
    If (strServerIP = strRemoteIP) And objASPError.File <> "?" Then
      Response.Write Server.HTMLEncode(objASPError.File)
      If objASPError.Line > 0 Then Response.Write ", line " & objASPError.Line
      If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
      Response.Write "<br>"
      Response.Write "<font style=""COLOR:000000; FONT: 8pt/11pt courier new""><b>"
      Response.Write Server.HTMLEncode(objASPError.Source) & "<br>"
      If objASPError.Column > 0 Then Response.Write String((objASPError.Column - 1), "-") & "^<br>"
      Response.Write "</b></font>"
      blnErrorWritten = True
    End If
  End If
  If Not blnErrorWritten And objASPError.File <> "?" Then
    Response.Write "<b>" & Server.HTMLEncode(  objASPError.File)
    If objASPError.Line > 0 Then Response.Write Server.HTMLEncode(", ligne " & objASPError.Line)
    If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
    Response.Write "</b><br>"
  End If
%></div>
 
</li>
<li>Type de navigateur&nbsp;:<br> <%= Server.HTMLEncode(Request.ServerVariables("HTTP_USER_AGENT")) %> <br><br></li>
<li>Page&nbsp;:<br> <%
  strMethod = Request.ServerVariables("REQUEST_METHOD")
  Response.Write strMethod & " "
  If strMethod = "POST" Then
    Response.Write Request.TotalBytes & " bytes to "
  End If
  Response.Write Request.ServerVariables("SCRIPT_NAME")
  Response.Write "</li>"
  If strMethod = "POST" Then
    Response.Write "<p><li>POST Data:<br>"
    ' On Error in case Request.BinaryRead was executed in the page that triggered the error.
    On Error Resume Next
    If Request.TotalBytes > lngMaxFormBytes Then
      Response.Write Server.HTMLEncode(Left(Request.Form, lngMaxFormBytes)) & " . . ."
    Else
      Response.Write Server.HTMLEncode(Request.Form)
    End If
    On Error Goto 0
    Response.Write "</li>"
  End If
%> <br><br></li>
<li>Heure&nbsp;:<br> <%
  datNow = Now()
  Response.Write Server.HTMLEncode(FormatDateTime(datNow, 1) & ", " & FormatDateTime(datNow, 3))
  on error resume next
    Session.Codepage = bakCodepage 
  on error goto 0
%> <br><br></li>
<li>Plus d'informations&nbsp;:<br> <%  
  strQueryString = "prd=iis&sbp=&pver=5.0&ID=500;100&cat=" & Server.URLEncode(objASPError.Category) & "&os=&over=&hrd=&Opt1=" & Server.URLEncode(objASPError.ASPCode)  & "&Opt2=" & Server.URLEncode(objASPError.Number) & "&Opt3=" & Server.URLEncode(objASPError.Description) 
  strURL = "http://www.microsoft.com/ContentRedirect.asp?" & strQueryString
%>
  <ul>
            <li>Cliquez sur <a href="<%= strURL %>">Support technique Microsoft</a> 
              pour obtenir des liens vers des articles relatifs à cette erreur 
              <em>(si si, essayez, vous verrez. Pr&eacute;voir une petite apr&egrave;s-midi, 
              tout de m&ecirc;me)</em></li>
  <li>Sur le site des <a href="http://go.microsoft.com/fwlink/?linkid=8180" target="_blank">Services de support technique de Microsoft</a> effectuez une recherche dans les titres avec les mots <b>HTTP</b> et <b>500</b>.</li>
  <li>Ouvrez l'<b>Aide IIS</b>, qui est accessible dans le Gestionnaire des services Internet (inetmgr) et recherchez les rubriques intitulées <b>Administration de site Web</b> et <b>À propos des messages d'erreur personnalisés</b>.</li>
  <li>Dans le Kit de développement IIS (SDK) ou sur le site <a href="http://go.microsoft.com/fwlink/?LinkId=8181">MSDN Online Library</a>, recherchez les rubriques intitulées <b>Débogage de scripts ASP</b>, <b>Débogage de composants</b> et <b>Débogage d'extensions et de filtres ISAPI</b>.</li>
  </ul>
</li>
</ul>
 
</TD></TR></TABLE></BODY></HTML>

Euh ... il est personalisé ! (un jour de grosse colère

, j'ai craqué !!); faites-en bon usage (seuls les libellés (textes) sont personalisés)

19/06/2007, 11h30	#3
Neuromancien2 Membre confirmé Inscription : mai 2002 Messages : 543 Détails du profil Informations forums : Inscription : mai 2002 Messages : 543 Points : 238 Points : 238	Le problème c'est qu'il y a des dizaines d'erreurs. C'est pourquoi je préfère récupérer le fichier de Windows 2000.
	00

05/09/2007, 17h26	#4
Manatane Invité régulier Inscription : mars 2006 Messages : 12 Détails du profil Informations personnelles : Âge : 29 Informations forums : Inscription : mars 2006 Messages : 12 Points : 8 Points : 8	Bon le post est vieux mais moi aussi je voudrais le détail sur la page d'erreur 500, si une âme charitable sous windows 2000 pouvait nous mettre son "C:\WINDOWS\Help\iisHelp\common\500-100.asp" en ligne J'ai beau décocher "Afficher des messages d'erreur HTTP simplifiés" je me tape toujours "Internal Server Error" sans plus de détail.
	00

Outils de la discussion
Afficher une version imprimable Envoyer un lien vers cette page par email