Saisie automatique propriétés personnalisés Visio 2007 [FAQ]

[Samlion]

Bonjour à vous
quelqu'un peut me dire comment on peut parametrer une forme de base dans un gabarit visio pour que le système demande automatiquement de saisir les propriétés personnalisés de la forme lorsque celle-ci est insérée dans le dessin.

Merci à l'avance.

[Arkham46]

Je débute sur visio, juste pour voir à quoi ça ressemble

Je n'ai rien vu en standard pour faire apparaître la fenêtre des propriétés automatiquement, mais ça peut se programmer en VBA :

Outils --> Macro --> Editeur Visual Basic
Puis repérez le projet du nom du gabarit et ThisDocument doit se trouver dans le répertoire Visio Object
Mettez le code ci-dessous dans le module ThisDocument du gabarit.
Fermez le gabarit et réouvrez le pour activer le code.

Remarque : J'ai testé ça sur Visio 2000.

Code vb :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Option Explicit
 
' Objet application pour capture des événements
Private WithEvents gAppli As Application
 
' Avant fermeture du gabarit
Private Sub Document_BeforeDocumentClose(ByVal doc As IVDocument)
' Libère l'objet application
Set gAppli = Nothing
End Sub
 
' A l'ouverture du gabarit
Private Sub Document_DocumentOpened(ByVal doc As IVDocument)
' Définit l'objet application
Set gAppli = ThisDocument.Application
End Sub
 
' Lors de l'ajout d'une forme dans un dessin
Private Sub gAppli_ShapeAdded(ByVal Shape As IVShape)
Dim lMasterName As String
' Recherche le nom de la forme maître
On Error Resume Next
lMasterName = Shape.Master.Name
If Err.Number <> 0 Then Exit Sub
On Error GoTo Gestion_Erreurs
' Action en fonction du nom de la forme maître
Select Case Shape.Master.Name
    ' Lister ici les formes pour lesquelles on veut afficher la fenêtre de saisie
    '    des propriétés
    Case "test_titi","MaForme1","Blablabla"
        ' Appel la boîte de dialogue pour saisie des propriétés
       Application.DoCmd (visCmdFormatCustPropEdit)
End Select
' Fin procédure
Exit Sub
' Gestion des erreurs
Gestion_Erreurs:
MsgBox Err.Number & " : " & Err.Description
End Sub

[Arkham46]

Encore plus simple, toujours testé sur Visio 2000 :
Sélectionner la forme.
Afficher la fenêtre ShapeSheet (Fenêtre --> Afficher la feuille ShapeSheet)
Dans la cellule CréationEvén de la section Evénement, écrire :

Code :

=FAIRECMD(1312)

Plus besoin de VBA.