[VBA-P] - checkbox dynamique

[fredroux]

bonjour à tous,

voilà j'ai créé des checkbox en dynamique, mais je n'arrive pas à récupérer l'évènement "click" individuellement pour chaque checkbox.

Voici mon code

Dans un module de classe : "classe1"

Code :

1
2
3
4
5
6
Public WithEvents ess As CheckBox
 
Private Sub ess_click()
'ici je recupère bien tous mes évènement click
 
End Sub

Dans le code de mon userform

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Explicit
Dim cgroup() As New Classe1
Public i As Integer
 
Private Sub CommandButton1_Click()
 
i = i + 1
ReDim Preserve cgroup(1 To i) As New Classe1
Set cgroup(i).ess = Controls.Add("Forms.checkbox.1", "toto", True)
With cgroup(i).ess
.Move i * 10, i * 20
.Visible = True
 
End With
 
End Sub

Si quelqu'un peux m'aider, merci

[SilkyRoad]

bonsoir

j'espere que ces infos pourront t'aider

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
'--------------------------------------
'Procedure de creation de CheckBox dynamique
'dans l'UserForm
Option Explicit
 
Private Sub CommandButton1_Click()
Dim Obj As Control
Dim Cl As Classe1
 
Set Collect = New Collection
 
Set Obj = Me.Controls.Add("forms.Checkbox.1")
With Obj
    .Name = "moncheckbox"
    .Object.Caption = "le texte"
    .Left = 40
    .Top = 30
    .Width = 50
    .Height = 20
End With
 
'ajout de l'objet dans la classe
Set Cl = New Classe1
Set Cl.ChkBx = Obj
Collect.Add Cl
 
End Sub
'--------------------------------------

Code :

1
2
3
4
5
6
'--------------------------------------
'dans un module standard
Option Explicit
 
Public Collect As Collection
'--------------------------------------

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
'--------------------------------------
'dans un module de classe nommé "Classe1"
'
Option Explicit
 
Public WithEvents ChkBx As MSForms.checkbox
 
'exemple pour gerer l'evenement eclic sur les objets type CheckBox
Private Sub ChkBx_Click()
'cet exemple affiche la valeur de l'objet cliqué
MsgBox ChkBx.Value
End Sub
'--------------------------------------

bonne soiree
michel

[fredroux]

Merci pour ta réponse,

en effet cela marche pour créer des checkbox en dynamique,

mais je n'arrive toujours pas à savoir quel est le chkbx qui est activé.
il faudrait que je récupère le "numero" du chkbx !!

merci de m'aider encore, si possible.

Salutations

[SilkyRoad]

bonjour

tu peux utiliser cette adaptation dans le module de classe

Code :

1
2
3
4
Private Sub ChkBx_Click()
'cet exemple affiche la valeur de l'objet cliqué
MsgBox ChkBx.Name & " : " & ChkBx.Value
End Sub

bon apres midi
michel