Vérifier l'activation d'une référence [Trucs & Astuces] [Résolu]

[Pikasacha]

Bonjour,

Je voudrais savoir si il existerait un moyen pour vérifier, à partir du code, si une référence est activée et, si possible, de l'activer si ce n'est pas le cas.

Merci d'avance

[Pierre Fauconnier]

Bonjour

Le code va différer selon que tu travailles avec VBA pour Access, Excel, Word, PowerPoint.

D'une façon générale, je conseille de
1. tester si la référence est active
2. Si elle ne l'est pas, l'activer.

Cela peut se faire au moyen d'une fonction et d'une procédure.
La fonction de test demande le nom de la référence. La procédure demande le nom du fichier, éventuellement avec son chemin complet (à ma connaissance,facultatif lorsque ce chemin se trouve dans l'arborescence de c:\windows)

ACCESS
1. Fonction de test de référence active

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Function ReferenceActive(Nom As String) As Boolean
    Dim i As Integer
    Dim NbreRef As Integer
 
    NbreRef = Application.VBE.ActiveVBProject.References.Count
 
    For i = 1 To NbreRef
        If Application.VBE.ActiveVBProject.References(i).Name = Nom Then
            ReferenceActive = True
            Exit Function
        End If
    Next i
End Function

2. Procédure d'activation

Code :

1
2
3
Sub ActiverReference(NomFichier As String)
    Application.VBE.ActiveVBProject.References.AddFromFile NomFichier
End Sub

EXCEL, WORD, POWERPOINT
Pour Excel, Word ou PowerPoint, c'est la même démarche, mais les références font partie de l'objet actif, soit:
Pour Excel, ThisWorkbook
Pour Word, ThisDocument
Pour PowerPoint, ActivePresentation
Voici le code pour Excel. Pour les autres applications, il faudra remplacer ThisWorkbook par l'objet actif
1. Fonction de test

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Function ReferenceActive(Nom As String) As Boolean
    Dim i As Integer
    Dim NbreRef As Integer
 
    NbreRef = ThisWorkbook.VBProject.References.Count
 
    For i = 1 To NbreRef
        If ThisWorkbook.VBProject.References(i).Name = Nom Then
            ReferenceActive = True
            Exit Function
        End If
    Next i
End Function

2.Procédure d'activation

Code :

1
2
3
Sub ActiverReference(NomComplet As String)
    ThisWorkbook.VBProject.References.AddFromFile NomComplet
End Sub

Utilisation de la fonction et de la procédure
Attention! La procédure d'activation renvoie une erreur si la référence est déjà active. Dès lors, je propose le code suivant, qui fonctionne dans tous les cas, y compris Access. Par exemple, pour tester et activer le scripting Runtime

Code :

    If Not ReferenceActive("scripting") Then ActiverReference "scrrun.dll"

Ok?

[Pikasacha]

Merci beaucoup, tout marche

[adripagos]

J'ai amélioré les conditions avec la version utilisé car l'emplacement des référence change selon les version (voir table http://officesystemaccess.seneque.ne...constantes.htm)

De plus ma version la condition if Not ne résout pas le problème j'ai 'solutionné' par une mise en variable .... je suis pas développeur ...


Si cela peut aider quelqu'un sait on jamais

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Sub Workbook_Open()
 
 'TESTE SI LA REFERENCE WORD EST PRESENTE.
    q = ReferenceActive("Word")
 
    'SI BONNE VERSION
    If Verssion = 10 Or 11 Or 12 Then
 
 
            'SI PAS PRESENTE
            If q = False Then
                ThisWorkbook.VBProject.references.AddFromFile "MSWORD.OLB" 'ON LA MET
                MsgBox "MIS"
                Else
                'Sinon on l'enleve et la remet
                ThisWorkbook.VBProject.references.remove ThisWorkbook.VBProject.references("Word")
                ThisWorkbook.VBProject.references.AddFromFile "MSWORD.OLB" 'ON LA MET
                MsgBox "REMIS"
            End If
 
 
    Else
    'SINON on dit pas possible et quitte
     MsgBox "Attention Votre version d'Excel ne supportera pas l'export Word. Cette fonction marche à partir de la version 2002."
 
     End If
 
End Sub