[VBA-O]Automation Outlook et gestion des boites mail [Résolu]

[killkool2001]

Bonjour,

Je pilote actuellement mon outlook via automation. Grace aux différentes sources trouvés sur les faq vba, j'ai su créer et envoyer un email.

Maintenant je souhaiterais, lorsque mon email est créé, le ranger dans ma boite "courrier non lu" de mon poste, pour vérification manuelle de chaque email.

Malheureusement, la méthode send est simple pour envoyer un objet email, par contre je n'ai pas compris comment on peut utiliser la méthode save (si bien sur il faut utiliser ca...)

Donc si vous aviez des tuyaux, des docs...

Merci d'avance

edit : heu si vous ne comprenez pas dites moi le ^^

[SilkyRoad]

bonjour


Tu peux tester cette macro.
J'ai supposé que le répertoire de transfert était un sous dossier des "éléments envoyés".

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Sub CreationMailEtDeplacement()
    Dim OlApp As Outlook.Application
    Dim OlItem As Outlook.MailItem
    Dim olSpace As NameSpace
    Dim olSendFolder As MAPIFolder, olFolder As MAPIFolder
    Dim t As Date
 
    'Nécessite d'activer la référence
    '"Microsoft Outlook xx.x Object Library"
 
    Set OlApp = New Outlook.Application
    Set OlItem = OlApp.CreateItem(olMailItem)
 
    '---- Création et envoi message ------------
    With OlItem
        .To = "mimi@mail.fr"
        .Subject = "Le titre du message"
        .Body = "Découvrez Microsoft Office sur le site Developpez" & _
            vbLf & vbLf & "Cordialement" & vbLf & Environ("username")
        .Display
        .Send
    End With
 
    '--------------------------------------------
    'Crée une temporisation de 3 secondes (à adapter):
    t = Timer + 3: Do Until Timer > t: DoEvents: Loop
    '--------------------------------------------
 
 
    '---- Transfère le message envoyé -----------
    Set olSpace = OlApp.GetNamespace("MAPI")
    'Définit la boite des éléments envoyés
    Set olSendFolder = olSpace.GetDefaultFolder(olFolderSentMail)
 
    'Définit le sous dossier ou va être déplacé le message
    '********
    '/!\ Dans cet exemple le répertoire "Dossier attente lecture" est un
    'sous dossier, dans les éléments envoyés.
    '********
    Set olFolder = olSendFolder.Folders("Dossier attente lecture")
    'Tranfère le dernier message envoyé
    olSendFolder.Items(olSendFolder.Items.Count).Move olFolder
    '--------------------------------------------
 
 
    Set OlItem = Nothing
    Set OlApp = Nothing
End Sub

Si les messages envoyés sont facilement identifiables, tu pourrais aussi utiliser l'évènement Application_ItemSend directement dans Outlook.


michel

[killkool2001]

Merci ca ma beaucoup aidé à avancer !