Concaténer plusieurs tuples dans un résultat

[cdryk]

Bonjour à tous,

J'ai un problème qui a déjà été soulevé et résolu pour MySQL par exemple mais j'aimerai savoir si il existe quelque chose pour Oracle...

Voila un exemple :

Code :

1
2
3
4
5
6
7
8
9
10
Requete : SELECT pk FROM test
 
Qui me retourne :
 
pk
--------
1
2
3
4

Moi j'aimerai avoir :

Code :

1
2
3
res
----------
1,2,3,4

Donc j'ai lu pas mal de chose dont la fonction GROUP_CONCAT de MySQL qui semble répondre à ce besoin...

Mais je sèche sous oracle... a moins de faire une fonction ou procédure mais j'aimerai savoir si il n'y a pas quelque chose de plus light...

Merci d'avance !

[sygale]

Tu peux faire tes propres fonction d'aggregation exemple :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
CREATE OR REPLACE type string_agg_type AS object
(
   total varchar2(4000),
 
   static FUNCTION
        ODCIAggregateInitialize(sctx IN OUT string_agg_type )
        RETURN number,
 
   member FUNCTION
        ODCIAggregateIterate(self IN OUT string_agg_type ,
                             value IN varchar2 )
        RETURN number,
 
   member FUNCTION
        ODCIAggregateTerminate(self IN string_agg_type,
                               returnValue OUT  varchar2,
                               flags IN number)
        RETURN number,
 
   member FUNCTION
        ODCIAggregateMerge(self IN OUT string_agg_type,
                           ctx2 IN string_agg_type)
        RETURN number
);
/
 
 
 
 
CREATE OR REPLACE type body string_agg_type
IS
 
static FUNCTION ODCIAggregateInitialize(sctx IN OUT string_agg_type)
RETURN number
IS
begin
    sctx := string_agg_type( NULL );
    RETURN ODCIConst.Success;
end;
 
member FUNCTION ODCIAggregateIterate(self IN OUT string_agg_type,
                                     value IN varchar2 )
RETURN number
IS
begin
    self.total := self.total || ',' || value;
    RETURN ODCIConst.Success;
end;
 
member FUNCTION ODCIAggregateTerminate(self IN string_agg_type,
                                       returnValue OUT varchar2,
                                       flags IN number)
RETURN number
IS
begin
    returnValue := ltrim(self.total,',');
    RETURN ODCIConst.Success;
end;
 
member FUNCTION ODCIAggregateMerge(self IN OUT string_agg_type,
                                   ctx2 IN string_agg_type)
RETURN number
IS
begin
    self.total := self.total || ctx2.total;
    RETURN ODCIConst.Success;
end;
 
 
end;
/
 
CREATE OR REPLACE
FUNCTION stragg(input varchar2 )
RETURN varchar2
PARALLEL_ENABLE AGGREGATE USING string_agg_type;
/
 
 
SELECT deptno, stragg(ename)
 FROM emp
GROUP BY deptno
 
 
    DEPTNO
----------
STRAGG(ENAME)
---------------------------------------------------------------------------------
--------------------------------------------------
        10
CLARK,KING,MILLER
 
        20
SMITH,FORD,ADAMS,SCOTT,JONES
 
        30
ALLEN,BLAKE,MARTIN,TURNER,JAMES,WARD
 
 
would be the approach.