Discussion :

[mikedavem]

Bonsoir tout le monde,

Je voulais simplement savoir si en VBA il était possible de détecter à l'ouverture d'un fichier excel si des bibliotheques sont manquantes.

A l'ouverture de mon classeur je vérifie si une connexion à un serveur sql existe et selon le cas je traite différemment mon fichier.

J'utilise donc le composant ADO.
Le problème est que si j'ouvre ce fichier sur un ordinateur qui ne possède pas ce composant j'ai forcement une erreur de compilation.

Est il possible justement de vérifier si le composant ADO est présent à l'ouverture et afficher ainsi un message du genre "Veuillez installer ADO...." ?

Merci pour vos réponses

[tirex28]

Bonsoir,

Cette procédure ajoute la référence à ADO si elle n'est pas déja présente.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Private Sub Workbook_Open()
    Dim Ref, AdoIsInstalled As Boolean
    Const RefName As String = "ADODB"
    With ThisWorkbook.VBProject
        For Each Ref In .References
            If Ref.Name = RefName Then
                AdoIsInstalled = True
                Exit For
            End If
        Next
        If AdoIsInstalled Then
            MsgBox "Version installée: " & Ref.Name & " " & Ref.Major & "." & Ref.Minor
        Else
            .References.AddFromFile "C:\Program Files\Fichiers communs\System\ado\msado15.dll"
            'Ou
            '.References.AddFromGuid "{2A75196C-D9EB-4129-B803-931327F72D5C}", 2, 8
        End If
    End With
End Sub

Cela ne provoque pas d'erreur de compilation à condition qu'il n y ait aucune déclaration de variable d'un type d'objet fourni par ADO dans la section déclaration du module ThisWorkbook ou dans la procédure WorkBook_Open.

Cordialement,

Tirex28/

[mikedavem]

Merci pour ta réponse.

La procédure ne fonctionne pas chez moi
Je pense que Ref doit être d'un autre type que boolean.

J'ai continué à chercher et apparemment Ref devrait être du type Reference hors visual basic editor m'indique que ce type n'existe pas.
J'utilise excel 2003

quelqu'un a une idée ?

[mikedavem]

Pour que ca marche j'ai dû enlever "Option Explicit" sur ma feuille ainsi que la déclaration de la variable ref . Si quelqu'un a cependant l'explication du pourquoi le type "Reference" n'exite pas je suis preneur

du coup ma fonction devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Private Function verification_ADO() As Boolean
 
   ' Dim ref As Reference
    Dim AdoIsInstalled As Boolean
    Const refName AS String = "ADODB"
 
    AdoIsInstalled = False
 
    For Each ref In ThisWorkbook.VBProject.References
         If ref.Name = refName Then
             AdoInstalled = True
             Exit For
         End If
    Next ref
 
    verification_ADO = AdoIsInstalled
 
End Function

[tirex28]

Bonjour,

Je pense que Ref doit être d'un autre type que boolean

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Dim Ref, AdoIsInstalled As Boolean

En l'occurence Ref est de type Variant puisque la déclaration du type n'est pas explicite.

Ref devrait être du type Reference hors visual basic editor m'indique que ce type n'existe pas.

Ce type existe bel et bien mais pour pouvoir l'utiliser il faut aller dans Outils>References et cocher Visual Basic for Application Extensibility 5.3

Pour que ca marche j'ai dû enlever "Option Explicit" sur ma feuille ainsi que la déclaration de la variable ref

Utilisant egalement Excel 2003, ca fonctionne tres bien avec Option Explicit et une variable de type Variant. Si tu veux absolument déclarer un type Reference il faut ajouter la reférence à VBA ext 5.3 comme indiqué ci-dessus.

Cordialement,

Tirex28/

[mikedavem]

Effectivement ca marche bcp mieux en ayant coché la référence que tu as indiqué

Merci