Discussion :

[nicburger]

Bonjour à tous,

Je cherche à créer une table voire plusieurs (selon ce que veut rajouter l'utilisateur) et les lier à une table principale par une relation "1 à oo".

J'aimerais que cela se fasse via un bouton

Je ne sais pas comment faire ?

Je sais coder le bouton sur l'évènement "OnClick" mais ne sait pas comment ajouter une table et y insérer des champs ??


PS : j'ai cherché dans la FAQ, et la Recherche Avancée mais je n'ai trouvé que la possibilité de supprimer une table en VBA !!

[muse19]

Bonjour

Moi je sais juste créer une table via vba, mais pas pou les relations, je te mets le bout de code correspondant quand même.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim db As DAO.Database: Set db = CurrentDb
Dim tdf As TableDef: Set tdf = db.CreateTableDef("nom_de_la_table")
With tdf
    .Fields.Append .CreateField("champ1", dbSingle, 7)
    .Fields.Append .CreateField("champ2", dbText, 50)
End With
db.TableDefs.Append tdf
db.TableDefs.Refresh
db.Close

[Tofalu]

Il ne faut pas oublier d'ajouter une référence Microsoft DAO à ton projet.

Pour ce qui est des relations, c'est guère plus compliqué.
Prenons le cas d'une table commande et d'une autre client.

Commande(NumCommande,#IDclient)
Client(NumClient,Nom)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
Sub creation_base()
On Error Resume Next
Dim db As DAO.Database
 
Dim tdf As DAO.TableDef
Dim F As DAO.Field, ind As DAO.Index
Dim R As DAO.Relation
Set db = CurrentDb
'Cree la table client
    Set tdf = db.CreateTableDef("Client")
With tdf
 
    Set F = .CreateField("NumClient", dbLong)
    'specifie un champ Num_Auto
    F.Attributes = dbAutoIncrField
    .Fields.Append F
    .Fields.Append .CreateField("Nom", dbText, 50)
    'rafraichit la collection
    .Fields.Refresh
    'Creer la clé primaire
    Set ind = .CreateIndex("PK_Client")
    ind.Fields = "NumClient"
    ind.Primary = True
    ind.Unique = True
    .Indexes.Append ind
    'rafraichit la collection
    .Indexes.Refresh
End With
'Ajoute la table
db.TableDefs.Append tdf
'Cree la table Commande
Set tdf = db.CreateTableDef("Commande")
With tdf
 
    Set F = .CreateField("NumCommande", dbLong)
    'specifie un champ Num_Auto
    F.Attributes = dbAutoIncrField
    .Fields.Append F
    .Fields.Append .CreateField("IDClient", dbLong)
    'rafraichit la collection
    .Fields.Refresh
    'Creer la clé primaire
    Set ind = .CreateIndex("PK_Commande")
    ind.Fields = "NumCommande"
    ind.Primary = True
    ind.Unique = True
    .Indexes.Append ind
    'rafraichit la collection
    .Indexes.Refresh
End With
'Ajoute la table
db.TableDefs.Append tdf
db.TableDefs.Refresh
'Ajoute la relation
Set R = db.CreateRelation("Client-Commande")
With R
    .Table = "Client"
    .ForeignTable = "Commande"
    'CLé primaire NumClient
    Set F = R.CreateField("NumClient")
    'Clé Etrangère IDCLient
    F.ForeignName = "IDClient"
    .Fields.Append F
    .Fields.Refresh
    MsgBox .Fields.Count
    'definit la MAJ en cascade et
    'la suppression en cascade
    .Attributes = dbRelationDeleteCascade + _
      dbRelationUpdateCascade
End With
db.Relations.Append R
MsgBox "fini"
End Sub

[Gandalf24]

Supression de table :
docmd.runsql "drop table toto"

[nicburger]

Merci à vous tous,


Pour l'instant, je suis sur la création de table et cela ne marche pas...enfin je n'arrive pas trop !
J'ai recopié le code suivant dans un module de cette façon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Public Function InsertTable()
Dim db As DAO.Database: Set db = CurrentDb 
Dim tdf As TableDef: Set tdf = db.CreateTableDef("nom_de_la_table") 
With tdf 
    .Fields.Append .CreateField("champ1", dbSingle, 7) 
    .Fields.Append .CreateField("champ2", dbText, 50) 
End With 
db.TableDefs.Append tdf 
db.TableDefs.Refresh 
db.Close
End Function

Tout d'abord...ai-je bien fait de la mettre publique et non Private ?

Comment l'appeler sur un bouton
Moi j'ai fait sur l'évènement "OnClick" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call InsertTable

Mais ça me met un message d'erreur :

Object Variable ot With block Variable not set

Sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim tdf As TableDef: Set tdf = db.CreateTableDef("nom_de_la_table")

[/quote]

[nicburger]

Tofalu, dans ton code il semble y avoi rnon seulement celui de la liaison entre 2 tables maais aussi celui de la création de table n'est-ce pas ?

Dans ce cas : j'essaie de suite...

[Tofalu]

Mon code :

- Création des tables
- Création des champs
- Création des clés (index)
- Création des relations
- Mise en place de l'intégrité réferentielle.

[nicburger]

Merci beaucoup Tofalu : ton Code fonctionne parfaitement !

Je me posais la question cependant de la possibilité d'entrer le nom des tables à créer via une VBBox ????

[Tofalu]

Tu peux faire comme tu souhaites un nom de table est une string, la façon dont tu crées cette string est indépendante du moteur Jet

[nicburger]

J'ai réussi à crée les tables désirées...

Désormais j'aimerais crée une nouvelle Table (ça c'est OK) et ensuite la lier à une Table existante...

Que faudrait-il modifier dans le code pour cela ?

[Tofalu]

Plutot que de demander essaye de comprendre par toi même comment cela fonction en t'aidant par exemple de l'aide. Tu crois pas que ce serait mieux pour toi ?

[nicburger]

Plutot que de demander essaye de comprendre par toi même comment cela fonction en t'aidant par exemple de l'aide. Tu crois pas que ce serait mieux pour toi ?

Oui c'est ce ce que je fais !

Etant donné que je ne veux créer qu'une Table (Ex : Client) et que je veux lier son ID à une Table existante : il faut que je remplace dans ton code la 2ème table Commande par ma Table existante : mais spa évident !