[Fait]Arrondir un nombre à sa valeur supérieure ou inférieure

[philben]

Bonjour,

Contrairement à la fonction Round qui arrondi un nombre à sa valeur la plus proche en fonction des décimales choisies, je vous propose la fonction RoundUP qui arrondi un nombre à sa valeur supérieure en fonction des décimales choisies et, pour ne pas me faire couper l'herbe sous le pied , la fonction inverse RoundDown !

Voici le code et des exemples pour désherber tout ça :

 
Public Function RoundUp(vValeur As Variant, Optional byNbDec As Byte) As Variant
   RoundUp = -Int(-vValeur * 10 ^ byNbDec) / 10 ^ byNbDec
End Function
 
Public Function RoundDown(vValeur As Variant, Optional byNbDec As Byte) As Variant
   RoundDown = Int(vValeur * 10 ^ byNbDec) / 10 ^ byNbDec
End Function
 

Exemples :

   MsgBox "Round: " & Round(5.2)                 ' 5
   MsgBox "RoundUp: " & RoundUp(5.2)          ' 6
   MsgBox "RoundDown: " & RoundDown(5.2)  ' 5

   MsgBox "Round: " & Round(0.5)         ' 0 BUG ????????????????
   MsgBox "RoundUp: " & RoundUp(0.5)          ' 1
   MsgBox "RoundDown: " & RoundDown(0.5)  ' 0

   MsgBox "Round: " & Round(-0.5)       ' 0 BUG ????????????????
   MsgBox "RoundUp: " & RoundUp(-0.5)      ' 0
   MsgBox "RoundDown: " & RoundDown(-0.5)  ' -1

   MsgBox "Round: " & Round(2.51, 1)         'renvoie 2,5
   MsgBox "RoundUp: " & RoundUp(2.51, 1)     'renvoie 2,6
   MsgBox "RoundDown: " & RoundDown(2.51, 1) 'renvoie 2,5

   MsgBox "Round: " & Round(-2.56, 1)         'renvoie -2,6
   MsgBox "RoundUp: " & RoundUp(-2.56, 1)     'renvoie -2,5
   MsgBox "RoundDown: " & RoundDown(-2.56, 1) 'renvoie -2,6

Amicalement,

Philippe

[Tofalu]

Qu'est ce que tu penses de cette proposition

Enum myRoundEnum
    myRoundup = -1
    myRoundDown = 1
End Enum
 
Public Function myRound(vValeur As Variant, Optional byNbDec As Byte, Optional eSens As myRoundEnum = myRoundup) As Variant
   myRound = eSens * Int(eSens * vValeur * 10 ^ byNbDec) / 10 ^ byNbDec
End Function
 
Sub test()
MsgBox myRound(4.333, 1, myRoundup)
MsgBox myRound(4.333, 1, myRoundDown)
End Sub
 

On évite ainsi la multiplication des fonctions

[philben]

Bonjour Tofalu,

Excellent, de plus la formule 2 en 1 est vendeuse !

Amicalement,

Philippe

[tatayoyo]

ce genre de fonction s'ajoute dans la partie "Modules" n'est ce pas ?

peut on ensuite utiliser la fonction dans une requete SQL ?
peut on ensuite utiliser la fonction dans une requete SQL appellé via ODBC ?

[philben]

bonjour,

En principe oui mais le paramètre optional ne l'est plus et l'enum n'est pas reconnu (mettre la valeur correspondante). Il faut mettre les fonctions publiques dans un module standard.

Le plus simple peut être est d'écrire seulement la ligne de code de la fonction dans votre requête SQL.

J'en profite pour mettre le code des fonctions qui permettent aussi d'arrondir à la dizaine (-1), centaine (-2), etc... supérieur ou inférieure.
Je limite la puissance 10 à 5 pour éviter un overflow.

 
Public Function RoundUp(ByVal vValeur As Variant, Optional ByVal iNbDecimal As Integer) As Variant
   If Abs(iNbDecimal) < 5 Then RoundUp = -Int(-vValeur * 10 ^ iNbDecimal) / 10 ^ iNbDecimal
End Function
 
Public Function RoundDown(ByVal vValeur As Variant, Optional ByVal iNbDecimal As Integer) As Variant
   If Abs(iNbDecimal) < 5 Then RoundDown = Int(vValeur * 10 ^ iNbDecimal) / 10 ^ iNbDecimal
End Function
 
 

Exemples complémentaires :

 
Debug.Print RoundUp(1104, -2)    '=> 1200
Debug.Print RoundDown(116.5, -1) '=> 110
 
Debug.Print RoundUp(-1, -1)      '=> 0
Debug.Print RoundDown(-1, -2)    '=> -100
 

cordialement,

Philippe