Discussion :

[Geoffray]

Bonjour,

Désolé si la question a deja été posée, je n'ai pas trouvé.

Je cherche un début de macro qui par exemple ouvre tour à tour tous les fichiers excel se trouvant dans un même dossier. J'ai essayé de créer le code mais ca plante à chaque fois

Merci à vous

Geoffray

[SfJ5Rpw8]

et ces fichiers tu les ouvre pour les modifier .?

[SilkyRoad]

bonsoir

ci joint un exemple qui boucle et ouvre tous les classeurss d'un repertoire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub boucleClasseursRepertoire()
Dim Fichier As String, Chemin As String
Dim Wb As Workbook
 
'---lister les fichiers du répertoire ---
Chemin = "C:\Documents and Settings\michel\dossier"
Fichier = Dir(Chemin & "\*.xls")
 
    Do
        'ouverture de chaque classeur
        Set Wb = Workbooks.Open(Chemin & "\" & Fichier)
        '
        '
        'la macro à executer dans chaque classeur ...
        '
        '
        'fermeture des classeurs
        'mettre False pour que les modifs ne soient pas enregistrées
 
        Wb.Close True
    Fichier = Dir
    Loop Until Fichier = ""
 
End Sub

bonne soiree
michel

[Geoffray]

Merci pour le code Michel. Pour te répondre bbil en fait j'ai besoin d'ouvrir environ 80 fichiers excel pour ensuite les enregistrer en csv. Je teste ta macro dès que je peux Michel je suis d'apéro Merci en tout cas

[SilkyRoad]

rebonsoir

Si tu dois convertir beaucoup de classeurs en csv : cet exemple permet d'effectuer l'opération sans ouvrir tous les fichiers.
Dans cette procedure toutes les feuilles Excel sont supposées etre nommées "Feuil1"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub boucleClasseursFermesRepertoire()
'Necessite d'activer la reference Microsoft ActiveX Data Object 2.x Library
'
Dim Rs As ADODB.Recordset
Dim xConnect As String, xSql As String
Dim Fichier As String, Chemin As String, Feuille As String
 
'---lister les fichiers du répertoire ---
Chemin = "C:\Documents and Settings\michel\dossier\general\excel"
Fichier = Dir(Chemin & "\*.xls")
 
'Tous les classeurs du repertoire doivent contenir
'une feuille portant ce nom
Feuille = "Feuil1"
 
    Do
        xConnect = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
        Chemin & "\" & Fichier & ";" & "Extended Properties=Excel 8.0;"
 
        xSql = "SELECT * FROM [" & Feuille & "$];"
 
        Set Rs = New ADODB.Recordset
        Rs.Open xSql, xConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
 
        Open _
        Chemin & "\" & Left(Fichier, Len(Fichier) - 4) & ".csv" For Output As #1
 
        Do Until Rs.EOF
            'adaptez le séparateur
            'Print #1, Rs.GetString(, 500, vbTab, vbCrLf, "");
            Print #1, Rs.GetString(, 600, ";", vbCrLf, "");
        Loop
        Close #1
 
        Rs.Close
        Set Rs = Nothing
 
    Fichier = Dir
    Loop Until Fichier = ""
 
End Sub

bonne soiree
michel

[Geoffray]

Vraiment bien ce code. Peux tu me dire la différence entre :
'Print #1, Rs.GetString(, 500, vbTab, vbCrLf, "");
Print #1, Rs.GetString(, 600, ";", vbCrLf, "");

Dans mon cas je convertis un fichier xls en cvs de manière traditionnelle.

Merci

Geoffray

[SilkyRoad]

bonjour

Les 5 arguments de la la methode GetString:

1. adClipString définit le format du recordset :le format est de type chaîne de caracteres.
2. le nombre d'enregistrements à récupérer .Par défaut tous les enregistrements sont récupérés .
3. le délimiteur de colonnes.
4. le délimiteur d'enregistrements.
5. indique comment représenter des valeurs nulles .



bonne journée
michel

[Geoffray]

Merci Michel. J'ai fait tourner la macro aujourd'hui, un jeu d'enfant