Discussion :

[Oliviers]

Bonjour

Voila j'ai une base frontale dont je voudrais pouvoir connecter a une base dorsale.
j'ai trouver comment faire dans un livre,mais je voudrais pouvoir indiquer le chemin de la base dorsale avec l'object

msoFileDialogFilePicker

je n'ai rien trouve sur ce forum a ce sujet.

merci d'avance pour un coup de main.

[Dolphy35]

Bonjour,

je te conseillerais de passer par les API plutot que par FielDialog, tu rencontera moins de soucis si tu distribue l'appli.
Afficher la boîte de dialogue ouvrir afin de récupérer le nom et le chemin du fichier sélectionné

Il te suffit de créer un module et d'y coller le code.

ensuite pour récupérer le chemin :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox OuvrirUnFichier(Me.Hwnd, "Parcourir", 1, "Base Access", "mdb")

Concernant les liaisons des tables il y a également un point dans la
Rétablir les liaisons des tables liées après déplacement d'une base fractionnée

Dolphy

[Oliviers]

Merci Dophy35 pour ta reponse

l'api marche tres bien mais je n'arrive pas a retablir ma liaison avec les tables.

j'ai bien regarder le sujet dans la faq.je ne comprends pas comment faire.
j'ai mis le code pour retablir la liaison dans le module de l'api.

mais sans resultat,ta proposition me semble tres bonne mais je crois que j'ai besoin d'aide pour la realiser.

[Dolphy35]

Bonjour,

le plus simple est de créer un nouveau module et d'y insérer cette fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Function LierTables(strChmFichier As String) As Boolean
 
    'Déclaration des variables
    Dim dbBase As Database
    Dim tbdTables As TableDef
    Dim rst As Recordset
    Dim tbdTemp As TableDef
 
    LierTables = False
 
    'Instancie la base courrante
    Set dbBase = CurrentDb
 
    'Boucle Parcourant toutes les tables de la Bdd en cours
    For Each tbdTables In dbBase.TableDefs
 
        'Teste l'attribut de la table pour savoir si c'est une table liée
        If tbdTables.Attributes And dbAttachedTable Then
            tbdTables.Connect = ";DATABASE=" & strChmFichier
            tbdTables.RefreshLink
        End If
 
    Next tbdTables
 
    dbBase.Close
    Set dbBase = Nothing
 
    'Affiche Message
    MsgBox ("mise à jour terminée")
    LierTables = True
 
End Function

Ensuite sur le bouton de ton formulaire tu mets ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
    'Déclaration variable
    Dim strChemin As String
 
    'Ouverture de la fenêtre Windows et stockage du chemin dans la variable
    strChemin = OuvrirUnFichier(Me.hWnd, "Parcourir", 1, "Fichiers Access", "mdb")
 
    'Test si présence de caractères dans la variable au cas où l'utilisateur annule
    If Len(strChemin) <> 0 Then
 
        'Appel Fonction de Liaison table avce le chemin en paramètre et test retour de la fonction
        If LierTables(strChemin) = True Then
 
            'Code si la fonction c'est réalisée sans encombre
            DoCmd.Close
 
        Else
 
            'Message si la fonction n'a pas renvoyer le True
            MsgBox "Mise à jour des Tables non éffectuées", vbExclamation, "Liaison des tables"
 
        End If
 
    Else
 
        'Message si l'utilisateur à annuler la sélection du chemin
        MsgBox "Annulation par utilisateur", vbInformation, "Liaison des tables"
 
    End If

Bon week Dolphy

[Oliviers]

Merci pour t'on aide.
cela marche a merveille..

[DanBoxer95]

Merci - Beaucoup, je le cherche depuis longtemps
ça fonctionne parfaitement.
Daniel