FRM 41214 : Impossible d'exécuter l'état [FAQ] [Résolu]

[Process Linux]

Bonjours , je travail sur forms 9IDS . J'ai développé des états avec report builder 9IDS .
Quand j'essai d'appeler mon état à partir de forms j'ai cette erreur :
FRM 41214 impossible d'executer l'etat

voilà ce que j'ai fais pour préparer l'execution de mon état :

1- Création d'un service windows avec la commande
rwserver –install credits -- C'est le nom de mon serveur d'état
2- Je démarre le service dans le gestionnaire des services de windows
3- Je démarre mon OC4J
4- Le code du bouton qui fait appel à l'état à partir de form est le suivant :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
DECLARE
	report_id REPORT_OBJECT;
	v_rep VARCHAR2(100);
	rep_status varchar2(20); 
 
BEGIN
 
	report_id := FIND_REPORT_OBJECT('ET_ETAT');
-- J'ai déjà créé un noeud dans état pour donner les informations sur mon fichier rdf qui s'appelle test.rdf
 
  SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_SERVER,'credits');
  v_rep := RUN_REPORT_OBJECT(report_id);
  /* Dans un premier temps je veux juste executer l'état dans le cache */
	rep_status := report_object_status(v_rep); 
	IF rep_status = 'FINISHED' THEN
		message('OK');
		message('OK');
	else
		message('NON');
		message('NON');
	end IF;
 
END;

Merci de m'apporter des conseils concernant ce problème

[SheikYerbouti]

Vérifiez que votre Report Serveur est OK. (et que vous avez spécifié sont nom dans les propriétés de l'état dans Forms)

[Process Linux]

Bonjours , j'ai pu résoudre ce problème d'execution d'état , et pour aider les autres voici la procédure complète :

1 - Création du serveur d'état
Pour windows tappez dans l'invite des commandes la commande suivante:

Code :

rwserver –install votre_serveur

Pour linux / Unix et ses variantes

Code :

rwserver.sh server=votre_serveur batch=yes &

Pour windows il faut démarrer le service à partir du gestionnaire des services.

Attention : le nom du serveur ne doit pas contenir le caractère '_' car il est utilisé pour invoqué un objet créer au niveau du serveur d'état.

Une fois le serveur fonctionne bien, il faut enregistrer l'état créer avec report builder en format rdf.
pour le faire il suffit de changer l'extension quand vous sauvegardez votre état .
maintenant on va passer à forms 9i pour appeler notre état sauvegardée en format rdf.

Dans votre modul form , il faut créer un noeud dans la propriété Etat, appyuez sur F4 pour retrouver les informations de ce noeud. Il faut donner le nom de votre serveur , le chemin de l'état (RDF) .

Le reste des données on peut les données en runtime.

voici le code à mettre dans le déclencheur qui va invoquer la form :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
DECLARE 
report_id REPORT_OBJECT; 
report_job_id VARCHAR2(200); 
rep_status VARCHAR2(200); 
JOB_NUMBER number; 
server_name VARCHAR2(200) := 'credits'; 
 
BEGIN 
 
/* Check to see if forms application is WEB deployed */ 
 
IF get_application_property(user_interface) = 'WEB' THEN 
report_id:= FIND_REPORT_OBJECT('TEST'); 
 
/* Set Report parameters given WEB deployment */ 
SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_SERVER , server_name); 
SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_DESTYPE,CACHE); 
 
/* DESFORMAT could be HTML, HTMLCSS or PDF here*/ 
SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_DESFORMAT,'HTML'); 
 
/* Run the report */ 
report_job_id := RUN_REPORT_OBJECT(report_id); 
 
/* Check the report status */ 
rep_status:=REPORT_OBJECT_STATUS(report_job_id); 
WHILE rep_status IN ('RUNNING','OPENING_REPORT','ENQUEUED') 
LOOP 
rep_status := report_object_status(report_job_id); 
END LOOP; 
IF rep_status='FINISHED' THEN 
message('REPORT WAS CORRECTLY RUN'); 
 
/* Display the report output in the client browser */ 
JOB_NUMBER := length(server_name) + 2; 
WEB.SHOW_DOCUMENT ('/reports/rwservlet/getjobid'||substr(report_job_id,JOB_NUMBER)||'?server=' || server_name ,'_BLANK'); 
 
/* If report has failed display message to user */ 
ELSE 
message('REPORT FAILED WITH STATUS: '||rep_status); 
END IF; 
ELSE 
 
/* Else if forms application is Client-Server deployed */ 
/* Set Report parameters given Client-Server deployment */ 
 
report_id:= FIND_REPORT_OBJECT('TEST'); 
SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_SERVER ,''); 
 
/* Report to be executed via Reports Background Engine, not the 'new' Reports Multi-Tier Server */ 
/* Destype SCREEN or PREVIEW can be used here */ 
 
SET_REPORT_OBJECT_PROPERTY(report_id,REPORT_DESTYPE,SCREEN); 
 
/* Run the report */ 
 
report_job_id := RUN_REPORT_OBJECT(report_id); 
 
END IF; 
END;

maintenant vous pouvez executer le code. Ca doit marcher .

Voilà , sur le site developpez.com j'ai eu beaucoup d'information , beaucoup d'aide . J'ai décidé d'apporter cette information modest en reconnaissance des efforts de toutes l'équipe de développez.com

Merci SheikYerbouti

[SheikYerbouti]

Chaque info apportée dans ce forum est modeste.
L'ensemble, par contre est grandiose.

Merci de votre collaboration

[JerryMouse]

Merci Process Linux
Ca va beancoup m'aider.

[dikha08]

Bonjour
merci pour tout
maintenant le petit souci que g c que le fiecher excel s'ouvre le serveur et seul le grille de parametrage est afficher sur ce fichier excel
NB mon etat.rdf a des parametres

[mongilotti]

tu ajoute dans l'url &paramform=yes